Harry's Horn

#include <ESP8266WiFi.h>
#include <Ticker.h>
#include <AsyncMqttClient.h>

#include "networkConfig.h"
#include "mqttConfig.h"
#include "arduinoConfig.h"

///////
// pin assignments

#define PIEZO_PIN       D1_PIN

AsyncMqttClient mqttClient;
Ticker mqttReconnectTimer;

WiFiEventHandler wifiConnectHandler;
WiFiEventHandler wifiDisconnectHandler;
Ticker wifiReconnectTimer;

// WIFI and MQTT stuff
char    macAddressTopic[64];  // used to associate MAC address with function
char    locationTopic[64];    // used to associate function with house location
char    clientId[64];         // MQTT client id
uint8_t MAC_array[6];
char    MAC_char[18];

/////////////////////////////////////////////////////////////////////////////
// WIFI STUFF
///////

void connectToWifi() {
  Serial.println("Connecting to Wi-Fi...");
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
}

void onWifiConnect(const WiFiEventStationModeGotIP& event) {
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  WiFi.macAddress(MAC_array);
  for (int i = 0; i < sizeof(MAC_array); ++i) {
    sprintf(MAC_char, "%s%02x:", MAC_char, MAC_array[i]);
  }
  sprintf(macAddressTopic, "diyhas/esp_%02x%02x%02x", MAC_array[3], MAC_array[4], MAC_array[5]);
  sprintf(clientId, "ESP_%02X%02X%02X", MAC_array[3], MAC_array[4], MAC_array[5]);
  Serial.print("topic="); Serial.println(macAddressTopic);
  Serial.print("clientId="); Serial.println(clientId);

  connectToMqtt();
}

void onWifiDisconnect(const WiFiEventStationModeDisconnected& event) {
  Serial.println("Disconnected from Wi-Fi.");
  mqttReconnectTimer.detach(); // ensure we don't reconnect to MQTT while reconnecting to Wi-Fi
  wifiReconnectTimer.once(2, connectToWifi);
}

/////////////////////////////////////////////////////////////////////////////
// MQTT STUFF
///////

void connectToMqtt() {
  Serial.println("Connecting to MQTT...");
  mqttClient.connect();
}

void onMqttConnect(bool sessionPresent) {
  Serial.println("Connected to MQTT.");
  Serial.print("Session present: ");
  Serial.println(sessionPresent);
  uint16_t packetIdSub = mqttClient.subscribe(macAddressTopic, 2);
}

void onMqttDisconnect(AsyncMqttClientDisconnectReason reason) {
  Serial.println("Disconnected from MQTT.");

  if (WiFi.isConnected()) {
    mqttReconnectTimer.once(2, connectToMqtt);
  }
}

void onMqttSubscribe(uint16_t packetId, uint8_t qos) {
}

void onMqttUnsubscribe(uint16_t packetId) {
}

void onMqttMessage(char* topic, char* payload, AsyncMqttClientMessageProperties properties, size_t len, size_t index, size_t total) {
  Serial.println("Publish received.");
  if (strcmp((char *)topic, macAddressTopic) == 0) {
    Serial.print("topic="); Serial.print(topic);
    Serial.print("\tpayload="); Serial.println(payload);
    Serial.print("\tlen="); Serial.println(len);
    payload[len] = 0;
    setupTopics(payload);
  } else if (strcmp((char *)topic, "diyhas/system/panic") == 0) {
    if (strncmp((char *)payload, "ON", 2) == 0) {
      Serial.println("panic ON!");
      digitalWrite(PIEZO_PIN, HIGH);
    } else {
      Serial.println("panic OFF!");
      digitalWrite(PIEZO_PIN, LOW);
    }
  } else if (strcmp((char *)topic, "diyhas/system/fire") == 0) {
    if (strncmp((char *)payload, "ON", 2) == 0) {
      Serial.println("fire ON!");
      digitalWrite(PIEZO_PIN, HIGH);
    } else {
      Serial.println("fire OFF!");
      digitalWrite(PIEZO_PIN, LOW);
    }
  }
}

void onMqttPublish(uint16_t packetId) {
}

void setupMqtt() {
  mqttClient.onConnect(onMqttConnect);
  mqttClient.onDisconnect(onMqttDisconnect);
  mqttClient.onSubscribe(onMqttSubscribe);
  mqttClient.onUnsubscribe(onMqttUnsubscribe);
  mqttClient.onMessage(onMqttMessage);
  mqttClient.onPublish(onMqttPublish);
  mqttClient.setServer(MQTT_HOST, MQTT_PORT);
}

void setupTopics(char *payload) {
  sprintf(locationTopic, "%s/alarm", payload);
  Serial.print("setup topics: location=> "); Serial.println(locationTopic);
  for (int i = 0; i < MQTT_TOPICS; i++) {
    mqttClient.subscribe(mqttTopics[i], 2);
  }
}

/////////////////////////////////////////////////////////////////////////////
// SETUP INITIALIZATION
///////

void setup() {
  Serial.begin(115200);
  Serial.println();Serial.println();
  Serial.println("Source:   EspAlarmV2");
  Serial.println("Platform: ESP8266 WEMOS D1 Pro Mini");

  pinMode(PIEZO_PIN, OUTPUT);
  digitalWrite(PIEZO_PIN, LOW);

  // start tasks to handle acync messaging

  wifiConnectHandler = WiFi.onStationModeGotIP(onWifiConnect);
  wifiDisconnectHandler = WiFi.onStationModeDisconnected(onWifiDisconnect);

  // prepare MQTT services and event handlers

  setupMqtt();
  Serial.println("MQTT setup");

  // start WiFi

  connectToWifi();

  // wait for connection and initalization messages from the MQTT Broker

  while (locationTopic[0] == 0) {
    delay(100);
  }
}

/////////////////////////////////////////////////////////////////////////////
// MAIN PROCESSING
///////

void loop() {
}