Published July 16, 2016 © GPL3+

PhotoBlynk

How to use a SparkFun Blynk Board to create a wireless, battery-driven remote control for most digital cameras.

IntermediateFull instructions provided1 hour986

Things used in this project

Hardware components

SparkFun Blynk Board - ESP8266

FDC6401N

Any two NMOS transistors with Gate Threshold Voltage lower than 3.3V should work

Wired shutter release

1s LiPo battery

If you want your wireless remote to be wireless..

Software apps and online services

Blynk

Arduino IDE

Hand tools and fabrication machines

Soldering iron (generic)

Story

Introduction

So you want to take your selfies to the next level? Or you want an easy way of doing long exposure photography? Or maybe you just want to say "Look! I can control my camera with my phone!" Look no further than my first Hackster project.

I have been playing with wired and wireless remote triggers for party photobooths and experimental photography the last 5-6 years, but I have never used WiFi before. When I was sent a link to the IoT For Everyone contest I saw my chance to finally test a new and hopefully easy way of making a remote trigger.

I have tested this remote on different models so I know it should work on lots of brands as long as they have a similar 3-pin remote control plug. I do of course not take any responsibilities if you manage to break your camera by doing this, but if you do break anything then I am very interested in knowing how you did it.

To get going you need a cable for the kind of plug your camera has, and the fastest way of figuring out what you need is to ask ebay. Search for "wired remote" + [camera model] and you should get lots of hits. Buy one of those manual remotes and cut the cable to the desired length. Now you have two usable parts, one lockable dual-stage tactile switch for other projects and one camera cable for your wireless remote.

The ebay shutter release with one of many remote plug types

So the concept of triggering the camera is super easy. You have 3 wires for the remote; Trigger, Focus and ground. When you short Focus to ground your camera will focus, when you short all three you will trigger an exposure.

On my cable White is ground, Yellow is Focus and Red is Trigger. This may vary.

To make it possible to control the shorting to ground from a microcontroller you need relays or transistors. I use two NMOS transistors to do the work, they do not require any complicated circuits or calculations as long as the threshold voltage for turning the gate completely on is lower than the logic signal from the controller (3.3V on the Sparkfun Blynk board). The FDC6401N is two of these in one packace, in addition it is tiny and can tolerate really high currents so I use these for almost anything that needs switching.

The FDC6401N is small enough

Wiring

You connect the pins the following way to get things working:

Ground wire: Sparkfun Blynk board GND and Source on both transistors

Focus wire: Drain on NMOS1

Trigger wire: Drain on NMOS2

Gate on NMOS1: Sparkfun Blynk board pin 12

Gate on NMOS2: Sparkfun Blynk board pin 13

Unfortunately I have managed to delete the PCB design i have used here, it is more or less a breakout board for the ssot-6 package, so if you are skilled at soldering and gluegunning you don't acutally need a PCB at all. Upon request I will make a new PCB design as a shield to connect directly to the Blynk board pins.

Solder this stuff up, connect to the camera and your hardware is good to go.

When soldering is complete and with some too long jumper wires the wireless remote is complete!

You might want to put it in some kind of box, perhaps with a flash shoe mount?

The next step is firmware. My first attempt at using Arduino code was a pleasant surprise, I love the infinite amount of libraries! I only used SimpleTimer in addition to the ones i got when following the Sparkfun Blynk board tutorial.

On the Blynk app I have one button for focus, one for trigger and a slider for selecting how long the exposure will last. If the slider is set to 0 the trigger will last for 1/10 s, enough to capture one photo with normal settings on the camera. If you set the camera exposure time to "bulb" you can capture a long exposure photo with the time set by the slider.

I added an LCD that counts how long you need to wait.

The Arduino code and link to the Blynk app is attached, so test for yourself!

This is where the super cool video of my phone with the Blynk app and the camera triggering next to it should be. The only two gadgets I have that can film are the phone and the camera I want in the video. It is 2 am local time and the deadline for the contest is right around the corner. I had not planned this well enough...

Tips and Tricks:

If you want to make sure you have the fastest triggering possible, set the focus where you want it and turn off autofocus on the camera itself.

When using autofocus it may be a bit slow to react, so setting the slider to a couple of seconds may be necessary to make sure you focus before the camera is triggered.

If you want to make the remote a bit more modular, go for the 2.5mm jack to camera plug cables you find on ebay, by using those and a female 2.5mm 3-pin jack connected to the transistors you can connect to "any" camera.

My original plan was a bit more optimistic, but time has a way of passing too fast, if you want inspiration for making this remote a bit more advanced you can check the initial idea out here: https://www.hackster.io/challenges/sparkfun-blynk-contest/ideas/3780

Code

Arduino code

#define BLYNK_PRINT Serial    // Comment this out to disable prints and save space
#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>
#include <Adafruit_NeoPixel.h>
#include <SimpleTimer.h>

////////////////////
// Blynk Settings //
////////////////////
char BlynkAuth[] = "Your auth token here";
char WiFiNetwork[] = "Your wifi name here";
char WiFiPassword[] = "Your password here";

