Published November 2, 2021 © CC BY-NC-ND

Halloween Shield

The night before a Halloween party I thought - wouldn't it be cool to add a sound-responsive element to my costume?

BeginnerFull instructions provided2 hours369

Things used in this project

Hardware components

Arduino UNO

ElectroPeak MAX7219 8x8 Dot Matrix Display Module

ElectroPeak KY-037 Sound Detection Sensor Module

5 mm LED: Green

ElectroPeak Switch Push Button with Cap

Samsung 10,000mAh Ultra Battery pack

Elegoo A soldering PCB (5X7cm)

Hand tools and fabrication machines

Soldering iron (generic)

Solder Wire, Lead Free

Story

The Prelude

Preparing for a student "Fancy Dress" party can be a real challenge. I always struggle with finding an original and fun costume, as the majority of my ideas end up too generic, not achievable with my make-up skills, or most likely both.

This Halloween wasn't an exception. But the night of October 30th it dawned on me: I have an Arduino and a ton of LEDs in my electronics box. Thematic Fairy Lights always improve a party costume, and by adding a little sound sensor we can spice this idea up a little.

After a quick proof-of-concept with a single white LED and a tiny breadboard, I decided to design a shield for my Arduino Uno to make a relatively little and super-wavy festive accessory.

The Solder

The prototyping shield from my Elegoo Starter Kit wasn't big enough to fit all the components, so I designed a custom one instead. With a soldering iron, a 5X7cm generic PCB and some spare pins, it takes a few minutes to make a shield that sits perfectly on top of the Arduino Uno and connects to D0-D7, A0-A5, GND and 5V pins.

Figure 1. The main ingredients to making a custom prototyping shield (soldering iron omitted). I found it easiest to stick the barrette strip into the Arduino pins, position the PCB on top and then solder the through holes.

Unfortunately, the D8-D13 pins were slightly misaligned with the through-holes on my PCB, so I could not access them.

After a few hours of late-night soldering, the "Halloween Shield" assumed its final form, sporting the following components and pin connections:

8x8 LED Matrix (D5-D7)

Sound Sensor (A0, A1)

Two green LEDs (D2, D3)

Push button (D4)

1 / 2 • Figures 2. The top of the "Halloween Shield". The diamond sticker on top of the sound sensor module is the most crucial detail.

As a soldering amateur, I produced something in-between a work of art and an engineer's nightmare. But if it works, it works!

The Program

Perhaps due to my fabled electronics skill, or maybe because of the component quality, the sound sensor did not comply. I could easily change the baseline of the analog output by rotating the potentiometer; however, I couldn't find a perfect signal-to-noise ratio.

As the result, this left me with a relatively narrow " therapeutic window" for discerning the ambient sounds from the background noise. Finding a perfect potentiometer position was quite complicated - I had to hit the interval of about 15 degrees - so I programmed the two LEDs to light up when I am in the correct range (from the bottom and from the top).

Figure 4. Sound sensor analog output in response to my coughing with baseline at 540.

Seemingly, a lower baseline results in higher sensitivity, so feel free to play with the values to find your perfect thresholds.

Now, there is no point using a LED matrix if you don't throw a few fun sprites into your algorithm. Since putting a microphone face-to-face with a laptop speaker isn't a perfect recreation of a night out's ambience, I wasn't certain whether my sound sensor will behave itself.

To stay on the safe side, I made two types of animations. Type I has a "passive" and an "active" phase: one is always running (e.g. moving mouth), and the other is sound-triggered (e.g. blinking). Type II only responds to sound, because I was running out of time.

The "Halloween shield" offers you to cycle through animations by pressing the button. The script regularly checks for the input; however, the cycle of the current animation has to end before the sprite is changed.

Here is a quick demo:

Figure 5. ASMR clapping and animations showcase.

The Endshpil

Despite the capricious sound sensor, it took minimal tuning with a guitar pick to achieve the desired effect. My posthoc observations conclude:

1. The sound module best responds to loud bass, especially when you get closer to the DJ booth.

2. People in the bar queue will almost certainly bend the microphone to the point of breaking. Who would've thought?

3. It looks pretty cool with a suit and a soda:

Figure 6. Proof that the "Halloween Shield" looks cool with a suit and a soda.

Tell me know what you think below!

Especially if you see any rookie mistakes and/or improvements that can be made to the project. :)

Code

Halloween Shield Code

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||       Defining the shield pinout        ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

// LED matrix module
#include "LedControl.h"   
int DIN = 5;
int CS = 6; 
int CLK = 7; 
LedControl display=LedControl(DIN,CLK,CS,1);

