BUONO UNO R3 with RC522 RFID Reader Kit for Makers

/*=====================================================================================
ARDUINO_CODE_AN_1400001_RFID_RC522.ino
www.inhaos.com

RFID RC522 Demo Code
Rev: 1.0
Date: 18 Mar.2014

Hardware:
  1 * BUONO UNO R3 
  1 * RFID-RC522
  1 * RF ID Card

Tested Platform: 
  Arduino 1.5.4
  
Connection:
  UNO     <->    RFID-RC522
  3V3               VCC
  D5                RST
  GND               GND
  D12               MISO
  D11               MOSI
  D13               SCK
  D10               NSS
  x                 IRQ
=====================================================================================*/

#include <SPI.h>

#define uchar unsigned char
#define uint unsigned int

//data array maxium length
#define MAX_LEN 16

/////////////////////////////////////////////////////////////////////
//set the pin
/////////////////////////////////////////////////////////////////////
const int chipSelectPin = 10;
const int NRSTPD = 5;



//MF522 command bits
#define PCD_IDLE 0x00 //NO action; cancel current commands
#define PCD_AUTHENT 0x0E //verify password key
#define PCD_RECEIVE 0x08 //receive data
#define PCD_TRANSMIT 0x04 //send data
#define PCD_TRANSCEIVE 0x0C //send and receive data
#define PCD_RESETPHASE 0x0F //reset
#define PCD_CALCCRC 0x03 //CRC check and caculation

//Mifare_One card command bits
#define PICC_REQIDL 0x26 //Search the cards that not into sleep mode in the antenna area 
#define PICC_REQALL 0x52 //Search all the cards in the antenna area
#define PICC_ANTICOLL 0x93 //prevent conflict
#define PICC_SElECTTAG 0x93 //select card
#define PICC_AUTHENT1A 0x60 //verify A password key
#define PICC_AUTHENT1B 0x61 //verify B password key
#define PICC_READ 0x30 //read 
#define PICC_WRITE 0xA0 //write
#define PICC_DECREMENT 0xC0 //deduct value
#define PICC_INCREMENT 0xC1 //charge up value
#define PICC_RESTORE 0xC2 //Restore data into buffer
#define PICC_TRANSFER 0xB0 //Save data into buffer
#define PICC_HALT 0x50 //sleep mode


//THe mistake code that return when communicate with MF522
#define MI_OK 0
#define MI_NOTAGERR 1
#define MI_ERR 2


//------------------MFRC522 register ---------------
//Page 0:Command and Status
#define Reserved00 0x00 
#define CommandReg 0x01 
#define CommIEnReg 0x02 
#define DivlEnReg 0x03 
#define CommIrqReg 0x04 
#define DivIrqReg 0x05
#define ErrorReg 0x06 
#define Status1Reg 0x07 
#define Status2Reg 0x08 
#define FIFODataReg 0x09
#define FIFOLevelReg 0x0A
#define WaterLevelReg 0x0B
#define ControlReg 0x0C
#define BitFramingReg 0x0D
#define CollReg 0x0E
#define Reserved01 0x0F
//Page 1:Command 
#define Reserved10 0x10
#define ModeReg 0x11
#define TxModeReg 0x12
#define RxModeReg 0x13
#define TxControlReg 0x14
#define TxAutoReg 0x15
#define TxSelReg 0x16
#define RxSelReg 0x17
#define RxThresholdReg 0x18
#define DemodReg 0x19
#define Reserved11 0x1A
#define Reserved12 0x1B
#define MifareReg 0x1C
#define Reserved13 0x1D
#define Reserved14 0x1E
#define SerialSpeedReg 0x1F
//Page 2:CFG 
#define Reserved20 0x20 
#define CRCResultRegM 0x21
#define CRCResultRegL 0x22
#define Reserved21 0x23
#define ModWidthReg 0x24
#define Reserved22 0x25
#define RFCfgReg 0x26
#define GsNReg 0x27
#define CWGsPReg 0x28
#define ModGsPReg 0x29
#define TModeReg 0x2A
#define TPrescalerReg 0x2B
#define TReloadRegH 0x2C
#define TReloadRegL 0x2D
#define TCounterValueRegH 0x2E
#define TCounterValueRegL 0x2F
//Page 3:TestRegister 
#define Reserved30 0x30
#define TestSel1Reg 0x31
#define TestSel2Reg 0x32
#define TestPinEnReg 0x33
#define TestPinValueReg 0x34
#define TestBusReg 0x35
#define AutoTestReg 0x36
#define VersionReg 0x37
#define AnalogTestReg 0x38
#define TestDAC1Reg 0x39 
#define TestDAC2Reg 0x3A 
#define TestADCReg 0x3B 
#define Reserved31 0x3C 
#define Reserved32 0x3D 
#define Reserved33 0x3E 
#define Reserved34 0x3F
//-----------------------------------------------

