Team Hamba Allah:

Lintang Cahya Wahyuningtyas 29745

•

Ahmad Saeful amri 77078

•

Aqil

•

Hendra Kusumah

•

Muhammad Raka Arifa Ilham

Published May 15, 2025

Prayer Reminder Clock Using Arduino UNO and Dot Matrix

This project is an automatic digital prayer time reminder clock built using an Arduino UNO microcontroller and a MAX7219 dot matrix display.

BeginnerFull instructions provided175

Prayer Reminder Clock Using Arduino UNO and Dot Matrix

Things used in this project

Hardware components

Arduino UNO

Maxim Integrated MAXREFDES99# MAX7219 Display Driver Shield

Male/Female Jumper Wires

Buzzer

Software apps and online services

Arduino IDE

Story

Our team created this project because we often miss prayer times while focusing on studying or working. We wanted a simple prayer time reminder that is easy to build and can display messages directly without needing to check a smartphone.

Features

Displays the current time using a dot matrix display.
Shows reminders for the five daily prayers: Subuh (Fajr), Dzuhur (Dhuhr), Ashar (Asr), Maghrib, and Isya (Isha).
Emits a simple beep sound when it’s time for prayer.

Benefits

Helps users maintain prayer discipline by providing timely reminders.
Operates independently without requiring internet or smartphone connectivity.
Offers a simple and cost-effective solution suitable for various settings like bedrooms, offices, or kitchens.
Serves as a practical learning project for those interested in microcontroller programming and electronic device control.

Hardware Used

component

We chose the Arduino UNO because it is easy to program and sufficient for our needs. For the display, we used a MAX7219 dot matrix module to clearly show text. We also added an active buzzer to signal when prayer time arrives.

Buzzer

How the Device Works

The Arduino UNO acts as the brain of the device and runs a program containing the prayer schedule (for example, Subuh at 04:30, Dhuhr at 12:00, and so on).

The current time is calculated automatically from when the device is turned on. The program counts from second zero and continues to track hours, minutes, and seconds while the device is on.

When the current time matches the programmed prayer time, the device will:

Show a prayer reminder message on the dot matrix (for example, “IT’S TIME FOR DHUHR PRAYER”)
Activate the buzzer to beep as a signalAfter a few seconds, the display returns to showing the current time

Steps to Build the Device

1. Prepare the components: Arduino UNO, MAX7219 dot matrix module, active buzzer, and jumper wires.

2. Connect the dot matrix module to the Arduino using SPI:

VCC → 5V
GND → GND
DIN → Pin 11 (MOSI)
CS → Pin 10 (Chip Select)
CLK → Pin 13 (SCK)

3. Connect the buzzer directly to Arduino:

Positive (+) pin of buzzer → Arduino digital pin 8
Negative (–) pin of buzzer → Arduino GND

4. Write the Arduino program that includes:

Manually set the initial time
Prayer schedule fixed inside the code
Logic to compare current time with prayer times
Commands to display text and activate buzzer when time comes

5. Upload the code to the Arduino using the Arduino IDE.

6. Power the device with a USB cable or adapter.

7. The device is ready and will run automatically every time it’s turned on.

Conclusion

This prayer reminder clock made with Arduino UNO, dot matrix, and buzzer can show the time and alert users when it’s time to pray. It helps support daily worship in a simple and independent way. We hope this project inspires others to make useful tools that connect technology with daily life.

We hope this project helps people stay consistent with their prayers and inspires simple, meaningful ideas. Thank you!

Code

Prayer Time Reminder

#include <MD_Parola.h>
#include <MD_MAX72XX.h>
#include <SPI.h>

#define HARDWARE_TYPE MD_MAX72XX::FC16_HW
#define MAX_DEVICES 4
#define DATA_PIN 11
#define CS_PIN   10
#define CLK_PIN  13

#define BUZZER_PIN 8

MD_Parola display = MD_Parola(HARDWARE_TYPE, CS_PIN, MAX_DEVICES);

unsigned long previousMillis = 0;
const long interval = 1000;
int hours = 4;
int minutes = 29;
int seconds = 50;

bool adzanPlayed[5] = {false, false, false, false, false};

const char* namaAdzan[5] = {
  "Subuh", "Dzuhur", "Asar", "Maghrib", "Isya"
};

int jadwalAdzan[5][2] = {
  {4, 30},   // Subuh
  {12, 0},   // Dzuhur
  {15, 15},  // Asar
  {18, 0},   // Maghrib
  {19, 15}   // Isya
};

bool isScrolling = false;
char scrollText[50];

void setup() {
  pinMode(BUZZER_PIN, OUTPUT);
  digitalWrite(BUZZER_PIN, LOW);

  display.begin();
  display.setIntensity(5);
  display.displayClear();
  display.displayText(scrollText, PA_CENTER, 50, 2000, PA_SCROLL_LEFT, PA_SCROLL_LEFT);
}

void loop() {
  if (millis() - previousMillis >= interval) {
    previousMillis = millis();
    updateClock();
  }

  if (isScrolling) {
    if (display.displayAnimate()) {
      isScrolling = false;
    }
  } else {
    char buf[6];
    sprintf(buf, "%02d:%02d", hours, minutes);
    display.setTextAlignment(PA_CENTER);
    display.print(buf);
  }

  for (int i = 0; i < 5; i++) {
    if (hours == jadwalAdzan[i][0] && minutes == jadwalAdzan[i][1] && seconds == 0 && !adzanPlayed[i]) {
  
      bunyikanBuzzer(5);
      adzanPlayed[i] = true;

      sprintf(scrollText, "Adzan %s %02d:%02d", namaAdzan[i], jadwalAdzan[i][0], jadwalAdzan[i][1]);
      display.displayClear();
      display.displayText(scrollText, PA_LEFT, 50, 1000, PA_SCROLL_LEFT, PA_SCROLL_LEFT);
      display.displayReset();
      isScrolling = true;
    }

    if (!(hours == jadwalAdzan[i][0] && minutes == jadwalAdzan[i][1])) {
      adzanPlayed[i] = false;
    }
  }
}

void updateClock() {
  seconds++;
  if (seconds >= 60) {
    seconds = 0;
    minutes++;
    if (minutes >= 60) {
      minutes = 0;
      hours++;
      if (hours >= 24) {
        hours = 0;
      }
    }
  }
}

void bunyikanBuzzer(int durasiDetik) {
  for (int i = 0; i < durasiDetik * 10; i++) {
    digitalWrite(BUZZER_PIN, HIGH);
    delay(50);
    digitalWrite(BUZZER_PIN, LOW);
    delay(50);
  }
}

Prayer Reminder Clock Using Arduino UNO and Dot Matrix