// Sound sensor module
int sensorAnalogPin = A0;    // Select the pin for the Sound Sensor's analog output 
int analogValue = 0;
int baseline = 540;         // Pick a baseline with decent signal-to-noise ratio 
int signal_interval = 10;   // Minimal deviation from the baseline to be considered signal (not background noise) 
int sensorDigitalPin = A1;  // Select the pin for the Sound Sensor's digital output
// Using an analog pin due to the custom shield limitations >_<

// Other elements
int LED_1 = 2;
int LED_2 = 3;
int button = 4;

// Other variables
int operationMode = 0;      // Current animation's ID
const int modeMax = 3;      // Total number of animations - 1
bool buttonState = HIGH;
bool soundSignal = HIGH;    // Holding the sound signal until an appropriate moment in the program cycle

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||          Analog signal filter           ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

// A simple filter returning an average of several analogRead() values
int filteredAnalog (int counter = 10, int filterDelay = 0.1) {
  int analogPot = 0;
  for (int i = 0; i<(counter-1); i++){
    analogPot = analogPot + analogRead(sensorAnalogPin);
    delay(filterDelay);
  }
  return(analogPot/counter);
}

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||            Debug functions              ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */
 
void serialDebug(){
  Serial.print(baseline);
  Serial.print(" ");
  Serial.print(baseline + signal_interval);
  Serial.print(" ");
  Serial.print(baseline - signal_interval);
  Serial.print(" ");
  Serial.println(filteredAnalog());
}

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||          Button control cycle           ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

// For cycling through the animations
void buttonCheck (){
  bool buttonStateNew = digitalRead (button);
  if (buttonStateNew != buttonState){
    buttonState = buttonStateNew;
    if (buttonState == LOW){ 
      if (operationMode < modeMax){operationMode++;}
      else {operationMode = 0;}
    }}
    }

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||         Sound input mini-cycles        ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */
 
void soundCheck (){
  // Check buttons & send signal every time you check sound
  buttonCheck ();
  //serialDebug ();
  
  // Read the value of the analog interface A0 assigned to analogValue 
  analogValue = filteredAnalog();

  // At what volume do the animation and LEDs react?
  if (analogValue >= (baseline + signal_interval) /*|| analogValue <= (baseline - signal_interval)*/){
    // A double threshold (above & below the baseline) may improve responsiveness to certain noises
    soundSignal = LOW;
  }
  if (analogValue > (baseline + signal_interval)){digitalWrite(LED_1, LOW);}
  else {digitalWrite(LED_1, HIGH);}
  if (analogValue < (baseline - signal_interval)){digitalWrite(LED_2, LOW);}
  else {digitalWrite(LED_2, HIGH);}}

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||       Matrix display functions          ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

void displayImage(uint64_t image) {
  for (int i = 0; i < 8; i++) {
    byte row = (image >> i * 8) & 0xFF;
    for (int j = 0; j < 8; j++) {
      display.setLed(0, i, j, bitRead(row, j));
    }}}

void displayAnimation (uint64_t animation [], uint8_t start_i = 0, uint8_t end_i = 3, uint8_t animation_delay = 0) {
    for (int i = start_i; i <= end_i; i++){
      displayImage (animation [i]);
      int timer = 0;
      while (timer != animation_delay){
        delay (1);
        timer ++;
        soundCheck ();
      }
    }}

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||          Angry Face animation           ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

// Has both sounds-responsive and passive animation

const uint64_t angryFace[] = {
  0x00dd7700e7e7c381,
  0x00eebb00e7e7c381,
  0x0077dd00e7e7c381,
  0x00bbee00e7e7c381};

const uint64_t angryBlink_3[] = {
  0x00bbee00e7e70000,
  0x00bbee00e7000000,
  0x00bbee0000000000,
  0x00bbee00e7e70000};
  
const uint64_t angryBlink_2[] = {
  0x0077dd00e7e70000,
  0x0077dd00e7000000,
  0x0077dd0000000000,
  0x0077dd00e7e70000};
  
const uint64_t angryBlink_1[] = {
  0x00eebb00e7e70000,
  0x00eebb00e7000000,
  0x00eebb0000000000,
  0x00eebb00e7e70000};
  
const uint64_t angryBlink_0[] = {
  0x00dd7700e7e70000,
  0x00dd7700e7000000,
  0x00dd770000000000,
  0x00dd7700e7e70000};

// Allows "interruption" of the passive animation whenever soundSignal == HIGH with an appropriate 
// soound-responsive animation cycle
void responsive_angryFace (uint8_t start_i = 0, uint8_t end_i = 3, uint8_t animation_delay = 300) {
  for (int i = start_i; i <= end_i; i++){
    soundCheck ();
    if (soundSignal == LOW){ 
      switch (i) {
        case 0:
          displayAnimation(angryBlink_0, 0, 3, animation_delay/4);
          break;
        case 1:
          displayAnimation(angryBlink_1, 0, 3, animation_delay/4);
          break;
        case 2:
          displayAnimation(angryBlink_2, 0, 3, animation_delay/4);
          break;
        case 3:
          displayAnimation(angryBlink_3, 0, 3, animation_delay/4);
          break;
      }
      soundSignal = HIGH;;  
    }
    else {
      int timer = 0;
      while (timer != animation_delay){
        delay (1);
        timer ++;
        soundCheck ();
      }}
    displayImage(angryFace [i]);
  }}

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||            Ghost animation              ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

