Published February 24, 2019 © MIT

Smart Cable Car

Provide cableways a reliable feedback.

IntermediateFull instructions provided2 hours1,597

The Best GPS Project using Spresense: 3rd Place

Make It Better

Things used in this project

Hardware components

Sony Spresense boards (main & extension)

Espressif ESP32

DHT11 Temperature & Humidity Sensor (3 pins)

PIR Motion Sensor (generic)

MQ135 Air quality sensor

Software apps and online services

ThingSpeak API

Arduino IDE

Story

Overview

The cableways are convenient means of transport and are used by both tourists to reach the summit of a mountain and by people who reach the workplace.

Sometimes, when the weather is unfavorable, operators must stop the cabins leaving the passengers in midair and alone. When this happens, it is important for the control center to know if there are people inside a cabin and if the environmental parameters are safe.

The project is based on the assumption that many of the new plants are equipped with fiber-optic network and Wi-Fi access points on the pylons. This network, however, is only used by surveillance cameras, but does not meet all the needs of the case.

My device allows the measurement of air quality, temperature, GPS position and detects the presence of people or animals on board.

Software

The Sony Spresense board is used to detect the environmental parameters of the cab and its GPS position. The collected data are sent every ten seconds to the ESP32 module via the EasyTransfer library. The data is then sent to the ThingSpeak server for viewing.

To start, you need to create a channel on thingspeak.com and prepare the fields as shown in the picture. Write down the "Write API Key" available in the API Keys section.

Be sure to set the SSID, PASSWORD, and API_KEY variables before loading the programs.

1 / 3

Hardware

To provide the 5V needed for the system, I set up a photovoltaic storage system to be installed on one side of the cabin. Power is supplied to the USB connector of the ESP32 module and distributed to the other devices by the 5V pin.

I decided to host the components inside an IP65 junction box in order to guarantee solidity to the system.

To start, I made a ø5mm hole on one side and placed a green LED inside. Once I removed one of the plastic caps, I placed and glued the PIR sensor. I connected the devices to each other via Dupont jumper cables.

Before closing the box, I opened another cap and connected the USB cable to the ESP32 module. Care must be taken to prevent possible short circuits between components, perhaps by placing sheets of cardboard between them.

1 / 6

Operation

Not having a cablecar available I decided to test the system using my car. I took the power from a USB cigarette lighter and the smartphone hotspot for internet connection. The collected data were correctly displayed on the ThingSpeak channel.

Code

#include <GNSS.h>          // GNSS library
#include <dht11.h>         // DHT11 temperature sensor library
#include <EasyTransfer.h>  // Library for serial transfer of multiple datas


#define DHT11PIN 2 // Pin for DHT11 sensor
#define AIRPIN A3
#define MOVPIN A5 // Pin for IR sensor. Using analog read because pull-up breaks compatibility
dht11 DHT11; // Dht object
static SpGnss Gnss; // SpGnss object
EasyTransfer ETout;


// Serial output values
struct SEND_DATA_STRUCTURE{
  int16_t temp;
  int16_t movement;
  float longit;
  float latit;
  double altit;
  int16_t air;
};
SEND_DATA_STRUCTURE mydataout;
struct RECEIVE_DATA_STRUCTURE{
  int audio_track;
};
RECEIVE_DATA_STRUCTURE mydatain;


void setupGNSS(){ // Function to setup GNSS module
  int result;
  result = Gnss.begin(); // Function to setup GNSS module
  if (result == 0){
    result = Gnss.start(COLD_START);
    if (result == 0) ledOff(PIN_LED0);
  }
}


void setup() {  // Setup routine. Called when Spresense is powered up
  delay(10000); // Leave some time to the ESP board
  Serial2.begin(57600);  // Setup serial communication with ESP
  ETout.begin(details(mydataout), &Serial2);
  Serial.begin(115200); // Setup serial communication for debug
  ledOn(PIN_LED0);
  setupGNSS();
  Serial.println("Setup completed");
}


void loop() {  // Loop routine
  ledOn(PIN_LED3); // Debug loop status
  DHT11.read(DHT11PIN);  // Read temperature
  mydataout.temp = DHT11.temperature;
  mydataout.air = analogRead(AIRPIN); // Read air quality
  // Check movements
  if(analogRead(MOVPIN) > 100){
    mydataout.movement = 1;
  }else{
    mydataout.movement = 0;
  }
  // Read GPS data
  if(Gnss.waitUpdate(-1)){
    SpNavData datagps;
    Gnss.getNavData(&datagps);
      mydataout.longit = datagps.longitude;
      mydataout.latit = datagps.latitude;
      mydataout.altit = datagps.altitude;
  }
  // Debug GPS presence
  if(mydataout.altit>1){ 
    ledOn(PIN_LED2);
  }else{
    ledOff(PIN_LED2);
  }
  // Send sensors data to ESP
  ETout.sendData();
  Serial.println("Data sent");
  ledOff(PIN_LED3);
  delay(10000);
}

#include <WiFi.h>          // ESP WiFi libraries
#include <WiFiMulti.h> 
#include <EasyTransfer.h>  // Library for serial transfer of multiple datas
#define RXD2 16
#define TXD2 17


const char* ssid      = "network"; // Your SSID (Name of your WiFi)
const char* password  = "*******"; //Your Wifi password
const char* host      = "api.thingspeak.com";
String      api_key   = "O5**********5XS"; // Your API Key provied by thingspeak


EasyTransfer ETin;
// Serial input values
struct RECEIVE_DATA_STRUCTURE{
  int16_t temp;
  int16_t movement;
  float longit;
  float latit;
  double altit;
  int16_t air;
};
RECEIVE_DATA_STRUCTURE mydatain;


void setup() {  // Setup routine. Called when ESP is powered up
  Serial2.begin(57600, SERIAL_8N1, RXD2, TXD2);  // Setup serial communication with Spresense
  ETin.begin(details(mydatain), &Serial2);
  WiFi.mode(WIFI_STA);    
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
  }
}


void loop() {  // Loop routine
  //check and see if a data packet has come in  
  if(ETin.receiveData()){
    // call function to send data to Thingspeak
    SendTS();
  }
  delay(500);
}


void SendTS(){
  // Use WiFiClient class to create TCP connections
  WiFiClient client;
  const int httpPort = 80;
  if (!client.connect(host, httpPort)) {
    return;
  }
  else
  {
    String data_to_send = api_key;
    data_to_send += "&field1=";
    data_to_send += String(mydatain.temp);
    data_to_send += "&field2=";
    data_to_send += String(mydatain.movement);
    data_to_send += "&field3=";
    data_to_send += String(mydatain.latit);
    data_to_send += "&field4=";
    data_to_send += String(mydatain.longit);
    data_to_send += "&field5=";
    data_to_send += String(mydatain.altit);
    data_to_send += "&field6=";
    data_to_send += String(mydatain.air);
    data_to_send += "\r\n\r\n";

    client.print("POST /update HTTP/1.1\n");
    client.print("Host: api.thingspeak.com\n");
    client.print("Connection: close\n");
    client.print("X-THINGSPEAKAPIKEY: " + api_key + "\n");
    client.print("Content-Type: application/x-www-form-urlencoded\n");
    client.print("Content-Length: ");
    client.print(data_to_send.length());
    client.print("\n\n");
    client.print(data_to_send);
  }
  delay(2000);
  client.stop();
}