//4 bytes Serial number of card, the 5 bytes is verfiy bytes
uchar serNum[5];


void setup() 
{ 
  Serial.begin(57600); 

  SPI.begin();

  pinMode(chipSelectPin,OUTPUT); // Set digital pin 10 as OUTPUT to connect it to the RFID /ENABLE pin 
  digitalWrite(chipSelectPin, LOW); // Activate the RFID reader
  pinMode(NRSTPD,OUTPUT); // Set digital pin 5 , Not Reset and Power-down

  MFRC522_Init(); 
}


void loop()
{

  uchar status;
  uchar str[MAX_LEN];


  // Search card, return card types
  status = MFRC522_Request(PICC_REQIDL, str); 
  if (status != MI_OK)
  {
    return;
  }


  // Show card type
  ShowCardType(str);

  //Prevent conflict, return the 4 bytes Serial number of the card
  status = MFRC522_Anticoll(str);

  // str[0..3]: serial number of the card
  // str[4]: XOR checksum of the SN.
  if (status == MI_OK)
  {
    Serial.print("The card's number is: ");
    memcpy(serNum, str, 5);
    ShowCardID(serNum);

    // Check people associated with card ID
    uchar* id = serNum;
    if( id[0]==0x4B && id[1]==0xE6 && id[2]==0xD1 && id[3]==0x3B ) {
      Serial.println("Hello Mary!");
    } 
    else if(id[0]==0x3B && id[1]==0xE6 && id[2]==0xD1 && id[3]==0x3B) {
      Serial.println("Hello Greg!");
    }
    else{
      Serial.println("Hello unkown guy!");
    }
  }


  MFRC522_Halt(); //command the card into sleep mode 

  delay(200);
}

/*
 * FunctionShowCardID
 * DescriptionShow Card ID
 * Input parameterID string
 * ReturnNull
 */
void ShowCardID(uchar *id)
{
  int IDlen=4;
  for(int i=0; i<IDlen; i++){
    Serial.print(0x0F & (id[i]>>4), HEX);
    Serial.print(0x0F & id[i],HEX);
  }
  Serial.println("");
}

/*
 * FunctionShowCardType
 * DescriptionShow Card type
 * Input parameterType string
 * ReturnNull
 */
void ShowCardType(uchar* type)
{
  Serial.print("Card type: ");
  if(type[0]==0x04&&type[1]==0x00) 
    Serial.println("MFOne-S50");
  else if(type[0]==0x02&&type[1]==0x00)
    Serial.println("MFOne-S70");
  else if(type[0]==0x44&&type[1]==0x00)
    Serial.println("MF-UltraLight");
  else if(type[0]==0x08&&type[1]==0x00)
    Serial.println("MF-Pro");
  else if(type[0]==0x44&&type[1]==0x03)
    Serial.println("MF Desire");
  else
    Serial.println("Unknown");
}

/*
 * FunctionWrite_MFRC5200
 * Descriptionwrite a byte data into one register of MR RC522
 * Input parameteraddr--register addressval--the value that need to write in
 * ReturnNull
 */
void Write_MFRC522(uchar addr, uchar val)
{
  digitalWrite(chipSelectPin, LOW);

  //address format0XXXXXX0
  SPI.transfer((addr<<1)&0x7E); 
  SPI.transfer(val);

  digitalWrite(chipSelectPin, HIGH);
}


