Time of Flight modules, some experiments

Using the famous HC-SR04 ultrasonic distance sensor is quite common, while using of Time-of-Flight modules up to now is not. Well, as soon as you get one, you will download the library and run the "Single" sketch and be happy when it works. In case you got more of them you might want to compare them simultaneously. And there comes the problem: they all are configured as I2C devices at adress 0x29 which can not be modified. Even if your microcontroller had more than one I2C port you can address only one module at a time. That is where the multiplexer comes into the game. I used a CMOS CD4052 which was introduced in 1980. It has two inputs A and B to select the channel, and it works bidirectional what is necessary for I2C communication. The wiring is a bit complicated because the pins of the CD4052 are ordered in a crazy manner. Just try to follow the colored lines.

For the selection of the modules I choose Arduino pins 8 and 9, so I can set PORTB = 0, 1, 2, and 3 to select any one of them.

#include <Wire.h>
#include <VL53L0X.h>

VL53L0X sensor[4];
byte maxi = 4;
const byte SEL_A = 8; // PORT B
const byte SEL_B = 9;

void setup() {
  Serial.begin(9600);
  Serial.println(__FILE__ " " __TIME__);
  pinMode(SEL_A, OUTPUT);
  pinMode(SEL_B, OUTPUT);
  Wire.begin();
  for (int i = 0; i < maxi; i++) initSensor(i);
}

void loop() {
  for (int i = 0; i < maxi; i++) getSensor(i);
  Serial.println();
}

void initSensor(int i) {
  PORTB = i;
  VL53L0X *s = &sensor[i];
  s->setTimeout(500);
  if (!s->init()) {
    Serial.print("Failed to detect and initialize sensor ");
    Serial.println(i);
  }
  s->setSignalRateLimit(0.1);
  s->setVcselPulsePeriod(VL53L0X::VcselPeriodPreRange, 18);
  s->setVcselPulsePeriod(VL53L0X::VcselPeriodFinalRange, 14);
  s->setMeasurementTimingBudget(200000);
}

void getSensor(int i) {
  VL53L0X *s = &sensor[i];
  PORTB = i;
  Serial.print(" ");
  long d = s->readRangeSingleMillimeters();
  if (d > 1280) d = 1280;
  if (s->timeoutOccurred()) d = -1;
  Serial.print(d);
  Serial.print(" ");
}

When you are lucky you might get a diagram like this using the Serial Plotter:

As you can see, all the sensors give results differing just one millimeter. If you are less lucky and choose a different set of sensors the plotter might show something like this:

And there is a difference of sixty millimeters between two of the sensors.