Demonstration
Screen shots
Schematic
3D printing
The PCB
Assembly - Step 1
Assembly - Step 2
Assembly - Step 3
Assembly - Step 4
Conclusion

Published May 19, 2023 © GPL3+

Brick a Bottle or Three

A simple game on a Nokia 5110 LCD screen

IntermediateFull instructions provided8 hours88

Things used in this project

Hardware components

Microchip ATtiny1614 Microprocessor

Nokia 5110 LCD Screen

LM1117-33 3.3V SMD Regulator

SOT223-T

Tactile Switch, Top Actuated

17mm Shaft

Buzzer

Passive Components

3 x 330R 0805 Resistors, 1 x 220R 0805 Resistior, 2 x 0.1uF 0805 ceramic capacitors, 1 x 220uF/10V through hole capacitor, 1 x 10uF 1206 ceramic capacitor

DC power socket

See images for the type used

Software apps and online services

Arduino IDE

Hand tools and fabrication machines

3D Printer (generic)

Soldering iron (generic)

Story

This project is my rebuild of the Brick a Bottle or Three by Palingenesis. It has been redesigned to use an updated microprocessor along with a custom PCB and 3D printed case.

Demonstration

Demonstrating the game

Screen shots

Various screens in the game

Schematic

The updated circuit is designed around a ATtiny1614 microprocessor. This 14pin device has 16K Flash memory and 2K Static memory which is more than enough for this project.

Rather than using a processor IO pin for each switch, the updated circuit wires the switches onto a voltage divider. Each switch generates a different voltage which is read via a single analog pin.

While the circuit can easily run on a single 3V battery, I decided to add a 3.3V regulator and power it using a power brick.

Schematic of Brick a Bottle or Three game

3D printing

The STL files are included. Either take these to a 3D print shop or if you have your own printer, run them through your slicing software. I used a 0.2 mm layer height and no supports for the top, back and LCD supports.

The button tops were printed with a 0.1 mm layer height. Change the filament to a contrasting color at the start of layer 69.

The PCB

As the ATtiny1614 microprocessor only comes as a Surface Mount Device (SMD), I decided to use SMD packages for most of the components in the build.

SMD components are used for most of the components

The Eagle files have been included should you wish to have the board commercially made or you can do as I did and make it yourself. I used the Toner method.

Assembly - Step 1

Start by adding the SMD components. I find it easier to use solder paste rather than use solder from a reel when soldering SMD components. I used my SMD Hot Plate to reflow the solder paste.

My 400W SMD Hot Plate used to reflow the solder paste

Add a 3 pin right angle male header on the copper-side of the board for the UPDI programmer.

Add a 2 pin right angle KF2510 male connector on the copper-side of the board for the power connection.

Add SMD components and headers

Assembly - Step 2

Add the top side components. The PCB is designed for small passive buzzer with pins with a 7.4mm spacing. I used a buzzer that was purchased from a Rockby Electronics sale. It has a 9mm spacing.

The 8 pin female header used to connect the Nokia 5110 display board has a 5mm height. Note: this differs from the standard 8.4mm height.

Glue the four LCD support posts to the PCB using super glue.

Add the four 6mm x 6mm tactile switches with 17mm shafts. Glue on the 3D printed button tops ensuring the glue doesn't run down the shaft and into the switch itself.

Add top side components, display supports and Nokia 5110 Display

Assembly - Step 3

Add a DC Panel Socket to the case.

Screw the PCB into the case using 4 x M2 4mm screws.

Add a DC Panel Socket and screw in the PCB

Assembly - Step 4

The ATtiny1614 is part of the new breed of ATtiny microprocessors. Unlike the earlier series such as the ATtiny85, the new breed use the RESET pin to program the CPU. To program it you need a UPDI programmer. I made one using a Arduino Nano. You can find complete build instructions at Create Your Own UPDI Programmer. It also contains the instructions for adding the megaTinyCore boards to your IDE.

My home made UPDI programmer outputs 5V. Since the Nokia 5110 display runs from 3.3V, connect the ground and UPDI wires to the UPDI connector and the 5V wire to the other side of the regulator as shown below.

Programming the ATtiny1614 microprocessor

Plug in the power connector to the PCB and close up the case.

Conclusion

As a project it was an enjoyable build 😀. As a game, you always lose 😔.

Thanks Palingenesis for publishing your project. 👍

Schematics

Code

Brick_A_Bottle_V1.ino

