ESP32 + SHT40: Remote Temp & Humidity Monitoring to Google S

#include <WiFi.h>
#include <HTTPClient.h>
#include <Wire.h>
#include <SensirionI2cSht4x.h>
#define NO_ERROR 0

const char* ssid = "Enter Your WiFi SSID";
const char* password = "Enter Your WiFi Passcode";
const char* scriptURL = "Enter your google sheet deploy URL";

SensirionI2cSht4x sensor;

static char errorMessage[64];
static int16_t error;

void setup() {
  Serial.begin(115200);
  while (!Serial) {
    delay(100);
  }

  Wire.begin();
  sensor.begin(Wire, SHT40_I2C_ADDR_44);
  sensor.softReset();
  delay(10);

  uint32_t serialNumber = 0;
  error = sensor.serialNumber(serialNumber);
  if (error != 0) {
    Serial.print("Error trying to execute serialNumber(): ");
    errorToString(error, errorMessage, sizeof(errorMessage));
    Serial.println(errorMessage);
  } else {
    Serial.print("Sensor serialNumber: ");
    Serial.println(serialNumber);
  }

  Serial.print("Connecting to WiFi");
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("\nWiFi Connected!");
  Serial.print("IP: ");
  Serial.println(WiFi.localIP());
}

void loop() {
  float aTemperature = 0.0;
  float aHumidity = 0.0;
  delay(20);
  error = sensor.measureLowestPrecision(aTemperature, aHumidity);

  if (error != NO_ERROR) {
    Serial.print("Sensor read error: ");
    errorToString(error, errorMessage, sizeof(errorMessage));
    Serial.println(errorMessage);
  } else {
    Serial.print("Temp: ");
    Serial.print(aTemperature);
    Serial.print(" °C\tHumidity: ");
    Serial.print(aHumidity);
    Serial.println(" %");

    if (WiFi.status() == WL_CONNECTED) {
      HTTPClient http;

      String url = String(scriptURL) + "?temp=" + String(aTemperature, 2) + "&hum=" + String(aHumidity, 2);
      Serial.println("Sending to: " + url);
      
      http.begin(url);
      int httpCode = http.GET();

      Serial.print("HTTP response code: ");
      Serial.println(httpCode);

      if (httpCode > 0) {
        String response = http.getString();
        Serial.println("Server response: " + response);
      } else {
        Serial.println("Failed to send data.");
      }

      http.end();
    } else {
      Serial.println("WiFi disconnected");
    }
  }

  delay(20000);  // Send every 20 sec
}