Homelessness Awareness Project

#include <neopixel.h>

#include "Particle.h"

SYSTEM_MODE(AUTOMATIC);

SerialLogHandler logHandler(LOG_LEVEL_INFO);

// NeoPixel Setup
#if (PLATFORM_ID == 32)
  #define PIXEL_PIN SPI1
#else
  #define PIXEL_PIN D2
#endif

#define PIXEL_COUNT 4
#define PIXEL_TYPE WS2812B

Adafruit_NeoPixel strip(PIXEL_COUNT, PIXEL_PIN, PIXEL_TYPE);

// Servo Setup
Servo fullServo;
Servo halfServo;


String occupancyStatus = "";
int policeDistrict = -1;

bool actionInProgress = false;
unsigned long actionStartTime = 0;
bool movingForward = true;
bool servoIncreasing = true;
int servoPosition = 180;

bool pixelsOn = false;
unsigned long lastFlashTime = 0;
const unsigned long flashInterval = 500;

bool flashRed = true;

void setup() {
  Serial.begin(9600);

  // Initialize NeoPixel
  strip.begin();
  strip.show();

  // Subscribe to the webhook
  Particle.subscribe("hook-response/service_request", handleData);

  // Attach servos 
  fullServo.attach(16);
  halfServo.attach(15);
  

  // Wait to connect
  delay(5000);

  // Publish event to trigger the webhook
  Particle.publish("service_request");
  Serial.println("Published service_request event. Waiting for response...");
}

void loop() {
  if (actionInProgress) {
    unsigned long currentMillis = millis();

    // Check if action duration passed
    if (currentMillis - actionStartTime >= 15000) { // 15 seconds
      stopActions();
      Serial.println("Action finished after 15 seconds.");
    } else {
      // Continue moving servos gradually
      moveServosGradually();

      // Flash the NeoPixels
      if (currentMillis - lastFlashTime >= flashInterval) {
        lastFlashTime = currentMillis;
        if (pixelsOn) {
          turnOffPixels();
        } else {
          if (flashRed) {
            flashRedPixels();
          } else {
            flashWhitePixels();
            }
        }
        pixelsOn = !pixelsOn; // Toggle state
      }
    }
  }
}

// Handle incoming webhook data
void handleData(const char *event, const char *data) {
  Serial.println("Received webhook response!");

  // Convert data to String
  String response = String(data);
  Serial.println("Raw data: " + response);

  int commaIndex = response.indexOf(',');

  if (commaIndex != -1) {
    occupancyStatus = response.substring(0, commaIndex);
    occupancyStatus.trim();

    String districtStr = response.substring(commaIndex + 1);
    districtStr.trim();
    policeDistrict = districtStr.toInt();

    Serial.println("Occupancy Status: " + occupancyStatus);
    Serial.println("Police District: " + String(policeDistrict));

    // Determine flash color
    flashRed = matchesDistrict(policeDistrict);

    if (occupancyStatus == "true") {
      Serial.println("Starting servo and LED actions based on webhook!");
      startActions();
    }
  } else {
    Serial.println("ERROR: Response format is unexpected.");
  }
}

// Start the servo and pixel actions
void startActions() {
  actionInProgress = true;
  actionStartTime = millis();
  servoPosition = 0;
  pixelsOn = false;
  lastFlashTime = millis();
}

// Stop all actions
void stopActions() {
  actionInProgress = false;

  // Turn off pixels
  turnOffPixels();

  // Detach servos to save power
  fullServo.detach();
  halfServo.detach();
}

void moveServosGradually() {
    halfServo.write(servoPosition);
    
    if (servoIncreasing) {
        servoPosition += 2;
        if (servoPosition >= 180) {
            servoIncreasing = false;
        }
    } else {
        servoPosition -= 2;
        if (servoPosition <= 0) {
            servoIncreasing = true;
        }
    }
}

// Flash NeoPixels red
void flashRedPixels() {
  for (int i = 0; i < PIXEL_COUNT; i++) {
    strip.setPixelColor(i, strip.Color(255, 0, 0)); // Red
  }
  strip.show();
}
// Flash NeoPixels white
void flashWhitePixels() {
  for (int i = 0; i < PIXEL_COUNT; i++) {
    strip.setPixelColor(i, strip.Color(255, 255, 255)); // White
  }
  strip.show();
}
// Turn off NeoPixels
void turnOffPixels() {
  for (int i = 0; i < PIXEL_COUNT; i++) {
    strip.setPixelColor(i, strip.Color(0, 0, 0)); // Off
  }
  strip.show();
}

// Check if the police district matches the target list
bool matchesDistrict(int district) {
  return (district == 9 || district == 8 || district == 7 || district == 2 ||
          district == 3 || district == 6 || district == 22 || district == 5 ||
          district == 4 || district == 12 || district == 1);
}