Automatic Tropical Terrarium

#include <DHT.h>
#include <SPI.h>
#include <SD.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include "RTClib.h"

//const int lightRelay = 12;
const int rainRelay = 11;
const int fanRelay = 8;
const int chipSelect = 10;
const int DHTPIN_1 = 5;
const int DHTPIN_2 = 6;

int fanState = 0;
int rainState = 0;

int maxTemp = 29;
int normTemp = 25;

int minHum = 96;

int i = 0;

LiquidCrystal_I2C lcd(0x27, 16, 2);

#define DHTTYPE DHT22
DHT dht_1(DHTPIN_1, DHTTYPE);
DHT dht_2(DHTPIN_2, DHTTYPE);
RTC_DS1307 rtc;

File myFile;
char dateBuffer[12];
char sensBuffer[10];

void setup() {
  Serial.begin(9600);
  while (!Serial) {
    ;
  }

  lcd.init();
  lcd.backlight();
  lcd.setCursor(0, 0);

  if (! rtc.begin()) {
    error("No RTC");
    Serial.flush();
    abort();
  }

  if (! rtc.isrunning()) {
    error("RTC was off. Setting new time.");
    rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));
  }
  //rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));
  Serial.print(F("Initializing SD card..."));
  if (!SD.begin(chipSelect)) {
    error("SD initialization failed");
    while (1);
  }

  Serial.println(F("initialization done."));
  if (SD.exists(F("terralog.txt"))) {
    Serial.println(F("terralog.txt exists."));
  } else {
    Serial.println(F("terralog.txt doesn't exist."));
    Serial.println(F("Creating terraaaaa.txt"));
    myFile = SD.open("terralog.txt", FILE_WRITE);
    myFile.println("date,time,temp_1,temp_2,hum_1,hum_2,fanState, rainState,i");
    myFile.close();
    if (SD.exists("terralog.txt")) {
      Serial.println(F("terralog.txt was successfully created."));
    } else {
      Serial.println(F("File creation failed."));
    }
  }

  pinMode(fanRelay, OUTPUT);
  dht_1.begin();
  dht_2.begin();
  Serial.println(F("date,time,temp_1,temp_2,hum_1,hum_2,fanState,rainState,i"));
}

void loop() {
  float h_1 = dht_1.readHumidity();
  float t_1 = dht_1.readTemperature();
  if (isnan(h_1) || isnan(t_1)) {
    error("DHT 1");
    return;
  }
  float h_2 = dht_2.readHumidity();
  float t_2 = dht_2.readTemperature();
  if (isnan(h_2) || isnan(t_2)) {
    error("DHT 2");
    return;
  }

  DateTime time = rtc.now();
  lcd.setCursor(0, 0);
  lcd.print(t_1);
  lcd.print(", ");
  lcd.print(h_1);
  lcd.setCursor(0, 1);
  lcd.print(t_2);
  lcd.print(", ");
  lcd.print(h_2);

  sprintf(dateBuffer, "%02u-%02u-%04u", time.day(), time.month(), time.year());
  Serial.print(dateBuffer);
  Serial.print(",");
  sprintf(dateBuffer, "%02u:%02u:%02u", time.hour(), time.minute(), time.second());
  Serial.print(dateBuffer);
  Serial.print(F(","));
  Serial.print(t_1);
  Serial.print(F(","));
  Serial.print(t_2);
  Serial.print(F(","));
  Serial.print(h_1);
  Serial.print(F(","));
  Serial.print(h_2);
  Serial.print(F(","));

  File myFile = SD.open("terralog.txt", FILE_WRITE);
  if (!myFile) {
    error("logfile");
  }
  sprintf(dateBuffer, "%02u-%02u-%04u", time.day(), time.month(), time.year());
  myFile.print(dateBuffer);
  myFile.print(",");
  sprintf(dateBuffer, "%02u:%02u:%02u", time.hour(), time.minute(), time.second());
  myFile.print(dateBuffer);
  myFile.print(",");
  myFile.print(t_1);
  myFile.print(",");
  myFile.print(t_2);
  myFile.print(",");
  myFile.print(h_1);
  myFile.print(",");
  myFile.print(h_2);
  myFile.print(",");

  //
  // Temperature Control
  //

  if (t_1 >= maxTemp) {
    fanState = 1;
    digitalWrite(fanRelay, HIGH);
    Serial.print(fanState);
    myFile.print(fanState);
  }
  else if (t_1 < maxTemp && t_1 >= normTemp) {
    Serial.print(fanState);
    myFile.print(fanState);
  }
  else if (t_1 < normTemp) {
    fanState = 0;
    digitalWrite(fanRelay, LOW);
    Serial.print(fanState);
    myFile.print(fanState);
  }

  //
  // Rain Control
  //

  if (h_1 < 80 && fanState == 0) {
    if (i <= 4) {
      rainState = 1;
      digitalWrite(rainRelay, HIGH);
      i++;
    }
    else if (i > 4 && i <= 300) {
      rainState = 2;
      digitalWrite(rainRelay, LOW);
      i++;
    }
  }
  else {
    rainState = 0;
    i = 0;
  }
  Serial.print(",");
  Serial.print(rainState);
  Serial.print(",");
  Serial.print(i);
  
  myFile.println();
  myFile.close();
  Serial.println();
  delay(1000);
}

void error(char *str) {
  Serial.print(F("Fehler: "));
  Serial.println(str);
  lcd.clear();
  lcd.print("Error: ");
  lcd.print(str);
  delay(5000);
  lcd.clear();
  //while(1); //halt command
}