Published October 12, 2017 © GPL3+

Automatic Water Source Switching And Monitoring System

In this project, we monitor cistern water level and switch to water well when needed.

AdvancedFull instructions provided8 hours3,247

Things used in this project

Hardware components

SparkFun ESP8266 Thing - Dev Board

I´ve used one SparkFun and one NodeMCU board.

Ultrasonic Sensor - HC-SR04 (Generic)

2 channel relay module (optocoupler)

Solenoid valve 220v

Transistor BC548B

Or equivalent

Resistor 10k ohm

Resistor 221 ohm

Jumper wires (generic)

5v power supply

Software apps and online services

myDevices Cayenne

Arduino IDE

Hand tools and fabrication machines

Soldering iron (generic)

Hot glue gun (generic)

Multimeter

Optional, but very useful

Story

Some time ago we started to build a country house in a rural area.

There is no city water over there, but we can source the house with a water well.

Due to our interest in water conservation, we installed a rainwater harvesting system that collects water from the rooftop and stores it in a cistern.

Rainwater stored is pumped to upper tanks in attic and it is mainly used to flush toilets. We also plan to use this water for irrigation, car washing and outside floor washing.

The house is still under construction, but now we can stay there in weekends and holydays.

One problem we faced in the first long dry spell using the house was the fact cistern ran out of water. We had to rush to install a manual system to allow source upper tanks with well water. Every time this occur, someone has to go to the attic, switch the water system and deactivate cistern water pump. When it rains again and there is enough water in cistern, the reverse manual process has to be taken, so it´s not practical.

I decided to make a system to monitor and automatically switch the upper tank source water between cistern and well water.

I´ve made a draw to illustrate the scenario and solution:

The big picture

Let´s see how this solution is made.

Part I : Cistern level monitoring

I used the distance sensor HC-SR04 and there are lots of water level monitoring projects in the internet using this sensor. My concern here is to protect it and made it durable, as this is not a water proof sensor.

Using a plastic box, make two holes for the sensor emitter-receiver

Attach the sensor to the holes and seal all borders, internal and external with hot glue

Cut a resistant plastic cup´s bottom and glue it to reinforce sensor spill protection

Connect the HC-SR04 to the ESP8266 (I used one NodeMCU that I had, you can use a SparkFun Thing Dev board for this too) - refer to section "Schematics" for connection reference

Results: all circuits protected, just emmiter-receiver exposed. (Hope this lasts for years)

Load the code (see code section) and test

1 / 4

Part II - Upper tank low water level monitoring

For this I decided to make my own sensor with digital output to ESP8266 gpio, just for fun. With a BC548B transistor, one Led and resistors it is simple and woks! (You can use another HC-SR04 or one Float Switch for this too).

Firstly, I've made a breadboard version:

When wires touches the water LED is ON

Then I´ve moved to solder the components in a perfboard, to have a reliable sensor module:

level sensor board

Again, refer to section "Schematics" below for reference. For the sensor probes, I've made with cpvc tubes, caps, one "L" curve and wires:

make 2 holes in one cap for probes, pass and glue 2 pieces of copper wire

solder a long pair of wires to the probes

the long tube section, I´ve adjust its length to signal when the water is lower than 25% tank capacity

mount the set as photos below, glue it all to make it water proof!

1 / 4 • Mounting Water Sensor probes for Upper Tank

Part III - Water switch central

Here we'll have the intelligence for automation and hardware for all needed actions.

Solder pins to your SparkFun Thing Dev Board. I´ve made with male pins, and on the top of the board, in order to not use a breadboard for connections.

1 / 3 • 3 photos

There is a very good SparkFun Tutorial for this hardware: https://learn.sparkfun.com/tutorials/esp8266-thing-development-board-hookup-guide/hardware-overview

Now you can connect all the parts (Schematics), load the code (code section)

1 / 2 • Final one in a box

Part IV - Cayenne Integration

Cayenne is the cloud platform that will provide the graphical user interface, remote access, alerts, automation monitor and manual intervention as needed.

Get started with the platform with this link: https://mydevices.com/cayenne/docs/getting-started/#getting-started

Install Cayenne libraries to your Arduino IDE:

https://mydevices.com/cayenne/docs/getting-started/#getting-started-arduino-arduino-setup-using-cayenne-arduino-library-add-cayenne-library-to-arduino-ide

Create your (free) Cayenne account, log in and click on All Devices > SparkFun ESP8266 Thing (for the Thing) or Generic (for other ESP8266).

Define one device to Cistern Monitor and one device to Water source switch. For each one, copy MQTT Username/MQTT Password/Client ID to paste in the codes. Insert your WiFi SSID and password in the codes too.

Compile each source in Arduino IDE, select Sketch > Upload to upload the sketch file to each ESP8266 device.

