Team BaesLab: Wiroon Sriborrirux, Nipon Sommai, Pariwat Leamsumran, Weradech Khumtong (Em), Tuntikorn Somjai, wasan wiyarun

Published December 24, 2015 © MIT

LinkIt ONE SMS Gateway for Elderly Care@Home

A SMS Gateway for Elderly Monitoring and Alert System at Home

IntermediateFull instructions provided1,636

LinkIt ONE SMS Gateway for Elderly Care@Home

Things used in this project

Hardware components

blueBLE Tag

Android device

Story

1. Introduction

There has been a 13% increase in the Thai aging population in the past half-century. This increase is still growing rapidly and will reach 20% within the next 3 years. Population aging is already becoming a tremendous issue in terms of living arrangements and health care. Moreover normally Thai families will not let their parents to stay at the nursing home but at home instead. However, parents will stay alone on day time because the rest have to go to work. And there is still a lack of long-term geriatric nursing methodologies. So it's important to provide the suitable technology for elderly people when living alone on day time.

SAENSUK is small city (Chonburi, THAILAND) which is a one the top tourist destination and, also there are a number of nursing homes. The city vision is to be the Healthy City within 2020. So the first pilot to prove smart city concept, we have selected only subset of the smart city solutions which is “Smart Healthcare with Elderly houses”.

SaenSuk Smart City Vision

We then designed a low-power wireless device based on CC1110 Bluetooth LE from Texas Instrument, called the blueBLE Tag. It is simply used for the elderly people staying alone at home by just pressing it whenever there are some emergency occurred or help needs. The SMS Gateway powered by LinkIt ONE will always monitor the elderly and will send the sms message to his/her family immediately as shown in figure below.

Push to SMS Conceptual Diagram

2. Features

Press-to-SMS
Out-of-area Alert
SMS Gateway LinkIt ONE Setup via Config file
blueBLE iBeacon Configuration using BAESLab's Android SDK

3. blueBLE Tag

blueBLE necklace tag

Specifications:

High-Performance CC1110 TI SoC with Low-Power 8051 Microcontroller Core
In-System-Programmable Flash, 256 KB
8-KB SRAM
Frequency: 2.4GHz
Modulation: GFSK, Bluetooth Low Power, V4.0
Input Voltage: +3.3 DC
Operating temperature： -10 ℃ ~ +65 ℃
Battery and Temperature Sensor build-in.

3.1 What does blueBLE SDK provide?:

This library allows for easy access to a Bluetooth LE devices. It also offers:

A simple running average RSSI reading.
iBeacon: Get manufacturer data [Raw Data]
iBeacon: Distance indicators (Near, Far, Immediate, Unknown).
iBeacon: Config UUID, Major, Minor, Name and data (buffer 200 bytes)

This will only work on devices with Android 4.3 (API Level 18) and above.

3.2 How to import lib aar to Android Studio:

1. Download blueBLE SDK from the github

2. Copy file blueBLE.aar to your /app/libs

3. Open Project Structure [File --> Project Structure]

4. Push "+" on top left of window

5. Select Import .JAR or .AAR Package

6. Browse file .aar --> OK

3.3 How to use the blueBLE Android App:

APK file for blueBLE Tag configuration. ==> Link
Android code of blueBLE Tag configuration ==> Link

4. LinkIt ONE SMS Gateway at Home

It's simply easy to apply the LinkIt ONE board as sms gateway. So we just design the housing case for it for easily installation at a home.

3D Housing

4.2 SMS Gateway Assembly

From the photo below, we just add two LEDs connected to Pin 12 (LED_POWER) and Pin 13 (LED_SIGNAL). The rest are the battery and all antenna cables.

Inside the SMS Gateway

After assembled, it look like this as photo below. The user can easily install it at any places in the home via the two hanging arms.

Completed SMS Gateway Housing Case

5. Coding LinkIt ONE SMS Gateway

5.1 Gateway configuration file

Before using the sms gateway, the user have to connect the LinkIt ONE board via USB to the computer by changing the DIP switch to "Mass Storage Bootup" and then press the reset button.

Two types of Bootup

The user will find the mounted drive of LinkIt ONE board and after that create the config file named "Config.txt" into the same default directory as shown below.

Config.txt on Internal Flash

There are two parameters i.e.; time_interval and phone_number. First parameter is the value of timeout for starting sending the sms message when the out-of-area is detected.