///////////////////////
// Hardware Settings //
///////////////////////
#define WS2812_PIN 4 // Pin connected to WS2812 LED
#define BUTTON_PIN 0
#define LED_PIN    5
#define FOCUS_PIN  12
#define TRIGGER_PIN  13
WidgetLCD lcd(V10);

bool isFirstConnect = true;
SimpleTimer timer; // Create a Timer object called "timer"! 
int timerId = 0;
int countdownId = 0;

Adafruit_NeoPixel rgb = Adafruit_NeoPixel(1, WS2812_PIN, NEO_GRB + NEO_KHZ800);
bool focus_lock = false;
bool exposure_ongoing = false;
int exposure_time = 0;
int countdown_time = 0;

BLYNK_WRITE(V0) // Store new exposure time from V0
{
  exposure_time = param[0].asInt();

  Serial.print("Exposure time: ");
  Serial.println(exposure_time, DEC);
}

BLYNK_WRITE(V1) // Handle focus lock
{
  if (param[0].asInt()) //V1 is high, so focus should be locked
  {
    digitalWrite(FOCUS_PIN, HIGH);   
    focus_lock = true;

    Serial.print("Focus locked\n");
  }
  else
  {
    digitalWrite(FOCUS_PIN, LOW);   
    focus_lock = false;

    Serial.print("Focus unlocked\n");
  }

}

BLYNK_WRITE(V2) // Handle trigger
{
  if (param[0].asInt()) //V2 button is high
  {
    digitalWrite(TRIGGER_PIN, HIGH);   
    digitalWrite(FOCUS_PIN, HIGH);   

    if (exposure_time > 0) //long exposure/continous trigger
    {
      //Start timer 
      timerId = timer.setTimeout((exposure_time * 1000), exposure_done);

      //Start interval timer for blynk app "LCD" update
      countdownId = timer.setInterval(1000, exposure_countdown);
      countdown_time = 0;
      lcd.clear();
      lcd.print(4, 0, "Exp ");
      lcd.print(8, 0, exposure_time);
      lcd.print(4, 1, "Cnt ");
      lcd.print(8, 1, 0);
    }
    else //Just a short trig, 100ms should be enough
    {
      lcd.clear();
      timerId = timer.setTimeout(100, exposure_done);
    }

    exposure_ongoing = true;
    Serial.print("Capture!\n");
    digitalWrite(LED_PIN, HIGH);
  }
  else if (exposure_ongoing) //V2 button low while exposure is ongoing
  {
    //Stop exposure
    timer.deleteTimer(timerId);
    exposure_done();
  }
}

BLYNK_CONNECTED() //At first connect or reconnecto
{
  //Make sure the app knows if exposure is ongoing
  if (exposure_ongoing)
  {
    Blynk.virtualWrite(V2, HIGH); 
  }
  else
  {
    Blynk.virtualWrite(V2, LOW); 
  }

  //Recommended by tutorial
  if (isFirstConnect) {
    Blynk.syncAll();
  }
  isFirstConnect = false;
}

void exposure_done() //Stop exposure
{
  digitalWrite(TRIGGER_PIN, LOW);   
  if (focus_lock == false){
    digitalWrite(FOCUS_PIN, LOW);   
  }
  
  exposure_ongoing = false;
  Serial.print("Capture done\n");
  digitalWrite(LED_PIN, LOW);
  Blynk.virtualWrite(V2, LOW);   
  
  //Stop Blynk app "LCD" update
  if (countdownId) 
  {
    timer.deleteTimer(countdownId);
    countdownId = 0;   
  }
  lcd.clear();
}

void exposure_countdown()
{
  //Update Blynk app "LCD" with the elapsed time
  lcd.print(8, 1, ++countdown_time);
}

void setup()
{
  // Initialize hardware
  Serial.begin(9600); // Serial
  rgb.begin(); // RGB LED
  pinMode(BUTTON_PIN, INPUT); // Button input
  pinMode(LED_PIN, OUTPUT); // LED output
  pinMode(FOCUS_PIN, OUTPUT); // FOCUS output
  pinMode(TRIGGER_PIN, OUTPUT); // TRIGGER output

  // Initialize Blynk
  Blynk.begin(BlynkAuth, WiFiNetwork, WiFiPassword);
}

void loop()
{
  // Execute Blynk.run() as often as possible during the loop
  Blynk.run();

  // Exposure timer
  timer.run();  
}

Credits

Egil Rotevatn

1 project • 2 followers

Electronics engineer with a fondness for making and fixing stuff with my own hands. Likes to take pictures.

Thanks to doc-diy.net and Marcello Romani.

PhotoBlynk

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Introduction

Wiring

Tips and Tricks:

Schematics

Schematics

Code

Arduino code

Credits

Egil Rotevatn

Comments

Embed the widget on your own site

PhotoBlynk

PhotoBlynk

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Introduction

Wiring

Tips and Tricks:

Schematics

Schematics

Code

Arduino code

Credits

Egil Rotevatn

Comments

Related channels and tags