In Cayenne, Click Add New > Device / Widget > Custom Widgets.

Define each Widget for Cistern Monitor as follow, check the final screen:

1 / 2

Define each Widget for Water source switch:

1 / 5

Click Add New > Trigger:

1 / 3

Definitions above will work this way: when the water line is below 125 cm from distance sensor (approx.49") it will trigger cistern low. When the water line is less than 90 cm (approx.35") it will clear the alert.

With these triggers, I´ve made the integration of the two devices via Cayenne, so water source switch central is aware when cistern monitor detects it is low on water.

Video

Video: System Demo and explanations

Current field implementation

I'm still implementing this. All works great in the city, but in the rural area the internet is weak and unstable and WiFi signal has the distance attenuation.

I'll have to try other Internet providers, and maybe install a Wi-Fi repeater.

That's All

Thanks for reading and watching!

Code

#define CAYENNE_DEBUG
#define CAYENNE_PRINT Serial
#include <CayenneMQTTESP8266.h>

#define LED     2
#define TRIGGER 5
#define ECHO    4

// NodeMCU Pin D1 > TRIGGER | Pin D2 > ECHO


// WiFi network info.
char ssid[] = "";
char wifiPassword[] = "";

// Cayenne authentication info. This should be obtained from the Cayenne Dashboard.
char username[] = "";
char password[] = "";
char clientID[] = "";

unsigned long lastMillis = 0;
boolean led_st = false;

void setup() {
  Serial.begin(9600);
  Cayenne.begin(username, password, clientID, ssid, wifiPassword);
  pinMode(LED, OUTPUT);
  pinMode(TRIGGER, OUTPUT);
  pinMode(ECHO, INPUT);
  digitalWrite(LED, led_st);
}

void loop() {
  Cayenne.loop();
  
  //Publish data every 10 seconds (10000 milliseconds). Change this value to publish at a different interval.
  if (millis() - lastMillis > 3000) {
    long rssi = WiFi.RSSI();
    long duration, distance;
    digitalWrite(TRIGGER, LOW);  
    delayMicroseconds(2); 
  
    digitalWrite(TRIGGER, HIGH);
    delayMicroseconds(10); 
  
    digitalWrite(TRIGGER, LOW);
    duration = pulseIn(ECHO, HIGH);
    distance = (duration/2) / 29.1;  // distance to water level
  
    lastMillis = millis();
    
    Cayenne.virtualWrite(0, rssi);
    Cayenne.virtualWrite(1, distance, TYPE_PROXIMITY, UNIT_CENTIMETER);
    led_st = !led_st;
    digitalWrite(LED, led_st); // LED will blink each measurement
    delay(300);
  }
}

//Default function for processing actuator commands from the Cayenne Dashboard.
//You can also use functions for specific channels, e.g CAYENNE_IN(1) for channel 1 commands.
CAYENNE_IN_DEFAULT()
{
  CAYENNE_LOG("CAYENNE_IN_DEFAULT(%u) - %s, %s", request.channel, getValue.getId(), getValue.asString());
  //Process message here. If there is an error set an error message using getValue.setError(), e.g getValue.setError("Error message");
}

//#define CAYENNE_DEBUG
#define CAYENNE_PRINT Serial
#include <CayenneMQTTESP8266.h>

//Channels used
#define WiFi_RSSI 0
#define TANK_ST 4
#define PUMP_DISABLE 12
#define BACKUP_SRC 13
#define CIST_ALARM 14
#define WATER_AUTO 15
#define TIMER_VIN 16

// WiFi network info.
char ssid[] = "";
char wifiPassword[] = "";

// Cayenne authentication info. This should be obtained from the Cayenne Dashboard.
char username[] = "";
char password[] = "";
char clientID[] = "";

// define & init variables
unsigned long lastMillis = 0;
unsigned long afterTime = 0;

int tankSt = 0;
int rssi = 0;
int cist_low = 0;
int water_automation = 1;
int bkp_timer = 5;

boolean backup_active = false;

// initalize
void setup() {
  Serial.begin(9600);
  pinMode(TANK_ST, INPUT);
  pinMode(PUMP_DISABLE, OUTPUT);
  pinMode(BACKUP_SRC, OUTPUT);
  digitalWrite(PUMP_DISABLE, HIGH);
  digitalWrite(BACKUP_SRC, HIGH);
    
  Cayenne.begin(username, password, clientID, ssid, wifiPassword);
  Cayenne.virtualWrite(PUMP_DISABLE, 0);
  Cayenne.virtualWrite(BACKUP_SRC, 0);
  Cayenne.virtualWrite(CIST_ALARM, 0);
  Cayenne.virtualWrite(WATER_AUTO, 1);
}