/*
 * FunctionRead_MFRC522
 * Descriptionread a byte data into one register of MR RC522
 * Input parameteraddr--register address
 * Returnreturn the read value
 */
uchar Read_MFRC522(uchar addr)
{
  uchar val;

  digitalWrite(chipSelectPin, LOW);

  //address format1XXXXXX0
  SPI.transfer(((addr<<1)&0x7E) | 0x80); 
  val =SPI.transfer(0x00);

  digitalWrite(chipSelectPin, HIGH);

  return val; 
}

/*
 * FunctionSetBitMask
 * Descriptionset RC522 register bit
 * Input parameterreg--register address;mask--value
 * Returnnull
 */
void SetBitMask(uchar reg, uchar mask) 
{
  uchar tmp;
  tmp = Read_MFRC522(reg);
  Write_MFRC522(reg, tmp | mask); // set bit mask
}


/*
 * FunctionClearBitMask
 * Descriptionclear RC522 register bit
 * Input parameterreg--register address;mask--value
 * Returnnull
 */
void ClearBitMask(uchar reg, uchar mask) 
{
  uchar tmp;
  tmp = Read_MFRC522(reg);
  Write_MFRC522(reg, tmp & (~mask)); // clear bit mask
} 


/*
 * FunctionAntennaOn
 * DescriptionTurn on antenna, every time turn on or shut down antenna need at least 1ms delay
 * Input parameternull
 * Returnnull
 */
void AntennaOn(void)
{
  uchar temp;

  temp = Read_MFRC522(TxControlReg);
  if (!(temp & 0x03))
  {
    SetBitMask(TxControlReg, 0x03);
  }
}


/*
 * FunctionAntennaOff
 * DescriptionTurn off antenna, every time turn on or shut down antenna need at least 1ms delay
 * Input parameternull
 * Returnnull
 */
void AntennaOff(void)
{
  ClearBitMask(TxControlReg, 0x03);
}


/*
 * FunctionResetMFRC522
 * Description reset RC522
 * Input parameternull
 * Returnnull
 */
void MFRC522_Reset(void)
{
  Write_MFRC522(CommandReg, PCD_RESETPHASE);
}


/*
 * FunctionInitMFRC522
 * Descriptioninitilize RC522
 * Input parameternull
 * Returnnull
 */
void MFRC522_Init(void)
{
  digitalWrite(NRSTPD,HIGH);

  MFRC522_Reset();

  //Timer: TPrescaler*TreloadVal/6.78MHz = 24ms
  Write_MFRC522(TModeReg, 0x8D); //Tauto=1; f(Timer) = 6.78MHz/TPreScaler
  Write_MFRC522(TPrescalerReg, 0x3E); //TModeReg[3..0] + TPrescalerReg
  Write_MFRC522(TReloadRegL, 30); 
  Write_MFRC522(TReloadRegH, 0);

  Write_MFRC522(TxAutoReg, 0x40); //100%ASK
  Write_MFRC522(ModeReg, 0x3D); //CRC initilizate value 0x6363 ???

  //ClearBitMask(Status2Reg, 0x08); //MFCrypto1On=0
  //Write_MFRC522(RxSelReg, 0x86); //RxWait = RxSelReg[5..0]
  //Write_MFRC522(RFCfgReg, 0x7F); //RxGain = 48dB

  AntennaOn(); //turn on antenna
}


/*
 * FunctionMFRC522_Request
 * DescriptionSearching card, read card type
 * Input parameterreqMode--search methods
 * TagType--return card types
 * 0x4400 = Mifare_UltraLight
 * 0x0400 = Mifare_One(S50)
 * 0x0200 = Mifare_One(S70)
 * 0x0800 = Mifare_Pro(X)
 * 0x4403 = Mifare_DESFire
 * returnreturn MI_OK if successed
 */
