Published October 21, 2018 © GPL3+

Keep Your Plant Moist (Appropriate Amount)

Shows level of plant moisture, and lasts more than a year from a battery.

IntermediateWork in progress8 hours667

Things used in this project

Hardware components

Microchip ATmega328

DIP case

resistor 27k

SG90 Micro-servo motor

General Purpose Transistor PNP

Resistor 475 ohm

Software apps and online services

Arduino IDE

Hand tools and fabrication machines

3D Printer (generic)

Story

I love my home plants but (as sometimes we all do) I forgot to pay enough attention to them and water them timely. So I want to create a small moisture level display. Also, I want it to be very power efficient and durable to last for a long time from the battery.

Although parts a pretty simple for this project (Arduino + moisture sensor + servo) I have learned a lot about power management and the durability of the project.

First part: Measure moisture level

I use 2 straightened clip and a voltage divider as an analog moisture sensor. Put to clips to soil and measure its resistance (more moisture mean less resistance). Simple enough. But if you will apply a constant current to this type of sensor - it will destroy itself pretty quickly. In less than a week of use with a 5v battery you will get this:

destroyed by the power of current

There are many solutions to the problem. But because it takes weeks for the plant to dry out I don't really need to constantly check moisture level. I will enable sensor every 3 or 4 hours, check moisture (that should take less than a millis) and than disable sensor again.

So here is a picture of my sensor:

2 clip + a dupont wire connector = moisture sensor

Second part: Display

For display I have used a SG90 Micro Servo (using standard Arduino Servo Lib) and a custom 3d printed and acrylic paint case:

1 / 5

Fusion files is attached.

Third part: Power management

There are 2 things to think of for power: you need enough current for the servo to move and you need to be power efficient to survive on a battery long enough. Servo needs 4.7v to 6v to operate normally.

I want this project to have a small size so I have started with some small batteries. I try 4xLR54 and then 2xCR2032 but both don't give enough current to servo (~300mA needed). With 4xAA servo works just fine. So for this stage, I will stick with AA batteries and will try to shrink down project size later.

Power efficiency is simple - you need just disable everything that consumes power.

I connected moisture sensor to an atmega digital pin and turn it off once I have read data. Also, I only read data once every 3h.

Servo consumes ~0.5mA trying to hold a position. I have to disable Servo after movement using the transistor.

And last but not least you need to put atmega at deep sleep. I use Low-Power lib from rocketscream to put arduino to sleep.

In the end project consume only 0, 006 mA which should give us more than a year on a battery.

UPDATE #1: 4 ladda batteries last for only 9 weeks. A little bit less than expected. I don't test my batteries for capacity but ladda was tested in the internet and the results was really good. So it should be some errors with calculation. Probably 1 sec every 3 hours to measure moisture level and moving servo gives a more significant impact. Will check & update.

The final product and next step

So currently project looks like this:

I will test it for a couple of months and 3d print a smart pot with embedded moisture display. Also, I want to try powering project from 2x CR2032 with supercapacitor to be able to provide enough current for the servo.

If you are interested please comment and I will post detailed video of the build.

Schematics

Code

ServoPlant

#include <Arduino.h>
// needs to install this libs;
#include <LowPower.h>
#include <Servo.h>

#define ANALOG_PIN A0 // read moister data from this pin
#define PLANT_PIN 4 // connect moister senser 
#define EN_MOTOR_PIN 5 // transistor to enable servo
#define SERVO_PIN 3 // controll the server
#define WATCH_DOG_OVERFLOW 1350 // deley counter for watch dog 1350 -> watchdog fires every 8 sec 7.5 times a minute * 60 = 450 times an hour *3 = 1350 times in 3 hours;

//move servo only if the data changes more than 50
int old = 0;
Servo servo;
volatile int watchdog_counter = WATCH_DOG_OVERFLOW;

// sleep for 8 secs
void sleep (){
  LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);
}

// read analog data from the plant;
int read(int pin){
  digitalWrite(pin, HIGH);
  int value = analogRead(ANALOG_PIN);
  digitalWrite(pin, LOW);  
  return value;
};

void setup() {
  Serial.begin(9600);
  pinMode(PLANT_PIN, OUTPUT);
  pinMode(EN_MOTOR_PIN, OUTPUT);
  // disable plant and monter on the start;
  digitalWrite(EN_MOTOR_PIN, HIGH);
  digitalWrite(PLANT_PIN, LOW);
}

void loop() {
  Serial.println("loop");
  sleep();
  // after sleep checking if I sleep long for plant to dry 
  if(watchdog_counter < WATCH_DOG_OVERFLOW){ 
     // increment spleep counter;
      watchdog_counter++;
      return;
  }
  watchdog_counter = 0;

  // read plant data;
  int value = read(PLANT_PIN);
  
  Serial.print("old: ");
  Serial.println(old);
  // if data changes more than 50 update servor postion;
  if(abs(old - value) > 50){
    // enable servo
    digitalWrite(EN_MOTOR_PIN, LOW);
    servo.attach(SERVO_PIN); 
    delay(50);
    // map plant data to servro angle 
    int servoValue = map(value, 0, 1024, 180, 0);
    Serial.print("value: ");
    Serial.print(value);
    Serial.print(" servo: ");
    Serial.println(servoValue);
    servo.write(servoValue);
    // wait for servo rich angle
    delay(1000);
    // update old plant value;
    old = value;
    // disable servo
    servo.detach();
    digitalWrite(EN_MOTOR_PIN, HIGH);
  }
  // go to spleep;
}

Credits

Max Tern

1 project • 1 follower

Keep Your Plant Moist (Appropriate Amount)

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

First part: Measure moisture level

Second part: Display

Third part: Power management

The final product and next step

Custom parts and enclosures

front_ghwoPKcHaH.f3d

arrow_tUN9kA8fNF.f3d

Schematics

ServoPlantS.jpg

Code

ServoPlant

Credits

Max Tern

Comments

Embed the widget on your own site

Keep Your Plant Moist (Appropriate Amount)

Keep Your Plant Moist (Appropriate Amount)

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

First part: Measure moisture level

Second part: Display

Third part: Power management

The final product and next step

Custom parts and enclosures

front_ghwoPKcHaH.f3d

arrow_tUN9kA8fNF.f3d

Schematics

ServoPlantS.jpg

Code

ServoPlant

Credits

Max Tern

Comments

Related channels and tags