// process
void loop() {
  Cayenne.loop();

  // process each interval
  if (millis() - lastMillis > 3000) {
    lastMillis = millis();

    rssi = WiFi.RSSI();
    Cayenne.virtualWrite(WiFi_RSSI, rssi);  
    tankSt = digitalRead(TANK_ST);
    Cayenne.virtualWrite(TANK_ST, tankSt);
    Cayenne.virtualWrite(WATER_AUTO, water_automation);
    Cayenne.virtualWrite(TIMER_VIN, bkp_timer);
    
    if (cist_low == 1 && tankSt == 0 && water_automation == 1 && !backup_active) {
      Serial.println("** Backup Water source activated **");
      digitalWrite(BACKUP_SRC, LOW);
      digitalWrite(PUMP_DISABLE, LOW);
      Cayenne.virtualWrite(PUMP_DISABLE, 1);
      Cayenne.virtualWrite(BACKUP_SRC, 1);
      Cayenne.virtualWrite(CIST_ALARM, 1);
      
      backup_active = true;
      afterTime = lastMillis + (bkp_timer * 60 * 1000); 
      if (lastMillis > afterTime) { // if the sum caused overflows
        afterTime = bkp_timer * 60 * 1000;
        lastMillis = 0;
      }
    } else {
      if (backup_active && (lastMillis > afterTime) && (cist_low == 0 || tankSt == 1)) {
        Serial.println("** Backup Water source deactivated **");
        digitalWrite(BACKUP_SRC, HIGH);
        digitalWrite(PUMP_DISABLE, HIGH);
        Cayenne.virtualWrite(PUMP_DISABLE, 0);
        Cayenne.virtualWrite(BACKUP_SRC, 0);
        if (cist_low == 0) {
          Cayenne.virtualWrite(CIST_ALARM, 0);
        }
        backup_active = false;
       }
      }
  }
    delay(300);
}

// Control cistern pump
CAYENNE_IN(12)
{
  int pump_st = getValue.asInt();
  Serial.print("** pump_st=");
  Serial.println(pump_st);
  if (pump_st == 0) {
    digitalWrite(PUMP_DISABLE, HIGH);
  } else {
    digitalWrite(PUMP_DISABLE, LOW);
  }
}

// Control backup source water solenoid
CAYENNE_IN(13)
{
  int bksrc_st = getValue.asInt();
  Serial.print("** bksrc_st=");
  Serial.println(bksrc_st);
  if (bksrc_st == 0) {
    digitalWrite(BACKUP_SRC, HIGH);
  } else {
    digitalWrite(BACKUP_SRC, LOW);
  }
}

// Cistern alarm received 
CAYENNE_IN(14)
{
  cist_low = getValue.asInt();
  Serial.print("** cist_low=");
  Serial.println(cist_low);
  Cayenne.virtualWrite(CIST_ALARM, cist_low);
}

// Water automation button
CAYENNE_IN(15)
{
  water_automation = getValue.asInt();
  Serial.print("** water_automation button=");
  Serial.println(water_automation);
  Cayenne.virtualWrite(WATER_AUTO, water_automation);
  afterTime = 0; // reset timer if active
}

// slider widget: timer value in minutes
CAYENNE_IN(16)
{
  bkp_timer = getValue.asInt();
  Serial.print("** bkp_timer=");
  Serial.println(bkp_timer);
  Cayenne.virtualWrite(TIMER_VIN, bkp_timer);
}

//Default function for processing actuator commands from the Cayenne Dashboard.
//You can also use functions for specific channels, e.g CAYENNE_IN(1) for channel 1 commands.
CAYENNE_IN_DEFAULT()
{
 CAYENNE_LOG("CAYENNE_IN_DEFAULT(%u) - %s, %s", request.channel, getValue.getId(), getValue.asString());
  //Process message here. If there is an error set an error message using getValue.setError(), e.g getValue.setError("Error message");
}

Credits

Marcos Y

0 projects • 0 followers

Maker and IT professional.

Automatic Water Source Switching And Monitoring System

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Part I : Cistern level monitoring

Part II - Upper tank low water level monitoring

Part III - Water switch central

Part IV - Cayenne Integration

Video

Current field implementation

That's All

Schematics

Cistern Level Monitoring connections

SparkFun Thing Dev connections

Low water sensor

Code

Cistern Level Monitoring

Backup water source automation

Credits

Marcos Y

Comments

Embed the widget on your own site

Automatic Water Source Switching And Monitoring System

Automatic Water Source Switching And Monitoring System

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Part I : Cistern level monitoring

Part II - Upper tank low water level monitoring

Part III - Water switch central

Part IV - Cayenne Integration

Video

Current field implementation

That's All

Schematics

Cistern Level Monitoring connections

SparkFun Thing Dev connections

Low water sensor

Code

Cistern Level Monitoring

Backup water source automation

Credits

Marcos Y

Comments

Related channels and tags