/* 
 *  Brick a bottle or three
 *  Based on "Brick a Bottle or Three" by Palingenesis
 *  (https://www.instructables.com/Brick-a-Bottle-or-Three/)
 *  
 *  230516 John Bradnam (jbrad2089@gial.com)
 *    - Coverted project to use a ATtiny1614 processor
 *    
 *-------------------------------------------------------------------------
 Arduino IDE:
 --------------------------------------------------------------------------
  BOARD: ATtiny1614/1604/814/804/414/404/214/204
  Chip: ATtiny1614
  Clock Speed: 20MHz
  millis()/micros(): "Enabled (default timer)"
  Programmer: jtag2updi (megaTinyCore)

  ATTiny1614 Pins mapped to Ardunio Pins
 
              +--------+
          VCC + 1   14 + GND
  (SS)  0 PA4 + 2   13 + PA3 10 (SCK)
        1 PA5 + 3   12 + PA2 9  (MISO)
  (DAC) 2 PA6 + 4   11 + PA1 8  (MOSI)
        3 PA7 + 5   10 + PA0 11 (UPDI)
  (RXD) 4 PB3 + 6    9 + PB0 7  (SCL)
  (TXD) 5 PB2 + 7    8 + PB1 6  (SDA)
              +--------+
  
 **************************************************************************/

#include <Adafruit_GFX.h>
#include <Adafruit_PCD8544.h>

#define LIGHT 0     //PA4
#define SCLK 1      //PA5
#define DIN 2       //PA6
#define DC 3        //PA7
#define CS_LCD 4    //PB3
#define RST 5       //PB2
#define PIEZO 7     //PB0
#define SWITCHES 10 //PA3

Adafruit_PCD8544 display = Adafruit_PCD8544(SCLK,DIN,DC,CS_LCD,RST);

enum SWITCH { NONE, ONE, TWO, THREE, FOUR };
struct SWITCH_VALUES
{
  SWITCH name;
  int low;
  int high;
};
#define SWITCH_COUNT 4
SWITCH_VALUES switches[SWITCH_COUNT] = {{ONE,600,700},{TWO,450,600},{THREE,300,450},{FOUR,0,100}};
SWITCH lastButtonPressed = NONE;

enum MODES {MENU, HELP, QUERY, TAKE, WIN};
MODES mode = MENU;

bool backlight;
int bottleNumber;
int youTake;
int iTake;

//---------------------------------------------------------------
// Bottle graphivs
//  brick 14x6 (Use Rectangle)
//  bottle 6x16
//---------------------------------------------------------------

const uint8_t bottle_img[] PROGMEM =
{ 
  B00110000,
  B00110000,
  B00110000,
  B00110000,
  B01111000,
  B11111100,
  B11111100,
  B11111100,
  B11111100,
  B11111100,
  B11111100,
  B11111100,
  B11111100,
  B11111100,
  B01111000 
};

//Smashed bottle 6x16
const uint8_t smash_bottle_img[] PROGMEM =
{ 
  B01001000,
  B10000100,
  B00100000,
  B01001000,
  B10000100,
  B00110000,
  B00100100,
  B10000000,
  B10001000,
  B11001100,
  B01000100,
  B11010100,
  B10010100,
  B10110100,
  B00101100 
};

//------------------------------------------------------------
// Hardware setup
//------------------------------------------------------------

void setup() 
{
  //Encoder
  pinMode(PIEZO,OUTPUT);
  pinMode(SWITCHES,INPUT);
  pinMode(LIGHT,OUTPUT);
  analogWrite(LIGHT, 0);
  backlight = false;

  display.begin(60, 4);
  //display.setContrast(50);
  display.display(); // show splashscreen
  delay(2000);
  writeTitleText();
  
  display.clearDisplay();
  drawBrickWall();
  for (size_t i = 1; i < 10; i++) 
  {
    drawBottle(i + bottleNumber);
  }
  display.display();
  delay(500);
  
  for (size_t i = 1; i < 10; i++) {
    smashBottle(i + bottleNumber);
    delay(100);
  }
  //delay(2000);
  
  display.setTextSize(1);
  display.setTextColor(BLACK);
  mode = MENU;
}

//------------------------------------------------------------
// Main loop
//------------------------------------------------------------

void loop() 
{
  switch (mode)
  {
    case MENU: writeMenuText(); break;
    case HELP: writeHelpText(); break;
    case QUERY: writeQuestionText(); break;
    case TAKE: writeITakeText(); break;
    case WIN: writeIWinText(); break;
  }
}

//-------------------------------------------------------------
// Graphic routines
//-------------------------------------------------------------