uchar MFRC522_Request(uchar reqMode, uchar *TagType)
{
  uchar status; 
  uint backBits; //the data bits that received

  Write_MFRC522(BitFramingReg, 0x07); //TxLastBists = BitFramingReg[2..0] ???

  TagType[0] = reqMode;
  status = MFRC522_ToCard(PCD_TRANSCEIVE, TagType, 1, TagType, &backBits);

  if ((status != MI_OK) || (backBits != 0x10))
  { 
    status = MI_ERR;
  }

  return status;
}


/*
 * FunctionMFRC522_ToCard
 * Descriptioncommunicate between RC522 and ISO14443
 * Input parametercommand--MF522 command bits
 * sendData--send data to card via rc522
 * sendLen--send data length 
 * backData--the return data from card
 * backLen--the length of return data
 * returnreturn MI_OK if successed
 */
uchar MFRC522_ToCard(uchar command, uchar *sendData, uchar sendLen, uchar *backData, uint *backLen)
{
  uchar status = MI_ERR;
  uchar irqEn = 0x00;
  uchar waitIRq = 0x00;
  uchar lastBits;
  uchar n;
  uint i;

  switch (command)
  {
  case PCD_AUTHENT: //verify card password
    {
      irqEn = 0x12;
      waitIRq = 0x10;
      break;
    }
  case PCD_TRANSCEIVE: //send data in the FIFO
    {
      irqEn = 0x77;
      waitIRq = 0x30;
      break;
    }
  default:
    break;
  }

  Write_MFRC522(CommIEnReg, irqEn|0x80); //Allow interruption
  ClearBitMask(CommIrqReg, 0x80); //Clear all the interrupt bits
  SetBitMask(FIFOLevelReg, 0x80); //FlushBuffer=1, FIFO initilizate

  Write_MFRC522(CommandReg, PCD_IDLE); //NO action;cancel current command ???

  //write data into FIFO
  for (i=0; i<sendLen; i++)
  { 
    Write_MFRC522(FIFODataReg, sendData[i]); 
  }

  //procceed it
  Write_MFRC522(CommandReg, command);
  if (command == PCD_TRANSCEIVE)
  { 
    SetBitMask(BitFramingReg, 0x80); //StartSend=1,transmission of data starts 
  } 

  //waite receive data is finished
  i = 2000; //i should adjust according the clock, the maxium the waiting time should be 25 ms???
  do 
  {
    //CommIrqReg[7..0]
    //Set1 TxIRq RxIRq IdleIRq HiAlerIRq LoAlertIRq ErrIRq TimerIRq
    n = Read_MFRC522(CommIrqReg);
    i--;
  }
  while ((i!=0) && !(n&0x01) && !(n&waitIRq));

  ClearBitMask(BitFramingReg, 0x80); //StartSend=0

    if (i != 0)
  { 
    if(!(Read_MFRC522(ErrorReg) & 0x1B)) //BufferOvfl Collerr CRCErr ProtecolErr
    {
      status = MI_OK;
      if (n & irqEn & 0x01)
      { 
        status = MI_NOTAGERR; //?? 
      }

      if (command == PCD_TRANSCEIVE)
      {
        n = Read_MFRC522(FIFOLevelReg);
        lastBits = Read_MFRC522(ControlReg) & 0x07;
        if (lastBits)
        { 
          *backLen = (n-1)*8 + lastBits; 
        }
        else
        { 
          *backLen = n*8; 
        }

        if (n == 0)
        { 
          n = 1; 
        }
        if (n > MAX_LEN)
        { 
          n = MAX_LEN; 
        }

        //read the data from FIFO
        for (i=0; i<n; i++)
        { 
          backData[i] = Read_MFRC522(FIFODataReg); 
        }
      }
    }
    else
    { 
      status = MI_ERR; 
    }

  }

  //SetBitMask(ControlReg,0x80); //timer stops
  //Write_MFRC522(CommandReg, PCD_IDLE); 

  return status;
}


/*
 * FunctionMFRC522_Anticoll
 * DescriptionPrevent conflict, read the card serial number 
 * Input parameterserNum--return the 4 bytes card serial number, the 5th byte is recheck byte
 * returnreturn MI_OK if successed
 */
