Published April 11, 2024 © GPL3+

Compare a bunch of DS18B20 Temperature Sensors

To investigate the internal climate inside a room or even a fridge it is useful to measure the temperatures at different places precisely.

IntermediateFull instructions provided2 hours89

Compare a bunch of DS18B20 Temperature Sensors

Things used in this project

Hardware components

Maxim Integrated DS18B20 Programmable Resolution 1-Wire Digital Thermometer

TFT LCD

Arduino UNO R4 Minima

Story

When I started reading the temperatures at different places, I realized that the results were a bit faulty. That was the reason for me to select sensors that gave the same or at least similar values. I did not like to compare long lists of figures, that is why I used the plotter of the old ARDUINO IDE:

By the way, if you perform continuously readings, the DS18B20 will heat up over the time. After some 75 readings, its internal temperature will increase by nearly 0.25 degrees Celsius. There were long pauses between the sequences of reading:

But at the end, I wanted to run it without a computer, so I got me a TFT LCD to show the results. I went for a 2.4" 320 x 240 display shield using an 8-bit parallel interface, knowing there are some drawbacks of this type. Its touch-screen is not very reliable, and the interface consumes most of the Arduino pins, leaving only a few to connect the sensors. But the set of DALLAS DS18B20 only requires one single pin for all of them. Another drawback is the libraries you need. I found many libraries that did not work at all. The KBV (MCUFRIEND) did its job even very fast and supports a zoo of driver chips (that I do not own), but I was not happy with their function names, for instance this is the command for placing the text cursor:

mylcd.Set_Text_Cousur(0, 0);

(Is there any language world-wide that contains a word like cousor?) Libraries like that should not pass the auditions.

Anyway, the Adafruit naming conventions suit me much better, but I have not been able to get their libraries working. So, at the end of the day I started to write a library of my own and even managed to support the new ARDUINO UNO R4 what the other libraries don't.

In the picture shown above you see five graphs recorded simultaneously at the same place, but obviously the data given by one of them are very different from the data of all the others. As I had a box full of DS18B20, I started to select one which gave the same results as the others.

The disadvantage of using the shield version is you have no access to the pins any more. Fortunately, some clones come with an extra layout: they offer the Serial pins, the I2C pins, and some extra power pins between the ICSP and the analog pins:

So it is easy to mount a small stripboard to carry the sensors to this pins. Some capacitors improve the stability. If your ARDUINO UNO is not equipped with these extra pins, you have to insert a shield like this in between:

Shields to give access to all the pins can be constructed easily using these components:

My initial aim was to connect as many sensors as possible and show as many samples as the width of the TFT LCD by just using an ARDUINO UNO R3. This was possibly only by storing the y-positions of the samples as byte values rather than float (4 bytes each). But when I tried autoscaling, I had to adjust all previous y-position when setting the new scale. And that was the end, I was reaching the limits of the R3 version and had to use the new MINIMA. The problem with R4 is you do no longer have any output PORTs, that makes setting pixels much slower. Especially clearing the screen is four times slower than using the R3 (despite running at 48 MHz).

At the end of the loop function of the sketch in the attachments you will find this line

//while (millis() < t);

If you uncomment this line, the x-axis will be streched to show values samples during the last hour, that is why tickmarks show 10 to 60.

The schematics is more than simple: the TFT shield only leaves pin A5 free to use, so this will be the data input for all the DS18B20. Do not forget to connect a 4.7 kOhms resistor from this input to Vcc.

More attachments coming soon.

/*
  Temperature logger
  max 6 x DS18B20  connected to A5
  TFT LCD 2.4", 320 x 240 shield 8-bit parallel
  autoscaling, taking 320 samples in one hour
  scrolling by software
*/
#include <DallasTemperature.h>
// this lib requires <OneWire.h>
const byte thePin = A5;
OneWire oneWire(thePin);
DallasTemperature s(&oneWire);
int devNum; // Number of devices
const int M = 320; // x-axis
const int N = 6; // max number of sensors
float logs[M][N];
const int x_grid = M / 6;
byte y_grid;

#include "ILI9341.h"
const word color[] = { BLUE, RED, GREEN, CYAN, MAGENTA, YELLOW};
ILI9341 tft;
const int width = M;
const int height = 240;
// portrait mode: 320 px = 1 hour
const int dt = 3600000 / M;
int count = M;
int mini, maxi, minOld, maxOld;

