IoT temperature and humidity meter with OLED screen

// IoT humidity and temperature meter with Oled screen
// I used some code from Adafruit IO example.

// Adafruit IO Analog In Example
// Tutorial Link: https://learn.adafruit.com/adafruit-io-basics-analog-input
//
// Adafruit invests time and resources providing this open source code.
// Please support Adafruit and open source hardware by purchasing
// products from Adafruit!
//
// Written by Todd Treece for Adafruit Industries
// Copyright (c) 2016 Adafruit Industries
// Licensed under the MIT license.
//
// All text above must be included in any redistribution.

/************************** Configuration ***********************************/

// edit the config.h tab and enter your Adafruit IO credentials
// and any additional configuration needed for WiFi, cellular,
// or ethernet clients.
#include "config.h"
#include <DHT.h>                // DHT11 library
#include <Wire.h>               // I2C library
#include <Adafruit_GFX.h>       // Graphic library
#include <Adafruit_SSD1306.h>   // Monochrome OLEDs SSD1306 drivers librarry

/************************ Example Starts Here *******************************/

// Use GPIO1 connected to the DHT11 sensor.
#define DHTPIN 1
// Select sensor type. In this case is DHT11. You can also use DHT22.
#define DHTTYPE DHT11

// Set our screen size.
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 32 // OLED display height, in pixels

// Set screen values.
#define OLED_RESET     -1 // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// Variables
int current_temp = 0;
int last_temp = -1;

int current_hum = 0;
int last_hum = -1;

// Initialize DHT sensor
DHT dht(DHTPIN, DHTTYPE);

// set up the temperature, humidity and heat index feeds.
AdafruitIO_Feed *temp_feed = io.feed("temp_feed");
AdafruitIO_Feed *hum_feed = io.feed("hum_feed");
AdafruitIO_Feed *st_feed = io.feed("st_feed");


void setup() {

  // start the serial connection
  Serial.begin(115200);

  
  dht.begin();

  // wait for serial monitor to open
  while(! Serial);

  // connect to io.adafruit.com
  Serial.print("Connecting to Adafruit IO");
  io.connect();

  // wait for a connection
  while(io.status() < AIO_CONNECTED) {
    Serial.print(".");
    delay(500);
  }

  // we are connected
  Serial.println();
  Serial.println(io.statusText());

  //Set I2C screen pins
  Wire.begin(2, 0); // GPIO2 => SDA, GPIO0 => SCL 

  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // Address 0x3C for 128x32
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }

    delay(2000); // Pause for 2 seconds

  // Clear the buffer
  display.clearDisplay();

  // Set text size and color.
  display.setTextSize(1);
  display.setTextColor(WHITE);
  
  
}

void loop() {

  //Show a initial message on the screen.
  display.clearDisplay();
  display.setCursor(0, 10);
  display.println("IoT temp & hum meter");
  display.println("www.rjconcepcion.com");
  display.display();
  

  // io.run(); is required for all sketches.
  // it should always be present at the top of your loop
  // function. it keeps the client connected to
  // io.adafruit.com, and processes any incoming data.
  io.run();

  // Get humidity value
  float hum = dht.readHumidity();
  // Get temperature value
  float temp = dht.readTemperature();
  // Calculate heat index
  float st = dht.computeHeatIndex(temp, hum, false);

  // wait for 15 seconds
  delay(15000);
 

  // Check for reading measures
  if (isnan(hum) || isnan(temp)){
    Serial.println("Error en obtener los datos ");
    return;
  }

  // Store current values.
  current_temp = temp;
  current_hum = hum;
  
  // return if the value hasn't changed
  if((current_temp == last_temp) && (current_hum == last_hum))
    return;

  // Send the feeds to Adafruit IO
  temp_feed->save(current_temp);
  hum_feed->save(current_hum);
  st_feed->save(st);

  // Store last values.
  last_temp = current_temp;
  last_hum = current_hum;

  // Show temperature value on the screen 
  display.clearDisplay();
  display.setCursor(0, 10);
  display.println("Temperatura: ");
  display.print(temp);
  display.println(" *C ");
  display.display();
  delay(15000); 

  // Show humidity value on the screen
  display.clearDisplay();
  display.setCursor(0, 10);
  display.println("Humedad: ");
  display.print(hum);
  display.println(" %\t");
  display.display();
  delay(15000);  

  // Show heat index value on the screen
  display.clearDisplay();
  display.setCursor(0, 10);
  display.println("Sensacion Termica: ");
  display.print(st);
  display.println(" *C");
  display.display(); 
  delay(15000); 

}