Published January 28, 2021 © GPL3+

Tic Tac Toe on a Business Card

A business card that can play the classic game of Tic Tac Toe.

AdvancedWork in progress3 hours8,986

Things used in this project

Hardware components

Microchip ATmega328

0603 SMD LED

9x Blue and 9x Red

0603 Resistors

2x 10k ohm, 19x 1k ohm

0603 Capacitors

1x 10uF, 2x 0.1uF (for decoupling capacitors)

USB Connector, Micro USB Type B

SMD Button

16MHz SMD Ceramic Resonator

Software apps and online services

Arduino IDE

Autodesk EAGLE

Story

About

With the internship application season in full swing, I decided to make some PCB business cards that I can give away to hopefully stand out from the crowd. This card specifically plays the classic game of tic tac toe.

Like normal Tic-Tac-Toe, there is a grid with 9 positions that a player can place their mark. One player is Blue and the other player is Red instead of the traditional X and O. Your current position is marked by a blinking blue or red LED. Pressing the button quickly will move you to a new position. Once you are at the desired position, you press and hold the button to place their mark and the turn moves to the other player. The first player to get three marks in a row wins.

The card is set to 2-player mode, but there is also a single-player mode that the user can activate by pressing and holding the main button for more than 5 seconds. The display will show a "1" to indicate single-player mode. To switch back to 2-player mode, the user just has to press the main button again for 5 seconds. The display will then show a "2" to indicate 2-player mode.

Video

Part 2:

Here is a video of the most recent version of the card with the fixes from Part 1:

Part 1:

The Design

The display is made up of 18 LEDs organized into 9 segments where there is a blue and red LED in each segment. There is a single button that the player uses to control where they will place their mark. There is also a micro-USB port that is used to power the card.

An ATmega328P-AU in a TQFP package is used as the brains to control everything. It is bootloaded with the Arduino Uno bootloader since I found that to be the most convenient and low-cost way to program it (although there are other ways to do it).

I have attached the Schematics and Code in case you are curious about how it works and would like to make your own. It includes the fixes discussed in the video. However, I did not include the Board Design because I believe business cards should be unique and reflect your own style.

Instructions

Hardware Instructions:

1.) Build or download the schematic found in the Schematic section at the bottom of the page in your preferred EDA program (I used Autodesk EAGLE).

2.) Route the board. Have fun designing it and make it unique!

3.) Export the Gerber file and send it to a PCB manufacturer (preferably one that offers SMD assembly) to get it produced (I used JLCPCB).

Software Instructions:

I used an Arduino Uno to program my card, but there are other methods that may be easier. To use the same method I used, follow these steps (here is a more in-depth tutorial from Arduino):

4.) Wire the card for Bootloading. To do this, connect pins 10, 11, 12, and 13 on the Arduino Uno to pins RST, PB3, PB4, and PB5 on the card respectively. Also connect the Arduino's 5V and GND to the card's 5V and GND.

5.) Upload the Arduino ISP to the Arduino Uno and burn the Bootloader. To do this, open the Arduino IDE, and open File > Examples > ArduinoISP > ArduinoISP. This will open a sketch. Upload this to your Arduino Uno. Next, burn the Bootloader by going to Tools > Burn Bootloader.

6.) Wire the card for Programming. To do this, first remove the ATMega328P chip from the Arduino Uno using a screwdriver (remember to put the chip back when you're done!). Next, connect the Arduino's RX to the card's TX and the Arduino's TX to the card's RX. Also connect the Arduino's 5V and GND to the card's 5V and GND.

7.) Upload the Tic-Tac-Toe code to the card. To do this, download the code from the Code section and press the upload button in the Arduino IDE.

Code

Business Card Tic Tac Toe Code

int playerBlue[9][2] = {{A0,0},{A2,0},{A4,0}, //{pin number, marked (0=empty, 1=marked)}
                        {0,0},{2,0},{4,0},
                        {6,0},{8,0},{10,0}}; 
int playerRed[9][2] = {{A1,0},{A3,0},{A5,0}, //{pin number, marked (0=empty, 1=marked)}
                       {1,0},{3,0},{5,0},
                       {7,0},{9,0},{11,0}}; 

const int controlButtonPin = 13;

int currentPosition = 0;

int setPositions = 0; // used to see if the board is completely filled

short turn = 0; // 0 = blue's turn, 1 = red's turn

boolean singlePlayer = false;

void setup() {
  randomSeed(analogRead(A7));
  pinMode(0,OUTPUT);
  pinMode(1,OUTPUT);
}

void loop() {
  checkWinner();
  
  int buttonHoldTime = 0;

  while(digitalRead(controlButtonPin)){
    buttonHoldTime++;
    delay(1);
  }

  if(buttonHoldTime > 1 && buttonHoldTime < 250){
    nextPosition();
  }else if(buttonHoldTime >= 250 && buttonHoldTime <= 5000){
    setPositions ++;
    setPosition();
    nextPosition();

    if(singlePlayer){
      computerMove();
    }
  }else if(buttonHoldTime > 5000){
    singlePlayer = !singlePlayer;
    resetGame();
    displayMode();
  }else{
    displaySetPositions();
    blinkCurrentPosition();
  }
}

