Smart WildFire Extinguisher

#include <RF24Network.h>
#include <RF24.h>

#include <OneWire.h>
#include <DallasTemperature.h>



#include <SPI.h>			//Bibloteka za SPI protokol koje NRF24 korist
#include <EEPROM.h>			//Biblioteka za EEPROM funkcije mikrokontrolera 
#include <DHT.h>            //Biblioteka za DHT senzor temperature i vlage

#define ONE_WIRE_BUS_1 2
#define DHTPIN 4
#define DHTVERZIJA DHT11	
#define CEPIN 9 
#define CSNPIN 10 
#define PROGRAMINGPIN 8 
#define RELAY 3

OneWire oneWire_in(ONE_WIRE_BUS_1);

DallasTemperature sensor_inhouse(&oneWire_in);

#define SERIALSPEED 9600



RF24 radio (CEPIN,CSNPIN);			//Kreiramo objekat radio koji prima parametre (CE pin , CSN pin)
RF24Network mreza(radio);			//Kreiramo objekat mreza kojem prosljedujemo objekat radio
DHT senzor(DHTPIN , DHTVERZIJA);	//Kreiramo objekat senzor koji prima parametre (DHTPIN  ,  DHTVERZIJA)

int adresa_trenutnog;						//Adresa ovog rutera ili end uredjaja
const uint16_t  adresa_kordinatora = 00;	//Adresa kordinatora (ESP8266)
byte sleep_interval;						//Vrijeme izmedju transmisija                
unsigned long tInterval;				   //Pomocna varijabla za tajmer
unsigned long tStart;                      //Pomocna varijabla za tajmer
bool timer = true ;						   //Bool kojim kontrolisemo interval slanja podataka	



 /* Varijable u koje spremamo sve podatke koje citamo sa senzora te ih prosljedujemo u strukturu paket i saljemo */
 
float temperatura;
float vlaga;
float indeks_topline;	


 
 
 /* Struktura koja cuva paket podataka koje saljemo kordinatoru (Node 00)  */
 
 struct paket_t
 {
	 float temperatura;			//Temperatura sa DHT11 senzora
	 float vlaga;				//Vlaga sa DHT11 senzora
	 float indeks_topline;		//Indeks topline sa DHT11 senzora
	 
 };

 

 /* Ova funkcija podesava sleep interval , izbor intervala je : 0 = 1 sec, 1 = 2 sec , 2 = 3 sec , 3 = 5 sec */
 
void podesiInterval(byte interval) 
{

	//postavljamo interval na 1 sekundu
	if(interval == 0)
	 { 
		tInterval = 1000; 
	}
	//postavljamo interval na 2 sekunde
	else if(interval == 1) 
	{ 
		tInterval = 2000;
	}
	//postavljamo interval na 3 sekunde
	else if(interval == 2)
	 {
		tInterval = 3000;
	}
	//postavljamo interval na 3 sekunde
	else 
	{
		tInterval = 5000;
	}
}



 /*	 Funkcija vraca true kada je vrijeme za slanje na osnovu postavljeni vrijednosti u EEPROM-u , a false u protivnom
     slucaju i za to vrijme dok je tajmer false mi prosljedujemo podatke od drugih nodeova prema  kordinatoru.        */

 
bool provjeriTajmer(void)
{
	unsigned long sada = millis(); // Zapocinjemo tajmer i spremamo vrjeme u varijablu sada
	if ( sada - tStart >= tInterval  ) //check to see if it is time to transmit based on set interval
	{
	 tStart = sada; // Resetujemo trenutno vrijednost tajmer na sadasnju
	 return true;
	}
	else 
	return false;
 }
 
 /*	 Funkcija koristi pointere , zahtjeva adrese koje prosljeudujemo koristeci operator '&' , a za izmjenu vrijednosti na adresi koristimo operator '*'      */
 
 void citajSenzore(float * temperatura , float * vlaga , float * indeks_topline  )
 {
	   *temperatura = senzor.readTemperature();
	   *vlaga = senzor.readHumidity();
	   *indeks_topline = senzor.computeHeatIndex(*temperatura , *vlaga , false); 
 }
 
 
		/* Ova funkcija nam omugucava programiranje nodeova putem serijske veze sa pc-om.Kada programiramo nesmjemo koristiti "Carige return " ili "Line Ending".
   U ovaj mod se ulazi tako sto se prvi put prikljuci i isprogramira node ili ukoliko pin za programiranje spojimo sa uzemljenjem.   */