void drawBrickWall(void) {

  byte FirstBrickLeft = 0;
  byte FirstBrickTop = 0;

  for (size_t i = 0; i < 3; i++) 
  {
    if (i == 1) 
    { 
      FirstBrickLeft = 10; 
    }
    else 
    { 
      FirstBrickLeft = 3; 
    }

    for (int16_t ii = 0; ii < 100; ii += 15) 
    {
      display.fillRect(ii - FirstBrickLeft, 31 + FirstBrickTop, 14, 6, 1);
    }
    FirstBrickTop += 7;
  }
  display.display();
}

void drawBottle(byte position) 
{
  display.drawBitmap(position * 7, 16, bottle_img, 6, 15, 1);
  display.display();
}

void smashBottle(byte position) 
{

  display.fillRect(position * 7, 16, 6, 15, 0);
  display.drawBitmap(position * 7, 16, smash_bottle_img, 6, 15, 1);
  display.display();
  playBottleSmashSound();
  delay(500);
  display.fillRect(position * 7, 16, 6, 15, 0);
  display.display();
}

//--------------------------------------------------
// Sound routines
//--------------------------------------------------

void playBottleSmashSound() 
{
  tone(PIEZO, 2000);
  delay(100);
  tone(PIEZO, 500);
  delay(200);
  for (size_t i = 400; i > 0; i-=10)  
  {
    tone(PIEZO, i);
    delay(15);
  }
  noTone(PIEZO);
}

void playStartSound() 
{
  for (size_t i = 0; i < 4; i++) 
  {
    tone(PIEZO, 500);
    delay(100);
    tone(PIEZO, 1000);
    delay(100);
    tone(PIEZO, 1500);
    delay(100);
    tone(PIEZO, 2000);
    delay(100);
    tone(PIEZO, 2500);
    delay(100);

  }
  noTone(PIEZO);
}

//----------------------------------------------------
// Display Text routines
//----------------------------------------------------

void writeTitleText() 
{
  display.clearDisplay();
  display.setCursor(27, 10);
  display.print("BRICK");
  display.setCursor(18, 20);
  display.print("A BOTTLE");
  display.setCursor(18, 30);
  display.print("OR THREE");
  display.display();
  playStartSound();
}

void writeMenuText() 
{
  display.clearDisplay();
  display.setCursor(0, 0);
  display.print("");
  display.setCursor(0, 9);
  display.print("1 = NEW GAME");
  display.setCursor(0, 18);
  display.print("2 = Help");
  display.setCursor(0, 27);
  display.print("3 = Exit");
  display.setCursor(0, 36);
  display.print("4 = LED");
  display.display();
  
  bottleNumber = 3;
  SWITCH button = readSwitches(true);
  while (button == NONE)
  {
    button = readSwitches(true);
  }

  switch (button)
  {
    case ONE:
      //Start a new game
      display.clearDisplay();
      drawBrickWall();
      for (size_t i = 1; i < 10; i++) {
        drawBottle(i + 2);
      }
      mode = QUERY;
      break;

    case TWO:
      //Help
      mode = HELP;
      break;

    case THREE:
      //Exit
      display.clearDisplay();
      display.setCursor(0, 0);
      display.print("");
      display.setCursor(0, 9);
      display.print("BYE");
      display.setCursor(0, 18);
      display.print("TRY AGAIN");
      display.setCursor(0, 27);
      display.print("ANOTHER TIME");
      display.setCursor(0, 41);
      display.print("");
      display.display();
      delay(5000);
      mode = MENU;
      break;

    case FOUR:
      backlight = !backlight;
      analogWrite(LIGHT, (backlight) ? 192 : 0);
      break;

    case NONE:
      break;
  }
}