void nextPosition(){
  checkWinner();
  
  boolean positionDecided = false;

  while(!positionDecided){
    currentPosition ++;
    if(currentPosition > 8){
      currentPosition = 0;  
    }
    
    if(playerBlue[currentPosition][1] == 0 && playerRed[currentPosition][1] == 0){
      positionDecided = true;
    }
  }
}

void setPosition(){
  if(turn == 0){
    playerBlue[currentPosition][1] = 1;
    turn = 1;
  }else{
    playerRed[currentPosition][1] = 1;
    turn = 0;
  }
}

void blinkCurrentPosition() {
  if(turn == 0){ //when it's blue's turn
    digitalWrite(playerBlue[currentPosition][0], HIGH);
    delay(100);
    digitalWrite(playerBlue[currentPosition][0], LOW);
    delay(100);
  }else{
    digitalWrite(playerRed[currentPosition][0], HIGH);
    delay(100);
    digitalWrite(playerRed[currentPosition][0], LOW);
    delay(100);
  }
}

void displaySetPositions(){
  for(int i = 0; i < 9; i++){
    digitalWrite(playerBlue[i][0],playerBlue[i][1]);  
    digitalWrite(playerRed[i][0],playerRed[i][1]);  
  }  
}

void resetGame(){
  for(int i = 0; i < 9; i++){
    playerBlue[i][1] = 0;
    playerRed[i][1] = 0;  
  }  

  currentPosition = 0;
  setPositions = 0;
  turn = 0;
}

void displayMode(){
  if(singlePlayer){
    PORTB = B00000011;
    PORTC = B00001100;
    PORTD = B00001100;
  }else{
    PORTB = B00001011;
    PORTC = B00110100;
    PORTD = B00011100;
  }
  delay(2000);

  PORTB = B00000000;
  PORTC = B00000000;
  PORTD = B00000000;
}

void computerMove(){
  for(int i = 0; i < random(9); i++){
    nextPosition();
  }
  setPosition();
  nextPosition();
}

void checkWinner(){
  boolean blue = false;
  boolean red = false;
  boolean gameEnd = false;
  
  // this is VERY sloppy. I plan to make a better algorithm soon
  if((playerBlue[0][1] == 1 && playerBlue[1][1] == 1 && playerBlue[2][1] == 1) ||
     (playerBlue[3][1] == 1 && playerBlue[4][1] == 1 && playerBlue[5][1] == 1) ||
     (playerBlue[6][1] == 1 && playerBlue[7][1] == 1 && playerBlue[8][1] == 1) ||
     (playerBlue[0][1] == 1 && playerBlue[3][1] == 1 && playerBlue[6][1] == 1) ||
     (playerBlue[1][1] == 1 && playerBlue[4][1] == 1 && playerBlue[7][1] == 1) ||
     (playerBlue[2][1] == 1 && playerBlue[5][1] == 1 && playerBlue[8][1] == 1) ||
     (playerBlue[0][1] == 1 && playerBlue[4][1] == 1 && playerBlue[8][1] == 1) ||
     (playerBlue[2][1] == 1 && playerBlue[4][1] == 1 && playerBlue[6][1] == 1))
  {
    blue = true;
    gameEnd = true;
  }
  else if((playerRed[0][1] == 1 && playerRed[1][1] == 1 && playerRed[2][1] == 1) ||
     (playerRed[3][1] == 1 && playerRed[4][1] == 1 && playerRed[5][1] == 1) ||
     (playerRed[6][1] == 1 && playerRed[7][1] == 1 && playerRed[8][1] == 1) ||
     (playerRed[0][1] == 1 && playerRed[3][1] == 1 && playerRed[6][1] == 1) ||
     (playerRed[1][1] == 1 && playerRed[4][1] == 1 && playerRed[7][1] == 1) ||
     (playerRed[2][1] == 1 && playerRed[5][1] == 1 && playerRed[8][1] == 1) ||
     (playerRed[0][1] == 1 && playerRed[4][1] == 1 && playerRed[8][1] == 1) ||
     (playerRed[2][1] == 1 && playerRed[4][1] == 1 && playerRed[6][1] == 1))
  {
    red = true;
    gameEnd = true;
  }

  if(setPositions > 8){
    blue = true;
    red = true;
    gameEnd = true;  
  }
  
  if(gameEnd){
    for(int j = 0; j < 5; j++){
        for(int i = 0; i < 9; i++){
          digitalWrite(playerBlue[i][0],blue);
          digitalWrite(playerRed[i][0],red);
        }
        delay(500);
        
        for(int i = 0; i < 9; i++){
          digitalWrite(playerBlue[i][0],LOW);
          digitalWrite(playerRed[i][0],LOW);
        }
        delay(500);
      }
      resetGame();
  }
}

Credits

Ryan Chan

9 projects • 231 followers

I like turtles. I also like robots.

Tic Tac Toe on a Business Card

Things used in this project

Hardware components

Software apps and online services

Story

About

Video

The Design

Instructions

Schematics

Business Card Schematic

Tic Tac Toe EAGLE schematic

Code

Business Card Tic Tac Toe Code

Credits

Ryan Chan

Comments

Embed the widget on your own site

Tic Tac Toe on a Business Card

Tic Tac Toe on a Business Card

Things used in this project

Hardware components

Software apps and online services

Story

About

Video

The Design

Instructions

Schematics

Business Card Schematic

Tic Tac Toe EAGLE schematic

Code

Business Card Tic Tac Toe Code

Credits

Ryan Chan

Comments

Related channels and tags