Published June 5, 2020 © GPL3+

Social Distancing Radar

A mobile radar unit that scans an area and displays a message to people who are too close.

BeginnerFull instructions provided5 hours2,485

Things used in this project

Hardware components

Teensy 4.0 Development Board

LED Dot Matrix Display, Red

SparkFun VL53L1X

SG90 Micro-servo motor

Software apps and online services

Arduino IDE

Microsoft VS Code

Hand tools and fabrication machines

3D Printer (generic)

Soldering iron (generic)

Story

Staying Safe

In the age of COVID-19, keeping your distance from others is vital to maintaining public safety. However, many people can be oblivious as to how far away they actually are, or just not know how far away two meters actually is. To help with this problem, I created a social distance "lidar" scanner that sweeps an area and displays a message to alert people who aren't respecting the bubble. I decided to mount this on my bike, as trails often host people that are all too happy to get close to others.

Components

The "brain" of this project is the Teensy 4.0, which is a powerful microcontroller that is capable of taking readings, performing calculations on them, and displaying message very quickly.

It has (an albeit overkill for this project) 1MB of RAM and 2MB of flash and a powerful ARM Cortex-M7 processor running at over 600MHz. To measure distances, I went with Sparkfun's VL53L1X ToF laser distance sensor that uses pulses of light to measure how far away an object is.

This is superior to an ultrasonic sensor in several ways. First, light travels far faster than sound, so measurements are done more quickly. Second, a laser is much narrower than a pulse of sound and therefore can be more accurate. Finally, the sensor consumes less power than an ultrasonic sensor and interfaces via the I2C bus. The final component to this project is a simple LED matrix that is driven by several MAX MD72XX ICs, which connect to the Teensy via SPI and can be controlled by very elegant libraries such as Parola.

Design and Fabrication

I began this project by going into Fusion 360 and creating a model of how the ToF sensor board would be attached to the micro servo. After that was done, I made a larger assembly that included a mount for it to attach to a bike. I then exported each piece and 3D printed them.

1 / 6

Programming

The program is quite simple in its operation. It starts by initializing the objects for the distance sensor, display, and servo. Next, it enters into the main loop. In this loop, the position of the servo is advanced and the distance is measured. If this distance is less than the set threshold, then the message "BACK" is displayed. Otherwise, "U GOOD" is shown.

Use

To test out the system, I went on a trail and began to bike. I noticed that whenever a person got too close, they saw the message and decided to slow down. This project can be used in different areas as well, such as near a cashier or while walking.

Schematics

Code

Social Distancing Radar

#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>
#include <PWMServo.h>
#include <ComponentObject.h>
#include <RangeSensor.h>
#include <SparkFun_VL53L1X.h>
#include <vl53l1x_class.h>
#include <vl53l1_error_codes.h>
#include <Wire.h>
#include "SparkFun_VL53L1X.h"

#define HARDWARE_TYPE MD_MAX72XX::FC16_HW
#define PANEL_COUNT 4
#define CLK_PIN 13
#define DATA_PIN 11
#define CS_PIN 10

#define SHUTDOWN_PIN 2 // optional
#define INTERRUPT_PIN 3 // optional
#define SERVO_PIN 9

#define MID_ANGLE 120

SFEVL53L1X distanceSensor;
PWMServo servo;

MD_Parola display = MD_Parola(HARDWARE_TYPE, CS_PIN, PANEL_COUNT);

const int16_t distanceThreshold = 2000; // stay 2m apart
const uint8_t angleDelta = 30; // go from 90-30 to 90+30

const char* message = "BACK";

uint8_t currentAngle = MID_ANGLE - angleDelta;
bool servoDirection = 0, changePossible = false;

void setup() {
    Serial.begin(115200);
    display.begin();
    Wire.begin();
    if(!distanceSensor.begin())
        Serial.println("Sensor online!");
    servo.attach(SERVO_PIN);
    showOKMessage();
}

void loop() {
    if(currentAngle < MID_ANGLE - angleDelta) {
        currentAngle = MID_ANGLE - angleDelta;
        servoDirection = !servoDirection;
    } else if(currentAngle > MID_ANGLE + angleDelta) {
        currentAngle = MID_ANGLE + angleDelta;
        servoDirection = !servoDirection;
    } else {
        if(servoDirection) currentAngle--;
        else currentAngle++;
    }
    servo.write(currentAngle);
    delay(50);
    if(measureDistance()) showBackMessage();
    else showOKMessage();
}

bool measureDistance() {
    distanceSensor.startRanging();
    int distance = distanceSensor.getDistance();
    distanceSensor.stopRanging();
    Serial.printf("Distance (mm): %d\n", distance);
    if(distance < distanceThreshold && distance != 0)
        return true;
    return false;
}

void showOKMessage() {
    if(!changePossible) display.print("U GOOD");
    changePossible = true;
}

void showBackMessage() {
    if(changePossible) display.print(message);
    changePossible = false;
}

Credits

Evan Rust

120 projects • 1053 followers

IoT, web, and embedded systems enthusiast. Contact me for product reviews or custom project requests.