void ucitajPostavke() 
{
	
	pinMode(PROGRAMINGPIN , INPUT); //Postavljamo pin za programiranje na stanje logicke jedinice , te ga postavljamo kao ulaz
	int adresa_nodea; //varijabla za spremanje adresse nodea
	byte adresa_praznog = 128; // Varijabla pomocu koje provjeravamo dali je cip bio prije programiran
	byte interval; //Vrijeme izmedju prenosa podataka
	
	//Ove stringove koristimo kako bi ustedjeli na memoriji 
	String potvrda = F("Unesi 'Y' za potvrdu ili bilo koji drugi karakter za odbijanje zahtjeva :");
	String greska  = F("Neispravan unost , postavljam na : ");
	String pitanje = F("Dali bi ste zeljeli promjeniti ");

	//Modul programiramo samoo ukoliko nije prije bio programiran ili je korisnik usao u mod za programiranje
	if(EEPROM.get(0,adresa_praznog)!= 128 || !digitalRead(PROGRAMINGPIN))
	 {
		Serial.begin(SERIALSPEED); //Zapocinjemo serijsku komunikaciju
		//Ovaj dio cita postavke trenutno spremljene u EEPROM , te ih prebacuje u lokalne varijable
		Serial.println(F("Trenutne postavke u EEPROM-u : "));
		Serial.print("Adresa node-a : ");
		Serial.println(EEPROM.get(1,adresa_nodea),OCT); 
		Serial.print("Sleep interval : ");
		Serial.println(EEPROM.get(3,interval));
		
		//Postavljanje Adrese node-a
		
		Serial.print(pitanje);
		Serial.print("adresu node-a ? ");
		Serial.println(potvrda);
			if (dajOdgovor())
			{
			Serial.println(F("Unesite novu adresu node-a :"));
			while (!Serial.available()) { }
			adresa_nodea = Serial.parseInt();
			if(adresa_nodea >= 0) {
				EEPROM.put(1, adresa_nodea);
			}
			else 
			{ 
				Serial.print(greska);
				Serial.println("01");
				adresa_nodea = 01;
				EEPROM.put(1, adresa_nodea);
			}
			}
			
		//Postavljanje vremenskog intervala node-a :
		
		Serial.print(pitanje);
		Serial.print("vremenski interval? ");
		Serial.println(potvrda);
		if(dajOdgovor()) 
		{
			Serial.println(F("Unesite : 0 za 1 sec, 1 za 2 sec, 2 za 3 sec , 3 za 5 sec"));
			while (!Serial.available()) { }
			interval = Serial.parseInt();
			if(interval >= 0 || interval < 4)
			 { 
				EEPROM.put(3, interval);
			 }
			else 
			{
				Serial.print(greska);
				Serial.println("3");
				interval = 3;
				EEPROM.put(3, interval);
			}
		}
		
		
		dajEEPROMvrjednosti(); //Sprema vrjednosti iz EEPROM-a u globalne varijable
		//Printamo vrjednosti spremljene u globalne varijable 
		Serial.print("Adresa nodea : ");
		Serial.println(adresa_trenutnog,OCT);
		Serial.print("Vremenski interval: ");
		Serial.println(sleep_interval);
		adresa_praznog = 128; //Pisemo '128' , kako nebi vise citao EEPROM kao prazan
		EEPROM.put(0, adresa_praznog);
		Serial.end(); //Prekid Serijske komunikacije
	}
	else 
	{
		//Ako nismo u modu za programiranje vadimo vrjednosti iz EEPROM-a i vracamo ih u globalne varijable
		dajEEPROMvrjednosti();
	}
}

/* Ova funkcija vraca podatke iz EEPROMA u globalne varijable na flash memoriji mikrokontrolera */

void dajEEPROMvrjednosti() 
	{
	EEPROM.get(1,adresa_trenutnog);
	EEPROM.get(3,sleep_interval);
	}

/* Ako korisnik pritisne 'Y' vraca true , za bilo koji slucaj je false */

bool dajOdgovor() 
{
	while (!Serial.available()) { }
	if(Serial.read() == 'Y')
	return true;
	else return false;
}

/* Ova funkcija vadi sleep interval i ispisuje ga na monitor */

String dajInterval() 
{
	byte i;
	EEPROM.get(3,i);
	if(i==0) 
	{
		return "1 sec";
	}
	else if (i==1) 
	{
		return ("2 sec");
	}
	else if (i==2) 
	{
		return ("3 sec");
	}
	else 
	{
		EEPROM.put(3,i);
		return ("5 sec");
	}
}

uint32_t detonated = 0;

void Detonate (void)
{
	detonated = millis();
	digitalWrite(RELAY , HIGH);
}

	
	