void writeHelpText() 
{
  display.clearDisplay();
  display.setCursor(0, 0);
  display.print("== THE GAME ==");
  display.setCursor(0, 9);
  display.print("THERE ARE");
  display.setCursor(0, 18);
  display.print("9 BOTTLES");
  display.setCursor(0, 27);
  display.print("ON A WALL.");
  display.setCursor(0, 41);
  display.print("(Press Button)");
  display.display();
  while (readSwitches(true) == NONE);
   
  display.clearDisplay();
  display.setCursor(0, 0);
  display.print("YOU ARE");
  display.setCursor(0, 9);
  display.print("EXPERT");
  display.setCursor(0, 18);
  display.print("AT THROWING");
  display.setCursor(0, 27);
  display.print("STONES.");
  display.setCursor(0, 41);
  display.print("(Press Button)");
  display.display();
  while (readSwitches(true) == NONE);

  display.clearDisplay();
  display.setCursor(0, 0);
  display.print("YOU ALWAYS");
  display.setCursor(0, 9);
  display.print("HIT A BOTTLE.");
  display.setCursor(0, 18);
  display.print("I'M");
  display.setCursor(0, 27);
  display.print("JUST AS GOOD.");
  display.setCursor(0, 41);
  display.print("(Press Button)");
  display.display();
  while (readSwitches(true) == NONE);

  display.clearDisplay();
  display.setCursor(0, 0);
  display.print("WE MAY TAKE");
  display.setCursor(0, 9);
  display.print("1, 2 OR 3");
  display.setCursor(0, 18);
  display.print("STONES");
  display.setCursor(0, 27);
  display.print("EACH TURN.");
  display.setCursor(0, 41);
  display.print("(Press Button)");
  display.display();
  while (readSwitches(true) == NONE);
  
  display.clearDisplay();
  display.setCursor(0, 0);
  display.print("ONE WITH THE");
  display.setCursor(0, 9);
  display.print("LAST BOTTLE,");
  display.setCursor(0, 18);
  display.print("LOSES");
  display.setCursor(0, 27);
  display.print("THE GAME.");
  display.setCursor(0, 41);
  display.print("(Press Button)");
  display.display();
  while (readSwitches(true) == NONE);

  mode = MENU;
}

void writeQuestionText() 
{
  display.fillRect(0, 0, 83, 14, 0);
  display.setCursor(0, 3);
  display.print("  1, 2 or 3?");
  display.display();
  
  SWITCH button = readSwitches(true);
  while (button == NONE || button == FOUR)
  {
    button = readSwitches(true);
  }
  youTake = (int)button;

  for (int i = 0; i < youTake; i++) 
  {
    smashBottle(i + bottleNumber);
    delay(100);
  }
  bottleNumber += youTake;
  mode = TAKE;
}

void writeITakeText() 
{
  iTake = 4 - youTake;

  display.fillRect(0, 0, 83, 14, 0);
  display.setCursor(0, 3);
  display.print("  I TAKE " + String(iTake));
  display.display();

  delay(2000);

  for (int i = 0; i < iTake; i++) 
  {
    smashBottle(i + bottleNumber);
    delay(100);
  }
  bottleNumber += iTake;

  mode = (bottleNumber < 9) ? QUERY : WIN;
}

void writeIWinText() 
{
  display.fillRect(0, 0, 83, 14, 0);
  display.setCursor(0, 3);
  display.println("Only 1 left.");
  display.print("I WIN");
  display.display();
  delay(500);
  playStartSound();
  mode = MENU;
}

//----------------------------------------------------
// Buttons
// - Returns NONE, ONE, TWO, THREE or FOUR
//----------------------------------------------------

SWITCH readSwitches(bool waitForRelease)
{
  SWITCH sw = NONE;
  int value = analogRead(SWITCHES);
  if (value < 1000)
  {
    delay(10);    //debounce
    if (analogRead(SWITCHES) < 1000)
    {
      for(int i = 0; i < SWITCH_COUNT; i++)
      {
        if (value >= switches[i].low && value < switches[i].high)
        {
          sw = switches[i].name;
          tone(PIEZO, 500);
          delay(10);
          noTone(PIEZO);
          if (waitForRelease)
          {
            while (analogRead(SWITCHES) < 1000)
            {
              yield();
            }
          }
          break;
        }
      }
    }
  }
  return sw;
}

Credits

John Bradnam

141 projects • 167 followers

Thanks to Palingenesis.

Brick a Bottle or Three

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Demonstration

Screen shots

Schematic

3D printing

The PCB

Assembly - Step 1

Assembly - Step 2

Assembly - Step 3

Assembly - Step 4

Conclusion

Custom parts and enclosures

STL Files

Schematics

Schematic

PCB

Eagle files

Code

Brick_A_Bottle_V1.ino

Credits

John Bradnam

Comments

Embed the widget on your own site

Brick a Bottle or Three

Brick a Bottle or Three

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Demonstration

Screen shots

Schematic

3D printing

The PCB

Assembly - Step 1

Assembly - Step 2

Assembly - Step 3

Assembly - Step 4

Conclusion

Custom parts and enclosures

STL Files

Schematics

Schematic

PCB

Eagle files

Code

Brick_A_Bottle_V1.ino

Credits

John Bradnam

Comments

Related channels and tags