void setup() {
  Serial.begin(9600);
  Serial.println(F(__FILE__));
  // ----- Sensoren DALLAS -----:
  const byte PREC = 12;
  s.begin();
  devNum = s.getDeviceCount();
  Serial.println(devNum);
  DeviceAddress da;
  for (int i = 0; i < devNum; i++)
    if (s.getAddress(da, i))
      s.setResolution(da, PREC);
  // ----- TFT -----:
  tft.begin();
  tft.fillScreen(BLACK);
}

void loop() {
  long t = millis() + dt;
  boolean change = false;
  getValues();
  // Skalierung:
  mini = 100; // impossible values
  maxi = -100;
  for (int i = 0; i < devNum; i++)
    for (int j = count; j < M; j++) {
      mini = min(mini, logs[j][i]);
      maxi = max(maxi, logs[j][i]);
    }
  maxi++;
  if ( (mini != minOld) || (maxi != maxOld) ) {
    minOld = mini;
    maxOld = maxi;
    change = true;
  }
  Serial.print(mini);
  Serial.print(" ");
  Serial.println(maxi);

  drawGrid(change); // neu zeichnen
  drawLogs();
  //while (millis() < t);
  if (count > 1) count--;
}

void getValues() {
  s.requestTemperatures();
  DeviceAddress da;// messen:
  for (int i = 0; i < devNum; i++)
    if (s.getAddress(da, i)) {
      Serial.print(F("\t"));
      float neu = s.getTempC(da);
      if (neu == DEVICE_DISCONNECTED_C)
        Serial.println("error");
      else {
        Serial.print(neu);
      }
      // kopiere alle um 1 nach links:
      for (int j = 0; j <= M - 2; j++)
        logs[j][i] = logs[j + 1][i];
      // trage neuen Wert hinten (rechts) ein:
      logs[M - 1][i] = neu; // <-----
    }
  Serial.println();
}

void drawLogs() {
  for (int i = 0; i < devNum; i++) {
    for (int j = count; j <= M - 2; j++) {
      int x1 = j + 1; // from
      int x2 = j + 2; // to
      // erase:
      int y1 = t2y(logs[j - 1][i]);
      int y2 = t2y(logs[j][i]); // erase
      // loesche alte Linie:
      tft.drawLine(x1, y1, x2, y2, BLACK);
      // draw:
      int z1 = y2;
      int z2 = t2y(logs[j + 1][i]); // draw
      // Schreibe neue Linie
      tft.drawLine(x1, z1, x2, z2, color[i]);
    }
  }
}

int t2y(float t) {
  return height * (1 - (t - mini)  / (maxi - mini));
}

void drawGrid(boolean erase) {
  if (erase) tft.fillScreen(BLACK);
  tft.setCursor(2, 2);
  tft.print("sensors: ");
  tft.print(devNum);
  y_grid = height / (maxi - mini);
  for (int y = 0, t = maxi; y <= height; y = y + y_grid, t--) {
    tft.drawDottedFastHLine(0, y, width, CYAN);
    tft.setCursor(2, y - 10);
    tft.print(t);
    tft.print(" C");
    tft.drawCircle(16, y - 10, 2, WHITE);
  }
  for (int x = 0, i = 0;
       x < width;
       x = x + x_grid, i = i + 10) {
    tft.drawDottedFastVLine(x, 0, height, CYAN);
    tft.setCursor(x - 12, height - 10);
    tft.print(i);
  }
  // x-Achse
  tft.drawFastHLine(0, height, width, WHITE);
  // y-Achse
  tft.drawFastVLine(0, 0, height, WHITE);
}

Credits

Klausj

66 projects • 5 followers

Compare a bunch of DS18B20 Temperature Sensors

Things used in this project

Hardware components

Story

Code

Library for LCD TFT 2,4" shield 8-bit parallel interface, ILI9341

Temperature Logger for up to 6 DS18B20

Credits

Klausj

Comments

Embed the widget on your own site

Compare a bunch of DS18B20 Temperature Sensors

Compare a bunch of DS18B20 Temperature Sensors

Things used in this project

Hardware components

Story

Code

Library for LCD TFT 2,4" shield 8-bit parallel interface, ILI9341

Temperature Logger for up to 6 DS18B20

Credits

Klausj

Comments

Related channels and tags