Published February 19, 2020 © GPL3+

Build a Laser Tachometer

Build you own Arduino-based laser tachometer for around $10 and learn something while doing it!

IntermediateFull instructions provided6 hours4,259

Story

Building a laser tachometer allows you to measure an object's rotational speed without mechanically interfering its movement. This specific project is based on Arduino and it's capable of measuring up to 99.999 RPM. I strongly recommend you to watch the building process first in order to see all the details of the build as well as the final test.

Laser Tachometer Project

Basic theory:

A constantly emitted laser beam from the tachometer gets reflected back to it when the part being measured completes one turn. A sensor gets triggered by its light and sends a pulse to the Arduino, which keeps the exact time in which those pulses take place and calculates the rotational speed in RPM doing basic math.

Step 1:

Connect and solder all the components as shown in the video. The wiring is very simple.

128 x 32’’ I2C OLED Display to Arduino Nano as follows:

GND to GND
VCC to 5V
SCK to A5
SDA to A4

9V Battery to Arduino Nano as follows:

Negative (black) to GND
Positive (red) to Push Button Pin 1 and Push Button Pin 2 to VIN

Laser Diode to Laser Sensor Module as follows:

Positive (red) to VCC
Negative (blue) to GND

Laser Sensor Module to Arduino Nano as follows:

VCC to 5V
GND to GND
OUT to D2

Step 2:

Upload the program to your Arduino Nano.

Step 3:

Print all the STL files. You can find them here:

https://www.thingiverse.com/thing:4152617

Laser Tachometer .STL files

Step 4:

Assemble all the parts as shown in the video.

Code

Arduino code

//Laser Tachometer by Elite Worm (YouTube.com/c/EliteWorm)
//Version 1.0.0

//Make sure you have all the libraries installed!

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 32

#define OLED_RESET     4
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

const byte sensor = 2;

volatile unsigned long t_pulse_started_volatile = 0;
volatile unsigned long t_pulse_duration_volatile = 0;
unsigned long t_pulse_started = 0;
unsigned long t_pulse_duration = 0;

long rpm_sum = 0;
long rpm_reading[100];
long rpm_average = 0;
byte n_max = 0;
byte n = 0;

volatile bool timeout = 1;
volatile bool newpulse = 0;

void setup() {
  
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    for(;;);
  }
  
  pinMode(sensor, INPUT);
  attachInterrupt(digitalPinToInterrupt(sensor), ISR_sensor, RISING);
 
}

void loop() { 
   
   noInterrupts();
   t_pulse_started = t_pulse_started_volatile;
   t_pulse_duration = t_pulse_duration_volatile;
   interrupts();
   
   if(((micros() - t_pulse_started) > 2000000) && timeout == 0 && newpulse == 0) {
           
     timeout = 1;
     rpm_average = 0;
     n = 0;

   };
   
   if(timeout == 0){
     
     if(newpulse){
       
       rpm_reading[n] = (60000000 / t_pulse_duration);
       n_max = constrain(map(rpm_reading[n], 60, 100000, 0, 100), 0, 100);
       n++;
       newpulse = 0;
       
       if(n > n_max){
       
         for (byte i = 0; i <= n_max; i++) {
           
           rpm_sum = rpm_sum + rpm_reading[i];
     
         };
         
         rpm_average = rpm_sum / (n_max + 1);     
         rpm_sum = 0;
         n = 0;
         
       }
       
     }
   
   }

updatedisplay();
  
}

void updatedisplay() {
  
  byte x = 0;
  
  display.clearDisplay();
  display.setTextSize(3);
  
  if(rpm_average < 10) x = 80;
  if(rpm_average >= 10 && rpm_average < 100) x = 62;
  if(rpm_average >= 100 && rpm_average < 1000) x = 44;
  if(rpm_average >= 1000 && rpm_average < 10000) x = 26;
  if(rpm_average >= 10000 && rpm_average < 100000) x = 8;
  
  display.setTextColor(SSD1306_WHITE);
  
  if(rpm_average < 100000){
    
    display.setCursor(x, 6); 
    display.print(rpm_average);
    display.setTextSize(1);
    display.setCursor(104, 20);
    display.print(F("RPM"));
    display.display();
  
  } else {
      
      display.setTextSize(2);
      display.setCursor(13, 8); 
      display.print(F("MAX LIMIT"));
      display.display();
    
    }
  
}

void ISR_sensor() {
 
  t_pulse_duration_volatile = micros() - t_pulse_started_volatile;
  t_pulse_started_volatile = micros();
  timeout = 0;
  newpulse = 1;
 
}

Credits

Elite Worm

7 projects • 3 followers

I make projects involving electronics, 3D printing and more. YouTube.com/c/EliteWorm

Build a Laser Tachometer

Story

Basic theory:

Step 1:

Step 2:

Step 3:

Step 4:

Custom parts and enclosures

Laser Tachometer

Code

Arduino code

Credits

Elite Worm

Comments

Embed the widget on your own site

Build a Laser Tachometer

Build a Laser Tachometer

Story

Basic theory:

Step 1:

Step 2:

Step 3:

Step 4:

Custom parts and enclosures

Laser Tachometer

Code

Arduino code

Credits

Elite Worm

Comments

Related channels and tags