And the second one is the lists of phone numbers (using the comma "," to separate the phone number) receiving the sms message sent from the SMS Gateway LinkIt ONE. After saving the config file, the user have to change the DIP switch back to "Normal Bootup" and reset the board.

Parameter of Gateway setup

5.2 Press-To-SMS Application

...

void loop() {

int devices = gateway.scanBLE();

if( devices > 0){

numberOfButtonsPressed = gateway.buttonsPressed(devices);

if( numberOfButtonsPressed > 0){

Serial.println("+++++++++++ Alert ++++++++++++");

smsFlag = true;

}

if(gateway.isSIM()){

if(smsFlag){

if(timeOut == 0){

if(gateway.sendSMS(numberOfButtonsPressed, "Help Me.")){

Serial.println("Send SMS complete.");

}

digitalWrite(LED_SIGNAL, !digitalRead(LED_SIGNAL)); //Toggle LED

timeOut++;

if(timeOut >= SMS_TIMEOUT){ // Time out sent SMS 30 second.

smsFlag = false;

timeOut = 0;

}

Press-to-SMS Video Demonstration

5.3 Out-Of-Area Application

...

void loop() {

int member = gateway.scanBLE();

if(!gateway.isLoss(member, RSSI_SIGNAL)){

Serial.println("+++++++++++ Alert ++++++++++++");

smsFlag = true;

}

if(gateway.isSIM()){

if(smsFlag){

if(timeOut == 0){

if(gateway.sendSMS("Out Of Area.")){

Serial.println("Send SMS complete.");

}

digitalWrite(LED_SIGNAL, !digitalRead(LED_SIGNAL)); //Toggle LED

timeOut++;

if(timeOut >= SMS_TIMEOUT){ // Time out sent SMS 30 second.

smsFlag = false;

timeOut = 0;

}

Out-of-Area Video Demonstration

ACKNOWLEDGMENT

This small work is one of big project of IoT Thailand Smart City organised by the collaboration of TRF, NIA, CAT and TESA. We would like to express our gratitude to Saensuk Municipality and Embedded Systems Laboratory, Electrical Engineering Department, Faculty of Engineering, Burapha University for HealthCare Research and Development supports. Moreover our completion of this work could not have been accomplished without the support of MediaTek, Seeedstudio, BAESLab engineer team and SE-EDUCATION (PLC) Ltd.

Schematics

Code

#ifndef _SMSGATEWAY_H_
#define _SMSGATEWAY_H_

#include <LGATT.h>
#include <LGATTClient.h>
#include <LFlash.h>
#include <LStorage.h>
#include <LGSM.h>

#define SIZE_OF_STR_TIME_INTERVAL 13
#define SIZE_OF_STR_PHONE_NUMBER  12
#define SIZE_OF_PHONE_NUMBER 10
#define MAX_PHONE_NUMBER 20
#define MAX_DEVICE_BLE_INFO 10

//#define _DEBUG
#define _DEBUG_INFO


enum mode{
  GET_TIME_INTERVAL = 0,
  GET_PHONE_NUBER
};

typedef struct {
  byte uuid[16];
  byte major[2];
  byte minor[2];
  byte nameBLE[12];
}typeBLEInfo;

// create a uuid for app, this uuid id is to identify a client
static LGATTUUID myUUID("B4B4B4B4-B4B4-B4B4-B4B4-B4B4B4B4B4B4");
static byte myUuid[16] = {0x4A, 0x03, 0x03, 0x19, 0x00, 0x00, 0x11, 0xA0, 0x01, 0x06, 0x42, 0x41, 0x45, 0x53, 0x00, 0x00};

class SMSGateway
{
private:
  LGATTClient c;
  LFile myFile;	
  
public:
  SMSGateway(void);
  ~SMSGateway(void); 
  bool begin();
	
private:
 typeBLEInfo BLEInfo[MAX_DEVICE_BLE_INFO];

 String str1 = "time_interval";
 String str2 = "phone_number";
 String phoneNuber[MAX_PHONE_NUMBER];
 String timeIntervalString[2];
 unsigned long timeInterval;
 unsigned long mtimeInterval;
 byte countT;
 byte countPN;

 
public:
   int scanBLE();
   int buttonsPressed(int num);
   bool isLoss(int num, int rssi);
   bool sendSMS(int numberAlert, const char message[]);
   bool sendSMS(const char message[]);
   bool isSIM();
   
private:
  bool getConfig(String strConfig[], byte *len, byte mode);
	
};

#endif

#include <LGATT.h>
#include <LGATTClient.h>
#include <LFlash.h>
#include <LStorage.h>
#include <LGSM.h>
#include "SMSGateway.h"

#define SMS_TIMEOUT 30
#define RSSI_SIGNAL -90

SMSGateway gateway;
bool smsFlag = false;
int numberOfButtonsPressed = 0;
unsigned int timeOut = 0;

void setup() {
  
    delay(3000);
    Serial.begin(115200);
    gateway.begin();
}

void loop() {

   int member = gateway.scanBLE();

   if(!gateway.isLoss(member, RSSI_SIGNAL)){
      Serial.println("+++++++++++ Alert ++++++++++++");
      smsFlag = true;
   }
     
   if(gateway.isSIM()){
       if(smsFlag){
           if(timeOut == 0){
              if(gateway.sendSMS("Out Of Area.")){
                Serial.println("Send SMS complete.");
              }
           }    
            digitalWrite(LED_SIGNAL, !digitalRead(LED_SIGNAL)); //Toggle LED
            timeOut++;
            if(timeOut >= SMS_TIMEOUT){ // Time out sent SMS 30 second.
              smsFlag = false;
              timeOut = 0;
            }
       }
   }
}

#include <LGATT.h>
#include <LGATTClient.h>
#include <LFlash.h>
#include <LStorage.h>
#include <LGSM.h>
#include "SMSGateway.h"

#define SMS_TIMEOUT 30

SMSGateway gateway;
bool smsFlag = false;
int numberOfButtonsPressed = 0;
unsigned int timeOut = 0;

void setup() {
  
    delay(3000);
    Serial.begin(115200);
    gateway.begin();
}

void loop() {
  
   int devices = gateway.scanBLE();
   
     if( devices > 0){
       numberOfButtonsPressed = gateway.buttonsPressed(devices);
        if( numberOfButtonsPressed > 0){
          Serial.println("+++++++++++ Alert ++++++++++++");
          smsFlag = true;
        }
     }
     
   if(gateway.isSIM()){
       if(smsFlag){
           if(timeOut == 0){
              if(gateway.sendSMS(numberOfButtonsPressed, "Help Me.")){
                Serial.println("Send SMS complete.");
              }
           }    
            digitalWrite(LED_SIGNAL, !digitalRead(LED_SIGNAL)); //Toggle LED
            timeOut++;
            if(timeOut >= SMS_TIMEOUT){ // Time out sent SMS 30 second.
              smsFlag = false;
              timeOut = 0;
            }
       }
   }
}

#include "SMSGateway.h"


SMSGateway::SMSGateway(void)
{
    countT  = 0;
    countPN = 0;
    timeInterval = 0;
    mtimeInterval = 0;
}

SMSGateway::~SMSGateway(void)
{
   
}

bool SMSGateway::begin()
{
     // GATT central begin to start
    if (c.begin(myUUID))
    {
        #ifdef _DEBUG
        Serial.println("LGATT Success to register.");
        #endif
    }
    else
    {
        #ifdef _DEBUG
        Serial.println("LATT Failed to register.");
        #endif
        delay(0xffffffff);
    }
      LFlash.begin();
      myFile = LFlash.open("Config.txt", FILE_WRITE);
      getConfig(timeIntervalString, &countT, GET_TIME_INTERVAL);
      
      #ifdef _DEBUG
      Serial.print("countT: ");
      Serial.println(countT);
      #endif
      
      timeInterval = timeIntervalString[0].toInt(); // ==> to Unit 1S
      Serial.print("timeInterval: ");
      Serial.println(timeInterval);
  
      myFile = LFlash.open("Config.txt", FILE_WRITE);
      getConfig(phoneNuber, &countPN, GET_PHONE_NUBER);
      
      #ifdef _DEBUG
      Serial.print("countPN: ");
      Serial.println(countPN);
      #endif
      
      isSIM();
}

bool SMSGateway::getConfig(String strConfig[], byte *len, byte mode){
  
  String stringOne = "";
  int lashListItem = 0;
  int indexItem = 0;
  char bufRead[256] = "";
  char *pBuf;
  
     pBuf = &bufRead[0];
      
     if (myFile){
       
        #ifdef _DEBUG
        Serial.println("Config.txt:");
        #endif
        
        myFile.seek(0);
        // read from the file until there's nothing else in it:
        while (myFile.available()){      
         *pBuf++ = myFile.read();
        }
        stringOne = String(bufRead);
         
       switch(mode){
         
           case GET_TIME_INTERVAL:
               lashListItem  = stringOne.indexOf(str1);
               indexItem = lashListItem + SIZE_OF_STR_TIME_INTERVAL + 1;
               pBuf = &bufRead[indexItem];
                do{
                  strConfig[0] = stringOne.substring(indexItem, indexItem + *len);
                  *len += 1;
               }while(*pBuf++ && (*pBuf != '\n'));
               *len -= 1;
           break;
           
           case GET_PHONE_NUBER:
            
              lashListItem = stringOne.indexOf(str2);
              indexItem = lashListItem + SIZE_OF_STR_PHONE_NUMBER + 1;
             
              pBuf = &bufRead[indexItem - 1];
              
              do{
                  if(*pBuf == '=' || *pBuf == ','){
                     strConfig[*len] = stringOne.substring(indexItem, indexItem + 10);
                     indexItem += SIZE_OF_PHONE_NUMBER + 1;
                     *len += 1;
                  }
              }while(*pBuf++);
              
              #ifdef _DEBUG
              for(int i = 0; i < *len; i++){
                  Serial.print("Phone number1: ");
                  Serial.println(phoneNuber[i]);
              }
              #endif
              
           break;
       }
        // close the file:
        myFile.close();
    } else {
      
        #ifdef _DEBUG
        Serial.println("error opening Config.txt");
        #endif
    }
    
  return true;
}


int SMSGateway::scanBLE()
{ 
     return c.scan(1);  //Time out 1S.
}


int SMSGateway::buttonsPressed(int num)
{
  LGATTDeviceInfo info = {0};
   typeBLEInfo mInfo;
   int numberAlert = 0;
   for (int i = 0; i < num; i++)
   {
      c.getScanResult(i, info);
      
      #ifdef _DEBUG_INFO
      Serial.printf("[LGATTC ino]dev address : [%x:%x:%x:%x:%x:%x] rssi [%d]", 
      info.bd_addr.addr[5], info.bd_addr.addr[4], info.bd_addr.addr[3], info.bd_addr.addr[2], info.bd_addr.addr[1], info.bd_addr.addr[0],
      info.rssi);
      Serial.println();
      #endif
 
      int lenAdvertData = info.eir[8];
      memcpy(&mInfo, &info.eir[9], lenAdvertData - 1);
      memcpy(&mInfo.nameBLE, &info.eir[9 + lenAdvertData + 2], 12); 
       
      if(memcmp(myUuid, mInfo.uuid, 16 ) == 0){
               
          if(mInfo.minor[1] == 0x12 || mInfo.minor[1] == 0x11){
             memcpy(&BLEInfo[numberAlert], &mInfo, 32);
             numberAlert++;
             
             #ifdef _DEBUG_INFO
             Serial.println("\n<<<<<< Alert >>>>>>\n");
             #endif
             
          }else if(mInfo.minor[1] == 0x02){
            
             #ifdef _DEBUG_INFO
             Serial.println("\n<<<<<< Normal >>>>>>\n");
             #endif
             
          }
      }
   }
  return numberAlert;
}


bool SMSGateway::isLoss(int num, int rssi)
{
  static bool fristScand = false;
   LGATTDeviceInfo info = {0};
   typeBLEInfo mInfo;
   int numberAlert = 0;
     for (int i = 0; i < num; i++){
          c.getScanResult(i, info);
          
          #ifdef _DEBUG_INFO
          Serial.printf("[LGATTC ino]dev address : [%x:%x:%x:%x:%x:%x] rssi [%d]", 
          info.bd_addr.addr[5], info.bd_addr.addr[4], info.bd_addr.addr[3], info.bd_addr.addr[2], info.bd_addr.addr[1], info.bd_addr.addr[0],
          info.rssi);
          Serial.println();
          #endif
  
          int lenAdvertData = info.eir[8];
          memcpy(&mInfo, &info.eir[9], lenAdvertData - 1);
          memcpy(&mInfo.nameBLE, &info.eir[9 + lenAdvertData + 2], 12); 
            
          if(memcmp(myUuid, mInfo.uuid, 16 ) == 0){
              fristScand = true;
              memcpy(&BLEInfo[0], &mInfo, 32);
              
              if(info.rssi > rssi){         
                mtimeInterval = 0;
              }else{
                mtimeInterval++;
                delay(1);
              }
          }       
      } 
 
     
     if(numberAlert == 0 && fristScand == true){
       mtimeInterval++;
       delay(1); 
     }
     
     if(mtimeInterval >= timeInterval){  
       
        #ifdef _DEBUG_INFO
        Serial.println("\n<<<<<< Alert >>>>>>\n");
        #endif
        
        return false;
     }else{
       
        #ifdef _DEBUG_INFO
        Serial.println("\n<<<<<< Normal >>>>>>\n");
        #endif
        
     }
     
     #ifdef _DEBUG
     Serial.print("mtimeInterval: ");
     Serial.println(mtimeInterval);
     #endif
     
    return true;
}


bool SMSGateway::sendSMS(int numberAlert, const char message[])
{

  char buf[SIZE_OF_PHONE_NUMBER];
  
  for(int i = 0; i < numberAlert; i++){
    for(int j = 0; j < countPN; j++){  
      phoneNuber[j].toCharArray(buf, SIZE_OF_PHONE_NUMBER + 1);
      
      #ifdef _DEBUG
      Serial.printf("%s %s",&BLEInfo[i].nameBLE[0], message);
      #endif
      
      LSMS.beginSMS(buf);
      LSMS.printf("%s %s",&BLEInfo[i].nameBLE[0], message);
      LSMS.endSMS();
 
    }
  }
  
  
 return true; 
}

bool SMSGateway::sendSMS(const char message[])
{
  char buf[SIZE_OF_PHONE_NUMBER];

    for(int j = 0; j < countPN; j++){   
      phoneNuber[j].toCharArray(buf, SIZE_OF_PHONE_NUMBER + 1);
      
      #ifdef _DEBUG
      Serial.printf("%s %s",&BLEInfo[0].nameBLE[0], message);
      #endif
      
      LSMS.beginSMS(buf);
      LSMS.printf("%s %s",&BLEInfo[0].nameBLE[0], message);
      LSMS.endSMS();
 
    }

 return true; 
}


bool SMSGateway::isSIM() //Check status SIM.
{
    if(!LSMS.ready()){
      
        #ifdef _DEBUG_INFO
        Serial.println("\n!!!!!!!!! SIM not ready. !!!!!!!!!!!\n");
        delay(1000);
        #endif
        
        return false;
    }
  return true;
}

LinkIt ONE SMS Gateway for Elderly Care@Home

Things used in this project

Hardware components

Story

1. Introduction

2. Features

3. blueBLE Tag

4. LinkIt ONE SMS Gateway at Home

5. Coding LinkIt ONE SMS Gateway

Custom parts and enclosures

3D SMS Gateway Cover - Part I

3D SMS Gateway Cover - Part II

Schematics

blueBLE Tag

Code

SMSGateway.h

Out-of-Area.ino

Press-to-SMS.ino

SMSGateway.cpp

SMS Gateway

Credits

Wiroon Sriborrirux

Nipon Sommai

Pariwat Leamsumran

Weradech Khumtong (Em)

Tuntikorn Somjai

wasan wiyarun

Comments

Embed the widget on your own site

LinkIt ONE SMS Gateway for Elderly Care@Home

LinkIt ONE SMS Gateway for Elderly Care@Home

Things used in this project

Hardware components

Story

1. Introduction

2. Features

3. blueBLE Tag

4. LinkIt ONE SMS Gateway at Home

5. Coding LinkIt ONE SMS Gateway

Custom parts and enclosures

3D SMS Gateway Cover - Part I

3D SMS Gateway Cover - Part II

Schematics

blueBLE Tag

Code

SMSGateway.h

Out-of-Area.ino

Press-to-SMS.ino

SMSGateway.cpp

SMS Gateway

Credits

Wiroon Sriborrirux

Nipon Sommai

Pariwat Leamsumran

Weradech Khumtong (Em)

Tuntikorn Somjai

wasan wiyarun

Comments

Related channels and tags