// Has both sounds-responsive and passive animation

const uint64_t ghost[] = {
  0xa5ffffff99997e3c,
  0xa5ffffff99ff7e3c,
  0xa5ffff99ffff7e3c,
  0xa5ffffff99ff7e3c};

const uint64_t ghost_0[] = {
  0xa5fff1ff99997e3c,
  0xa5ffe3ff99997e3c,
  0xa5ffc7ff99997e3c,
  0xa5ff8fff99997e3c};


const uint64_t ghost_1[] = {
  0xa5fff1ffff997e3c,
  0xa5ffe3ffff997e3c,
  0xa5ffc7ffff997e3c,
  0xa5ff8fffff997e3c};


const uint64_t ghost_2[] = {
  0xa5fff1ffffff7e3c,
  0xa5ffe3ffffff7e3c,
  0xa5ffc7ffffff7e3c,
  0xa5ff8fffffff7e3c};

// Allows "interruption" of the passive animation whenever soundSignal == HIGH with an appropriate 
// soound-responsive animation cycle
void responsive_ghost (uint8_t start_i = 0, uint8_t end_i = 3, uint8_t animation_delay = 500) {
  for (int i = start_i; i <= end_i; i++){
    soundCheck ();
    if (soundSignal == LOW){ 
      switch (i) {
        case 0:
          displayAnimation(ghost_0, 0, 3, animation_delay/5);
          break;
        case 1:
          displayAnimation(ghost_1, 0, 3, animation_delay/5);
          break;
        case 2:
          // No animation in this case
          break;
        case 3:
          displayAnimation(ghost_1, 0, 3, animation_delay/5);
          break;
      }
      soundSignal = HIGH;;  
    }
    else {
      int timer = 0;
      while (timer != animation_delay){
        delay (1);
        timer ++;
        soundCheck ();
      }}
    displayImage(ghost [i]);
  }}

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||            PacMan animation             ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

// A sound-responsive animation only

const uint64_t pacman [] = {
  0x3c7eff0ffffb7e3c,
  0x3c7e3f1f1f3b7e3c,
  0x3c7eff0ffffb7e3c,
  0x3c7eff0ff3f37e3c};

void responsive_pacman (uint8_t animation_delay = 250) {
  soundCheck ();
  if (soundSignal == LOW){ 
    displayAnimation(pacman, 0, 3, animation_delay);
    soundSignal = HIGH;;  
    }
  else {
    displayImage(pacman [0]);
    }}

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||          Heartbeat animation            ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

// A sound-responsive animation only

const uint64_t heart_empty [] = {
  0x183c7effffff6600,
  0x183c66e7ffff6600,
  0x183c66c3dbff6600,
  0x1824428181996600};

const uint64_t heart_fill [] = {
  0x1824428181996600,
  0x183c66c3dbff6600,
  0x183c66e7ffff6600,
  0x183c7effffff6600};

void responsive_heart (uint8_t animation_delay = 50) {
  soundCheck ();
  if (soundSignal == LOW){ 
    displayAnimation(heart_empty, 0, 3, animation_delay);
    displayAnimation(heart_fill, 0, 3, animation_delay);
    soundSignal = HIGH;;  
    }
  else {
    displayImage(heart_empty [0]);
    }}

/*  |||||||||||||||||||||||||||||||||||||||||||||||||||||
 *  ||||||         The main program body           ||||||
 *  ||||||||||||||||||||||||||||||||||||||||||||||||||||| */

void setup(){
  // Wake up, initialise and clear the LED matrix on startup
  display.shutdown(0,false);
  display.setIntensity(0,0.5);
  display.clearDisplay(0);
  pinMode (button, INPUT_PULLUP);
  digitalWrite(LED_1, LOW);
  digitalWrite(LED_2, LOW);
  // Not used in this version of the script:
  // pinMode (sensorDigitalPin, INPUT);
  // Serial.begin(9600);
}

void loop(){
  // serialDebug ();
  switch(operationMode){
    case 0:
      responsive_angryFace ();
      break;
    case 1:
      responsive_ghost ();
      break;
    case 2:
      responsive_pacman ();
      break;
    case 3:
      responsive_heart ();
      break;
  }}

Credits

Tommy Bianco

5 projects • 1 follower

A biologist procrastinating