USB MIDI Adapter

/*
 * USB MIDI adapter with "all notes off" filter.
 * 
 * ---
 * 
 * To allow larger sysex packages, modify the Control Surface library as follows:
 * 
 * In:
 * src\MIDI_Parsers\MIDI_MessageTypes.hpp
 * change:
 * uint8_t length;
 * to:
 * size_t length;
 * 
 * In:
 * src/Settings/Settings.hpp
 * change:
 * constexpr size_t SYSEX_BUFFER_SIZE = 128;
 * to:
 * constexpr size_t SYSEX_BUFFER_SIZE = 320;
 * 
 * This should be fixed when Control Surface 2.x will be released.
 * 
 * ---
 * 
 * To use a different USB device name, edit hardware/arduino/avr/boards.txt in your Arduino IDE install using admin privileges.
 * Change:
 * leonardo.build.usb_product="Arduino Leonardo"
 * to:
 * leonardo.build.usb_product="..."
 * change it back after uploading the project to your Arduino device.
 */

#include <Control_Surface.h> // Include the Control Surface library

USBMIDI_Interface midiusb;
// use this one instead to dump all MIDI data to the serial monitor
// USBDebugMIDI_Interface midiusb;
HardwareSerialMIDI_Interface midiser = {Serial1, MIDI_BAUD};

// Create a MIDI pipe factory to connect the MIDI interfaces to eachother and to the Control Surface
MIDI_PipeFactory<4> pipes;

// Example for adding extra controllers:
// CCPotentiometer pot = { A0, MIDI_CC::Expression_Controller };

// pin to which the power LED is connected
const int ledPin = 10;

// Custom MIDI callback that prints incoming messages.
struct MyMIDI_Callbacks : MIDI_Callbacks {
 
  // Callback for channel messages (notes, control change, pitch bend, etc.).
  void onChannelMessage(Parsing_MIDI_Interface &midi) override {
    ChannelMessage cm = midi.getChannelMessage();

    if (cm.header == 0xb0 && cm.data1 == 0x7b) {
      // ignore "all notes off" messages
      return;
    } else if (cm.header == 0x90 && cm.data2 == 0x00) {
      // convert "note on" messages with velocity of 0 to "note off" messages
      cm.header = 0x80;
    }

    midiusb.send(cm);
  }
 
  // Callback for system exclusive messages
  void onSysExMessage(Parsing_MIDI_Interface &midi) override {
    SysExMessage se = midi.getSysExMessage();

    // forward system exclusive messages without changes
    midiusb.send(se);
  }
 
  // Callback for real-time messages
  void onRealTimeMessage(Parsing_MIDI_Interface &midi) override {
    RealTimeMessage rt = midi.getRealTimeMessage();

    // forward real-time messages without changes
    midiusb.send(rt);
  }
 
} callbacks;

// setup code
void setup() {
  Serial.begin(115200);

  // turn on the power LED
  pinMode(ledPin, OUTPUT);
  digitalWrite(ledPin, HIGH);

  // forward MIDI USB to MIDI serial
  midiusb >> pipes >> midiser;
  // send control suface messages only to MIDI USB
  Control_Surface >> pipes >> midiusb;

  // connect both MIDI USB and serial to control surface
  midiser >> pipes >> Control_Surface;
  midiusb >> pipes >> Control_Surface;

  // initialize Control Surface _after_ connecting the interfaces
  Control_Surface.begin();

  // set the callback methods
  midiser.setCallbacks(callbacks);
}

// main processing loop
void loop() {
  Control_Surface.loop();
}