Ray's Break Timer

/*
 Ray's Break Timer

 Created by:
  John Lynch
  Manuel Diaz
  Jason Yang

*/

// include the library code:
#include <LiquidCrystal.h>
#include "pitches.h"

// borrowed from: https://create.arduino.cc/projecthub/jrance/super-mario-theme-song-w-piezo-buzzer-and-arduino-1cc2e4
//Mario main theme melody
int melody[] = {
  NOTE_E7, NOTE_E7, 0, NOTE_E7,
  0, NOTE_C7, NOTE_E7, 0,
  NOTE_G7, 0, 0,  0,
  NOTE_G6, 0, 0, 0,

  NOTE_C7, 0, 0, NOTE_G6,
  0, 0, NOTE_E6, 0,
  0, NOTE_A6, 0, NOTE_B6,
  0, NOTE_AS6, NOTE_A6, 0,

  NOTE_G6, NOTE_E7, NOTE_G7,
  NOTE_A7, 0, NOTE_F7, NOTE_G7,
  0, NOTE_E7, 0, NOTE_C7,
  NOTE_D7, NOTE_B6, 0, 0,

  NOTE_C7, 0, 0, NOTE_G6,
  0, 0, NOTE_E6, 0,
  0, NOTE_A6, 0, NOTE_B6,
  0, NOTE_AS6, NOTE_A6, 0,

  NOTE_G6, NOTE_E7, NOTE_G7,
  NOTE_A7, 0, NOTE_F7, NOTE_G7,
  0, NOTE_E7, 0, NOTE_C7,
  NOTE_D7, NOTE_B6, 0, 0
};

//Mario main them tempo
int noteDurations[] = {
  12, 12, 12, 12,
  12, 12, 12, 12,
  12, 12, 12, 12,
  12, 12, 12, 12,

  12, 12, 12, 12,
  12, 12, 12, 12,
  12, 12, 12, 12,
  12, 12, 12, 12,

  9, 9, 9,
  12, 12, 12, 12,
  12, 12, 12, 12,
  12, 12, 12, 12,

  12, 12, 12, 12,
  12, 12, 12, 12,
  12, 12, 12, 12,
  12, 12, 12, 12,

  9, 9, 9,
  12, 12, 12, 12,
  12, 12, 12, 12,
  12, 12, 12, 12,
};

// initialize the library by associating any needed LCD interface pin
// with the pin number it is connected to
const int rs = PC_6, en = PB_7, d4 = PA_2, d5 = PA_3, d6 = PA_4, d7 = PB_6;
LiquidCrystal lcd(rs, en, d4, d5, d6, d7);

// the absolute time that the timer will go off at
long endTime;

// the pin of the start/reset button
const int buttonPin = PUSH2;

// the pin for the piezo buzzer
const int buzzerPin = PC_4;

// the pin for the time-controlling potentiometer
const int potPin = PE_4;

// tilt switch
const int dismissPin = PD_2;

// the current pitch index in the melody
int pitchIndex = 0;

// a state variable used to indicate whether or not we're currently setting the time.
bool isSettingTime = false;

void setup() {
  // set up the LCD's number of columns and rows:
  lcd.begin(16, 2);

  // start a default time of 5 minutes
  endTime = millis() + (5 * 60 * 1000);

  // set our pins for input/output
  pinMode(buttonPin, INPUT_PULLUP);  
  pinMode(dismissPin, INPUT_PULLDOWN);  
  pinMode(buzzerPin, OUTPUT);  
}

void loop() {
  // if we're currently setting the time, do that!
  if (isSettingTime) {
    setTime();
  } else { 
    // otherwise, if we're past time, play the alarm
    if (millis() > endTime) {
      // alarm!
      doAlarm();
      return; 
    }
    
    // if we're counting and the button is pressed, reset
    if (digitalRead(buttonPin) == LOW) {
        isSettingTime = true;
        tone(buzzerPin, 260, 250);
        waitForUnpressed();
    }

    displayTime();
  }
}

// waits for the button to be unpressed
void waitForUnpressed() {
  waitForUnpressed(buttonPin);
}

void waitForUnpressed(int pin) {
  while (digitalRead(pin) == LOW) {}
}


void doAlarm() {
  // if we flip the switch, dismiss the alarm
  if (digitalRead(dismissPin) == LOW) {
      isSettingTime = true;
      waitForUnpressed(dismissPin);
      return; 
  }

  // play an alarm melody
  int noteDuration = 1000/noteDurations[pitchIndex];
  int pauseBetweenNotes = noteDuration * 1.30;

  tone(buzzerPin, melody[pitchIndex], noteDuration);
  delay(pauseBetweenNotes);
  noTone(buzzerPin);

  // if we're at the end of the melody, restart!
  if (pitchIndex >= (sizeof(melody) / 4)) pitchIndex = 0;
  else pitchIndex++;
}

void setTime() {
  // time setting loop, read the data from the pot
  int value = analogRead(potPin);
  int timeVal = ((int)(value / 68.5f) + 1) * 5;

  // display the set time
  displayMinSec(timeVal);
  
  // if we hit the button, start the timer!
  if (digitalRead(buttonPin) == LOW) {
      isSettingTime = false;
      endTime = millis() + (timeVal * 1000);
      tone(buzzerPin, 260, 250);
      waitForUnpressed();
  }
}

// display the current timer time
void displayTime() {
  int totalSecondsLeft = (endTime - millis()) / 1000;
  displayMinSec(totalSecondsLeft);
}

// display a given minute/second combination given a period of seconds.
void displayMinSec(int timeLeft) {
  int minLeft = timeLeft / 60; 
  int secLeft = timeLeft % 60; 
  
  // set the cursor to column 0, line 0
  lcd.setCursor(0, 0);
  lcd.print(minLeft);
  if (minLeft == 1)
    lcd.print(" minute  ");
  else
    lcd.print(" minutes ");
  
  lcd.setCursor(0, 1);
  lcd.print(secLeft);
  
  if (secLeft == 1)
    lcd.print(" second  ");
  else
    lcd.print(" seconds ");
}