uchar MFRC522_Anticoll(uchar *serNum)
{
  uchar status;
  uchar i;
  uchar serNumCheck=0;
  uint unLen;

  //ClearBitMask(Status2Reg, 0x08); //strSensclear
  //ClearBitMask(CollReg,0x80); //ValuesAfterColl
  Write_MFRC522(BitFramingReg, 0x00); //TxLastBists = BitFramingReg[2..0]

  serNum[0] = PICC_ANTICOLL;
  serNum[1] = 0x20;
  status = MFRC522_ToCard(PCD_TRANSCEIVE, serNum, 2, serNum, &unLen);

  if (status == MI_OK)
  {
    //Verify card serial number
    for (i=0; i<4; i++)
    { 
      serNumCheck ^= serNum[i];
    }
    if (serNumCheck != serNum[i])
    { 
      status = MI_ERR; 
    }
  }

  //SetBitMask(CollReg, 0x80); //ValuesAfterColl=1

  return status;
} 


/*
 * FunctionCalulateCRC
 * DescriptionUse MF522 to caculate CRC
 * Input parameterpIndata--the CRC data need to be readlen--data lengthpOutData-- the caculated result of CRC
 * returnNull
 */
void CalulateCRC(uchar *pIndata, uchar len, uchar *pOutData)
{
  uchar i, n;

  ClearBitMask(DivIrqReg, 0x04); //CRCIrq = 0
  SetBitMask(FIFOLevelReg, 0x80); //Clear FIFO pointer
  //Write_MFRC522(CommandReg, PCD_IDLE);

  //Write data into FIFO 
  for (i=0; i<len; i++)
  { 
    Write_MFRC522(FIFODataReg, *(pIndata+i)); 
  }
  Write_MFRC522(CommandReg, PCD_CALCCRC);

  //waite CRC caculation to finish
  i = 0xFF;
  do 
  {
    n = Read_MFRC522(DivIrqReg);
    i--;
  }
  while ((i!=0) && !(n&0x04)); //CRCIrq = 1

  //read CRC caculation result
  pOutData[0] = Read_MFRC522(CRCResultRegL);
  pOutData[1] = Read_MFRC522(CRCResultRegM);
}



/*
 * FunctionMFRC522_Write
 * Descriptionwrite block data
 * Input parametersblockAddr--block address;writeData--Write 16 bytes data into block
 * returnreturn MI_OK if successed
 */
uchar MFRC522_Write(uchar blockAddr, uchar *writeData)
{
  uchar status;
  uint recvBits;
  uchar i;
  uchar buff[18]; 

  buff[0] = PICC_WRITE;
  buff[1] = blockAddr;
  CalulateCRC(buff, 2, &buff[2]);
  status = MFRC522_ToCard(PCD_TRANSCEIVE, buff, 4, buff, &recvBits);

  if ((status != MI_OK) || (recvBits != 4) || ((buff[0] & 0x0F) != 0x0A))
  { 
    status = MI_ERR; 
  }

  if (status == MI_OK)
  {
    for (i=0; i<16; i++) //Write 16 bytes data into FIFO
    { 
      buff[i] = *(writeData+i); 
    }
    CalulateCRC(buff, 16, &buff[16]);
    status = MFRC522_ToCard(PCD_TRANSCEIVE, buff, 18, buff, &recvBits);

    if ((status != MI_OK) || (recvBits != 4) || ((buff[0] & 0x0F) != 0x0A))
    { 
      status = MI_ERR; 
    }
  }

  return status;
}


/*
 * FunctionMFRC522_Halt
 * DescriptionCommand the cards into sleep mode
 * Input parametersnull
 * returnnull
 */
void MFRC522_Halt(void)
{
  uchar status;
  uint unLen;
  uchar buff[4]; 

  buff[0] = PICC_HALT;
  buff[1] = 0;
  CalulateCRC(buff, 2, &buff[2]);

  status = MFRC522_ToCard(PCD_TRANSCEIVE, buff, 4, buff,&unLen);
}