void setup(void)
{
	sensor_inhouse.begin();
	pinMode(RELAY,OUTPUT);
	
	digitalWrite(RELAY,LOW);
	ucitajPostavke(); //Ulazimo u mod za programiranje
	podesiInterval(sleep_interval);//Podesavamo vrijeme izmedju transmisija
	SPI.begin();	//Pocetak SPI komunikacije 
	radio.begin();	//Pocetak NRF24 komunikacije
	mreza.begin(90, adresa_trenutnog);  // Incijalizacija Mreze (prvi argument jeste kanal na kojem komuniciramo , drugi je adresa ovog modula)		
}

void loop(void)
{
	mreza.update();  // Provjerava dali ima podataka od drugih nodova za prosjljediti ka kordinatoru
	
	sensor_inhouse.requestTemperatures();
	float temp = sensor_inhouse.getTempCByIndex(0);
	Serial.println(temp);
	if(temp > 60)
		Detonate();
	if (timer) // Ako je vrijeme za slanje timer boolean je true
	{
		citajSenzore(&temperatura,&vlaga,&indeks_topline);
		paket_t paket = { temperatura , vlaga , indeks_topline  }; // Kreiramo paket za slanje
		RF24NetworkHeader header (adresa_kordinatora); //Pravimo Header koji ide u transmit paket kako bi nodovi znali na koju adresu trebaju prosljediti paket
		mreza.write(header,&paket,sizeof(paket)); //Slanje paketa
	}
	timer = provjeriTajmer(); // Osvjezavanja stanja tajmera pozivanjem funkcije provjeriTajmer koja vraca T ili F
	
}

#include <RF24.h>			//Bilbioteka za NRF24
#include <SPI.h>			//Bibloteka za SPI protokol koje NRF24 koristi
#include <RF24Network.h>	//Biblioteka za kreiranje  Mesh mreza sa NRF24

#include <ESP8266WiFi.h>
#include <ESP8266WiFiMulti.h>
#include <ESP8266HTTPClient.h>

#define CEPIN 2
#define CSNPIN 15


 struct paket_t
 {
   float temperatura;     //Temperatura sa DHT11 senzora
   float vlaga;       //Vlaga sa DHT11 senzora
   float indeks_topline;    //Indeks topline sa DHT11 senzora
   
 };

RF24 radio (CEPIN,CSNPIN);			//Kreiramo objekat radio koji prima parametre (CE pin , CSN pin)
RF24Network mreza(radio);			//Kreiramo objekat mreza kojem prosljedujemo objekat radio

ESP8266WiFiMulti WiFiMulti;

const uint16_t  adresa_kordinatora = 00;	//Adresa kordinatora (ESP8266)

void setup()
{
    Serial.begin(9600);
    Serial.println("Incijalizacija uspjesna ! ");
    SPI.begin();	//Pocetak SPI komunikacije
    radio.begin();	//Pocetak NRF24 komunikacije
    mreza.begin(90, adresa_kordinatora);  // Incijalizacija Mreze (prvi argument jeste kanal na kojem komuniciramo , drugi je adresa ovog modula)
    WiFiMulti.addAP("KPM 1", "plamenmira");

    while(WiFiMulti.run() != WL_CONNECTED) {
        Serial.print(".");
        delay(500);
    }
}



void sendUpdate(int node, paket_t packet)
{
	char getRequest[255] = "http://192.168.2.190/hak/?";
	char* last = getRequest + strlen(getRequest);
	
	strcpy(last, "temperatura=");
	last = getRequest + strlen(getRequest);
	dtostrf(packet.temperatura, 255 - strlen(getRequest), 2, last);
	
	last = getRequest + strlen(getRequest);
	strcpy(last, "&vlaga=");
	last = getRequest + strlen(getRequest);
	dtostrf(packet.vlaga, 255 - strlen(getRequest), 2, last);
	
	last = getRequest + strlen(getRequest);
	strcpy(last, "&indeks_topline=");
	last = getRequest + strlen(getRequest);
	dtostrf(packet.indeks_topline, 255 - strlen(getRequest), 2, last);
	
	last = getRequest + strlen(getRequest);
	strcpy(last, "&node=");
	last = getRequest + strlen(getRequest);
	sprintf(last, "%d", node);
	
	HTTPClient http;
	http.begin(getRequest); //HTTP
	Serial.println(getRequest);
	int httpCode = http.GET();

	// httpCode will be negative on error
	if(httpCode > 0) {
		// HTTP header has been send and Server response header has been handled
		Serial.print("[HTTP] GET... code: ");
		Serial.println(httpCode);
	}

	http.end();
}



void loop()
{
	mreza.update();  // Provjerava dali ima podataka od drugih nodova 
	paket_t paket; // Kreiramo objekat paket
	RF24NetworkHeader header; //Pravimo Header varijablu1

	if (mreza.available())
	{
		mreza.read(header,&paket,sizeof(paket));
		sendUpdate(header.from_node, paket);
	}
 }