Published October 13, 2015

CC3220SF IoT Workshop with CCS Cloud

Learn LaunchPad by building incredible IoT applications. Awesome!

BeginnerFull instructions provided3,340

Things used in this project

Hardware components

Texas Instruments CC3220SF-LAUNCHXL SimpleLink Wi-Fi CC3220SF LaunchPad

Texas Instruments BOOSTXL-EDUMKII Educational BoosterPack MK II

Software apps and online services

Texas Instruments Energia

Texas Instruments Code Composer Studio

Story

Introduction

The purpose of this guide is to get user's up and running with the SimpleLink CC3220SF LaunchPad and Educational BoosterPack MKII. The user will also be exposed to the basics of adding internet connectivity to a design using Temboo.

The IDE in this tutorial will be CCS Cloud, but we will be using the Energia framework, which utilizes the Wiring/Arduino APIs, available inside of CCS Cloud. CCS Cloud features faster compilation and enhanced debug capabilities on the CC3220SF over the Energia IDE. You can still run these labs in Energia IDE if you prefer.

Before we begin, please ensure you:

1. Sign up for a myTI account to access CCS Cloud. If you already have one (access to online resources, samples, store), you can login at http://dev.ti.com. Chrome browser is the recommended web browser for this experience.

a. When you first log in to CCS Cloud, the helper text will walk you through installing the drivers, cloud agent, and browser extensions. CCS Cloud is compatible with Mac OS, Windows, and Linux. When installing the extensions, you may need to refresh your page a few times.

2. Create an account on Temboo.com.

3. (Optional) Create a twitter handle on Twitter.com. This is not necessary as we have a dummy handle that you can use in this exercise, but if you wish to use your own twitter it is very easy to switch over.

Lab 1: Blink a LED

LED Diagram

The goal of this lab is to verify the hardware and software is setup correctly and to give the student a first taste of rapid prototyping in Energia. Blinking an LED is the "Hello World" of electronics and is often the first thing done on new hardware.

1. Plug in your LaunchPad with the supplied USB cable.

2. Open up CCS Cloud in your browser (http://dev.ti.com)

a. If this is your first time running CCS Cloud you will need to install the browser extension (firefox or chrome) and the TI Cloud Agent.

3. Go to File > New Energia Project

4. Under device, select CC3220 ARM -> CC3220SF-LAUNCHXL (80MHz).

5. Under Basic Examples, Select Blink.ino and click Finish.

6. Examine the code to see the basic structure of the program.

a. All Energia programs have two required functions: setup() and loop(). Setup is run one at startup and then loop runs continuously.

b. pinMode() is used to set the direction of a GPIO.

c. digitalWrite() is used to set the state of a GPIO.

d. delay pauses execution for a given number of milliseconds.

7. To upload the code, click the Run or Flash button at the top right. This will compile and upload your program to the board. If you would like to do a compile only of your code without flashing you can click the hammer icon to build your project.

a. You may be prompted to update your firmware. Click update and continue.

8. After programming completes verify that the redLED is blinking on your LaunchPad.

9. To take this a step further try:

a. Fading the LEDs by changing the calls from digitalWrite() to analogWrite().

b. Try using the other LEDs on the board

i. RED_LED

ii. GREEN_LED

Lab 2: Educational BoosterPack

Energia pin map for Educational BoosterPack MK II

BOOSTXL-EDUMKII

The goal of this lab is to familiarize the student with the concept of a BoosterPack and how software libraries can speed development of advanced applications. You can find the example code inside of Energia and on www.energia.nu/edumkii.

1. Plug the Educational BoosterPack MKII into the LaunchPad’s BoosterPack headers.

2. From the File menu at the top of the window ,select New Energia Project. Under device, select CC3220 ARM -> CC3220SF-LAUNCHXL (80MHz). Under Examples -> 09.EducationalBP_MKII -> AccelerometerLED. Click Finish.

3. Read through the code. There is a line you will need to uncomment in order to change the ADC resolution so the example works correctly. Uncomment this line before proceeding to the next step.

Type in a caption for this image

4. Click the the Run or Flash button. This will compile and upload your program to the board.

5. Verify the color of the RGB LED changes when you tilt the board.

6. Dance around with your LaunchPad like you were at a rave.

a. If you want to read the serial data: From the Target menu at the top of the window, select Connect COM Port, and then pick the serial port associated with your CC3220SF Launchpad and the correct baud rate (115200 is common). You can view the serial data in the debug window under the Serial tab. If it looks unreadable you can try hitting the reset button on your LaunchPad.

7. Experiment with other examples for the Educational BoosterPack. Try combining multiple examples to build a full application. You can find more information about the examples at www.energia.nu/edumkii.

a. This time is meant to be free form so you can experiment and learn on your own.

b. If you wish to try once of the LCD examples you'll need to do a special workaround to fix a bug on the CC3220SF. The error will say "Platform not supported"

1. Delete the EduBPMKII_Screen folder

2. upload the the files in this zip folder to the main LCD example folder

3. Change the .ino to include the local files. Replace #include <LCD_Screen.h> etc. with #include "LCD_Screen.h"

4. Now you should be able to build the project.

Delete the EduBPMKII_Screen folder and upload the files in the zip. Change the <> to "" in the includes of your main .ino file

When you feel you have a good grasp of the EDUMKII you can move on to the next section.

Lab 3: IoT

The goal of this lab is to introduce the student to the basics of adding internet connectivity to an application.

The stack should now be Educational BoosterPack MKII + CC3220SF-LAUNCHXL

NOTE: If you are at a location that requires your MAC address to be registered before you can connect, download the getMAC program from the bottom of this page, compile, and run it on your LaunchPad. Open the serial monitor and reset the board by pressing the reset push button. The MAC address should now be displayed in the serial terminal. Make note of the address and register your device on the network.

Part 1: Weather

For the lab, we are going to use the Temboo cloud service to get the weather report whenever we push a button. Go to www.temboo.com/hardware/ti and sign up for an account. Once logged in find the GetTemperature API under Yahoo > Weather > GetTemperature.

Make sure Texas Instruments is selected from the top menu and IoT mode is on. You can add a new connection which will let you type in your WiFi router information.

Enter the address you want to get the temperature from and Temboo will generate the Energia code for you. You can click the send to CCS Cloud button and it should import the project into your workspace.

Make sure to include the TembooAccount.h. It should be included in the import but can also be done manually. To add this right click the project folder and select new file. Call the new file TembooAccount.h and press enter. You should have a blank area where you can paste the TembooAccount.h information.

When you upload the code, go to Target > Connect COM port and check the Serial output and you should see the LaunchPad connecting to Wi-Fi and getting the temperature data.

The Temboo site does a great job of explaining how to use their APIs so refer there for additional help.

Part 2: Twitter

1. Create a new program in CCS Cloud (File -> New Energia Sketch). Call it Twitter and select Empty Sketch.

2. Go to your Temboo account and navigate to the Twitter Choreos. Once there, go to Tweets, Statuses Update

3. Make sure Texas Instruments is selected and IoT mode is on. You can add a new connection which will let you type in your WiFi router information. If you did this in part 1 it should be saved.

4. Start typing in the fields for the connection box. Scroll down this page and copy the contents of the header file box.

5. Make sure to include the TembooAccount.h. To add this right click the project folder and select new file. Call the new file TembooAccount.h and press enter. You should have a blank area where you can past the TembooAccount.h information.

6. Paste the contents of the header file box into TembooAccount.h

7. Update the WIFI_SSID #define to reflect your wireless network.

a. If your network has a password create a new#define called WPA_PASSWORD and type your password in quotes

8. On Temboo, copy the contents of the Code box and paste them into the main Temboo.ino file. Be sure to select everything in that sketch before replacing it with the code from Temboo.

9. You can copy the code from the provided LCD_Joystick+Twitter.ino file at the bottom of this Hackster page. If you are making changes manually, Add the following lines to your program:

// Set Choreo inputs

StringAccessTokenValue ="3361531038-PfYFeP3r9ykZ9hZzWCcsaQp4AHSHAX0BcBbVQ2K";

StatusesUpdateChoreo.addInput("AccessToken",AccessTokenValue);

StringAccessTokenSecretValue = "RzlVqDmPHKaD1L315bvJ2MqhKfJW7Zsr76YfkomuKrL2a";

StatusesUpdateChoreo.addInput("AccessTokenSecret",AccessTokenSecretValue);

StringConsumerSecretValue ="f1S7cqL2aJi3HVyFOnQ9wCihao0080OIQxm0rpp41AB1yc91xJ";

StatusesUpdateChoreo.addInput("ConsumerSecret",ConsumerSecretValue);

StringConsumerKeyValue = "oa1pgd6ibazJFOa8X9Gp5BrmF";

StatusesUpdateChoreo.addInput("ConsumerKey",ConsumerKeyValue);

StringStatusUpdateValue = "Look ma, I'm on twitter!";

StatusesUpdateChoreo.addInput("StatusUpdate",StatusUpdateValue);

These lines should be placed right before the call to StatusesUpdateChoreo.run(). For the tweet to be successful it needs to be unique so please change the text. Twitter will prevent duplicate messages from being sent within a certain time frame.

No Shenanigans Please!

10. Click the Run button to compile and upload the code to your board. Open the serial console to view the debug output.

11. If everything looks ok in the serial monitor, goto twitter.com/iotdump and see if your tweet was successful.

12. Experiment by combining this twitter functionality with some of the example for the Educational BoosterPack. For example you could use the LCD_Joystick example to send out the coordinates of the cursor on screen whenever Button 2 is pressed.

a. A completed example of this is provided in the code section below.

Conclusion

That is a good sample of basic IoT prototyping with TI LaunchPad. There is obviously a lot more to do with Temboo or other cloud services that are accessible through Energia libraries. There are also many hardware combination to try when connecting things wirelessly. You can learn more about the TI LaunchPad ecosystem at www.ti.com/launchpad and explore the Energia website for more ideas and help.

///
/// @mainpage	LCD_Joystick
///
/// @details	Joystick controlled cursor
/// @n
/// @n @a		Developed with [embedXcode+](http://embedXcode.weebly.com)
///
/// @author		Rei Vilo
/// @author		http://embeddedcomputing.weebly.com
/// @date		11/12/2013 10:19
/// @version	101
///
/// @copyright	(c) Rei Vilo, 2013
/// @copyright	CC = BY SA NC
///
/// @see		ReadMe.txt for references
///


///
/// @file		LCD_Joystick.ino
/// @brief		Main sketch
///
/// @details	Joystick controlled cursor
/// @n @a		Developed with [embedXcode+](http://embedXcode.weebly.com)
///
/// @author		Rei Vilo
/// @author		http://embeddedcomputing.weebly.com
/// @date		11/12/2013 10:19
/// @version	101
///
/// @copyright	(c) Rei Vilo, 2013
/// @copyright	CC = BY SA NC
///
/// @see		ReadMe.txt for references
/// @n
///
#define ENERGIA

// Core library for code-sense
#if defined(ENERGIA) // LaunchPad MSP430, Stellaris and Tiva, Experimeter Board FR5739 specific
#include "Energia.h"
#else // error
#error Platform not defined
#endif

#define TEMBOO_ACCOUNT "XXXXXXX"  // Your Temboo account name 
#define TEMBOO_APP_KEY_NAME "XXXXXXX"  // Your Temboo app name
#define TEMBOO_APP_KEY "XXXXXXX"  // Your Temboo app key

#define WIFI_SSID "XXXXXXX"


// Prototypes


// Include application, user and local libraries
#include <SPI.h>

#include <LCD_screen.h>
#include <LCD_screen_font.h>
#include <LCD_utilities.h>
#include <Screen_HX8353E.h>
#include <Terminal12e.h>
#include <Terminal6e.h>
#include <Terminal8e.h>


#include <WiFi.h>
#include <WiFiClient.h>

#include <Temboo.h>
#include "TembooAccount.h" // Contains Temboo account information


Screen_HX8353E myScreen;
WiFiClient client;
TembooChoreo StatusesUpdateChoreo(client);



// Define variables and constants
#define joystickX 2
#define joystickY 26
uint16_t x, y, x00, y00;
uint16_t colour;
uint32_t z;


// Add setup code
void setup()
{
  
    int wifiStatus = WL_IDLE_STATUS;

    Serial.begin(9600);
 
    // By default MSP432 has analogRead() set to 10 bits. 
    // This Sketch assumes 12 bits. Uncomment to line below to set analogRead()
    // to 12 bit resolution for MSP432.
    analogReadResolution(12);

    myScreen.begin();
    x00 = 0;
    y00 = 0;
    
    // Determine if the WiFi Shield is present
    Serial.print("\n\nShield:");
    if (WiFi.status() == WL_NO_SHIELD) {
      Serial.println("FAIL");

      // If there's no WiFi shield, stop here
      while(true);
    }
  
    // Try to connect to the local WiFi network
    while(wifiStatus != WL_CONNECTED) {
      Serial.print("WiFi:");
      wifiStatus = WiFi.begin(WIFI_SSID);
      if (wifiStatus == WL_CONNECTED) {
        Serial.println("OK");
      } else {
        Serial.println("FAIL");
      }
      delay(5000);
    }

    
}

void configureTemboo(void)
{

    // Invoke the Temboo client
    StatusesUpdateChoreo.begin();

    // Set Temboo account credentials
    StatusesUpdateChoreo.setAccountName(TEMBOO_ACCOUNT);
    StatusesUpdateChoreo.setAppKeyName(TEMBOO_APP_KEY_NAME);
    StatusesUpdateChoreo.setAppKey(TEMBOO_APP_KEY);

    // Set Choreo inputs
    String AccessTokenValue = "3361531038-PfYFeP3r9ykZ9hZzWCcsaQp4AHSHAX0BcBbVQ2K";
    StatusesUpdateChoreo.addInput("AccessToken", AccessTokenValue);
    String AccessTokenSecretValue = "RzlVqDmPHKaD1L315bvJ2MqhKfJW7Zsr76YfkomuKrL2a";
    StatusesUpdateChoreo.addInput("AccessTokenSecret", AccessTokenSecretValue);
    String ConsumerSecretValue = "f1S7cqL2aJi3HVyFOnQ9wCihao0080OIQxm0rpp41AB1yc91xJ";
    StatusesUpdateChoreo.addInput("ConsumerSecret", ConsumerSecretValue);
    String ConsumerKeyValue = "oa1pgd6ibazJFOa8X9Gp5BrmF";
    StatusesUpdateChoreo.addInput("ConsumerKey", ConsumerKeyValue);

    // Identify the Choreo to run
    StatusesUpdateChoreo.setChoreo("/Library/Twitter/Tweets/StatusesUpdate");  
  
}

void tweetData(int x, int y)
{
    //Update text
    String StatusUpdateValue = "Look ma, I'm on twitter! x=" + i32toa(x) + " y=" + i32toa(y);
    StatusesUpdateChoreo.addInput("StatusUpdate", StatusUpdateValue);

    // Run the Choreo
    StatusesUpdateChoreo.run();
    

    //StatusesUpdateChoreo.close();
  
  
}

// Add loop code
void loop()
{
    x = map(analogRead(joystickX), 0, 4096, 0, 128);
    y = map(analogRead(joystickY), 0, 4096, 128, 0);
    if (x < 1)      x = 1;
    if (x > 126)    x = 126;
    if (y < 1)      y = 1;
    if (y > 126)    y = 126;
    
    if ((x00 != x) || (y00 != y)) {
        z = (uint32_t)((x-64)*(x-64)+(y-64)*(y-64)) >> 8;
        if (z > 4)      colour = redColour;
        else if (z > 1) colour = yellowColour;
        else            colour = greenColour;
        
        myScreen.dRectangle(x00-1, y00-1, 3, 3, blackColour);
        myScreen.dRectangle(x-1, y-1, 3, 3, colour);
        x00 = x;
        y00 = y;
    }
    
    
    myScreen.gText(0, myScreen.screenSizeY()-myScreen.fontSizeY(),
                   "x=" + i32toa((int16_t)x-64, 10, 1, 6) +" y=" + i32toa(64-(int16_t)y, 10, 1, 6),
                   colour);
                   
   if(digitalRead(32)){
     tweetData((int16_t)x-64, 64-(int16_t)y);  
     
     
     
   }
}

//
// Screen_HX8353E.cpp
// Library C++ code
// ----------------------------------
// Developed with embedXcode
// http://embedXcode.weebly.com
//
// Project new_screen_HX8353
//
// Created by Rei VILO, mars 07, 2013 09:21
// embedXcode.weebly.com
//
// Apr 25, 2014
// Support for new LaunchPads with
// . MSP430F5529
// . LM4F120H5QR TM4C123GH6PM
// . TM4C1294NCPDT TM4C1294XNCZAD
//
//
// Copyright  Rei VILO, 2013-2014
// License CC = BY NC SA
//
// See Screen_HX8353E.h and ReadMe.txt for references
//
// Library header
#include "Screen_HX8353E.h"
///
#define HX8353E_WIDTH  128
#define HX8353E_HEIGHT 128
#define HX8353E_MADCTL_MY  0x80
#define HX8353E_MADCTL_MX  0x40
#define HX8353E_MADCTL_MV  0x20
#define HX8353E_MADCTL_ML  0x10
#define HX8353E_MADCTL_RGB 0x08
#define HX8353E_MADCTL_MH  0x04
#define HX8353E_NOP     0x00
#define HX8353E_SWRESET 0x01
#define HX8353E_RDDID   0x04
#define HX8353E_RDDST   0x09
#define HX8353E_SLPIN   0x10
#define HX8353E_SLPOUT  0x11
#define HX8353E_PTLON   0x12
#define HX8353E_NORON   0x13
#define HX8353E_INVOFF  0x20
#define HX8353E_INVON   0x21
#define HX8353E_GAMSET  0x26
#define HX8353E_DISPOFF 0x28
#define HX8353E_DISPON  0x29
#define HX8353E_CASET   0x2A
#define HX8353E_RASET   0x2B
#define HX8353E_RAMWR   0x2C
#define HX8353E_RGBSET  0x2d
#define HX8353E_RAMRD   0x2E
#define HX8353E_PTLAR   0x30
#define HX8353E_MADCTL  0x36
#define HX8353E_COLMOD  0x3A
#define HX8353E_SETPWCTR 0xB1
#define HX8353E_SETDISPL 0xB2
#define HX8353E_FRMCTR3  0xB3
#define HX8353E_SETCYC   0xB4
#define HX8353E_SETBGP   0xb5
#define HX8353E_SETVCOM  0xB6
#define HX8353E_SETSTBA  0xC0
#define HX8353E_SETID    0xC3
#define HX8353E_GETHID   0xd0
#define HX8353E_SETGAMMA 0xE0
Screen_HX8353E::Screen_HX8353E() {
#if defined(__LM4F120H5QR__) || defined(__MSP430F5529__) || defined(__TM4C123GH6PM__) || defined(__TM4C1294NCPDT__) || defined(__TM4C1294XNCZAD__) || defined(__MSP432P401R__)
    _pinReset          = 17;
    _pinDataCommand    = 31;
    _pinChipSelect     = 13;
    _pinBacklight      = NULL;
#else
#error Platform not supported
#endif
}
Screen_HX8353E::Screen_HX8353E(uint8_t resetPin, uint8_t dataCommandPin, uint8_t chipSelectPin, uint8_t backlightPin)
{
    _pinReset = resetPin;
    _pinDataCommand = dataCommandPin;
    _pinChipSelect = chipSelectPin;
    _pinBacklight = backlightPin;
};
void Screen_HX8353E::begin()
{
#if defined(__LM4F120H5QR__)
    SPI.setModule(2);
#endif
    SPI.begin();
    SPI.setClockDivider(SPI_CLOCK_DIV2);
    SPI.setBitOrder(MSBFIRST);
    SPI.setDataMode(SPI_MODE0);
    if (_pinReset!=NULL) pinMode(_pinReset, OUTPUT);
    if (_pinBacklight!=NULL) pinMode(_pinBacklight, OUTPUT);
    pinMode(_pinDataCommand, OUTPUT);
    pinMode(_pinChipSelect, OUTPUT);
    if (_pinBacklight!=NULL) digitalWrite(_pinBacklight, HIGH);
    if (_pinReset!=NULL) digitalWrite(_pinReset, 1);
    delay(100);
    if (_pinReset!=NULL) digitalWrite(_pinReset, 0);
    delay(50);
    if (_pinReset!=NULL) digitalWrite(_pinReset, 1);
    delay(120);
    _writeCommand(HX8353E_SWRESET);
    delay(150);
    _writeCommand(HX8353E_SLPOUT);
    delay(200);
    _writeRegister(HX8353E_GAMSET, 0x04);
    _writeCommand(HX8353E_SETPWCTR);
    _writeData88(0x0A, 0x14);
    _writeCommand(HX8353E_SETSTBA);
    _writeData88(0x0A, 0x00);
    _writeRegister(HX8353E_COLMOD, 0x05);
    delay(10);
    _writeRegister(HX8353E_MADCTL, HX8353E_MADCTL_RGB);
    _writeCommand(HX8353E_CASET);
    _writeData8888(0x00, 0x00, 0x00, 0x79);
    _writeCommand(HX8353E_RASET);
    _writeData8888(0x00, 0x00, 0x00, 0x79);
    _writeCommand(HX8353E_NORON);
    delay(10);
    _writeCommand(HX8353E_DISPON);
    delay(120);
    _writeCommand(HX8353E_RAMWR);
    setBacklight(true);
    setOrientation(0);
    _screenWidth  = HX8353E_WIDTH;
    _screenHeigth = HX8353E_HEIGHT;
    _penSolid  = false;
    _fontSolid = true;
    _flagRead  = false;
    _touchTrim = 0;
    clear();
}
String Screen_HX8353E::WhoAmI()
{
    return "LCD MKII BoosterPack";
}
void Screen_HX8353E::invert(boolean flag)
{
    _writeCommand(flag ? HX8353E_INVON : HX8353E_INVOFF);
}
void Screen_HX8353E::setBacklight(boolean flag)
{
    if (_pinBacklight!=NULL) digitalWrite(_pinBacklight, flag);
}
void Screen_HX8353E::setDisplay(boolean flag)
{
    if (_pinBacklight!=NULL) setBacklight(flag);
}
void Screen_HX8353E::setOrientation(uint8_t orientation)
{
    _orientation = orientation % 4;
    _writeCommand(HX8353E_MADCTL);
    switch (_orientation) {
        case 0:
            _writeData(HX8353E_MADCTL_MX | HX8353E_MADCTL_MY | HX8353E_MADCTL_RGB);
            break;
        case 1:
            _writeData(HX8353E_MADCTL_MY | HX8353E_MADCTL_MV | HX8353E_MADCTL_RGB);
            break;
        case 2:
            _writeData(HX8353E_MADCTL_RGB);
            break;
        case 3:
            _writeData(HX8353E_MADCTL_MX | HX8353E_MADCTL_MV | HX8353E_MADCTL_RGB);
            break;
    }
}
void Screen_HX8353E::_fastFill(uint16_t x1, uint16_t y1, uint16_t x2, uint16_t y2, uint16_t colour)
{
    if (x1 > x2) _swap(x1, x2);
    if (y1 > y2) _swap(y1, y2);
    _setWindow(x1, y1, x2, y2);
    digitalWrite(_pinDataCommand, HIGH);
    digitalWrite(_pinChipSelect, LOW);
    uint8_t hi = highByte(colour);
    uint8_t lo = lowByte(colour);
    for (uint32_t t=(uint32_t)(y2-y1+1)*(x2-x1+1); t>0; t--) {
        SPI.transfer(hi);
        SPI.transfer(lo);
    }
    digitalWrite(_pinChipSelect, HIGH);
}
void Screen_HX8353E::_setPoint(uint16_t x1, uint16_t y1, uint16_t colour)
{
    if( (x1 < 0) || (x1 >= screenSizeX()) || (y1 < 0) || (y1 >= screenSizeY()) ) return;
    _setWindow(x1, y1, x1+1, y1+1);
    _writeData16(colour);
}
void Screen_HX8353E::_setWindow(uint16_t x0, uint16_t y0, uint16_t x1, uint16_t y1)
{
    switch (_orientation) {
        case 0:
            x0 += 2;
            y0 += 3;
            x1 += 2;
            y1 += 3;
            break;
        case 1:
            x0 += 3;
            y0 += 2;
            x1 += 3;
            y1 += 2;
            break;
        case 2:
            x0 += 2;
            y0 += 1;
            x1 += 2;
            y1 += 1;
            break;
        case 3:
            x0 += 1;
            y0 += 2;
            x1 += 1;
            y1 += 2;
            break;
        default:
            break;
    }
    _writeCommand(HX8353E_CASET);
    _writeData16(x0);
    _writeData16(x1);
    _writeCommand(HX8353E_RASET);
    _writeData16(y0);
    _writeData16(y1);
    _writeCommand(HX8353E_RAMWR);
}
void Screen_HX8353E::_writeRegister(uint8_t command8, uint8_t data8)
{
    _writeCommand(command8);
    _writeData(data8);
}
void Screen_HX8353E::_writeCommand(uint8_t command8)
{
    digitalWrite(_pinDataCommand, LOW);
    digitalWrite(_pinChipSelect, LOW);
    SPI.transfer(command8);
    digitalWrite(_pinChipSelect, HIGH);
}
void Screen_HX8353E::_writeData(uint8_t data8)
{
    digitalWrite(_pinDataCommand, HIGH);
    digitalWrite(_pinChipSelect, LOW);
    SPI.transfer(data8);
    digitalWrite(_pinChipSelect, HIGH);
}
void Screen_HX8353E::_writeData16(uint16_t data16)
{
    digitalWrite(_pinDataCommand, HIGH);
    digitalWrite(_pinChipSelect, LOW);
    SPI.transfer(highByte(data16));
    SPI.transfer(lowByte(data16));
    digitalWrite(_pinChipSelect, HIGH);
}
void Screen_HX8353E::_writeData88(uint8_t dataHigh8, uint8_t dataLow8)
{
    digitalWrite(_pinDataCommand, HIGH);
    digitalWrite(_pinChipSelect, LOW);
    SPI.transfer(dataHigh8);
    SPI.transfer(dataLow8);
    digitalWrite(_pinChipSelect, HIGH);
}
void Screen_HX8353E::_writeData8888(uint8_t dataHigh8, uint8_t dataLow8, uint8_t data8_3, uint8_t data8_4)
{
    _writeData(dataHigh8);
    _writeData(dataLow8);
    _writeData(data8_3);
    _writeData(data8_4);
}
void Screen_HX8353E::_getRawTouch(uint16_t &x0, uint16_t &y0, uint16_t &z0)
{
    x0 = 0;
    y0 = 0;
    z0 = 0;
}

#include <SPI.h>
#include <WiFi.h>
#include <WiFiClient.h>

void setup()
{
  // put your setup code here, to run once:

  Serial.begin(115200);
  
    // print your MAC address:
  byte mac[6];
  WiFi.macAddress(mac);
  Serial.print("MAC address: ");
  Serial.print(mac[5], HEX);
  Serial.print(":");
  Serial.print(mac[4], HEX);
  Serial.print(":");
  Serial.print(mac[3], HEX);
  Serial.print(":");
  Serial.print(mac[2], HEX);
  Serial.print(":");
  Serial.print(mac[1], HEX);
  Serial.print(":");
  Serial.println(mac[0], HEX);

  
}

void loop()
{
  // put your main code here, to run repeatedly:
  
}

Credits

Mark Easley

65 projects • 137 followers

Texas Instruments LaunchPad SW Engineer

Adrian Fernandez

10 projects • 47 followers

peek a boo my name is adrian

CC3220SF IoT Workshop with CCS Cloud

Things used in this project

Hardware components

Software apps and online services

Story

Introduction

Lab 1: Blink a LED

Lab 2: Educational BoosterPack

Lab 3: IoT

Part 1: Weather

Part 2: Twitter

Conclusion

Code

LCD_Joystick + Twitter

Screen_HX8353E.cpp LCD Driver fix for MSP432

getMAC

Credits

Mark Easley

Adrian Fernandez

Comments

Embed the widget on your own site

CC3220SF IoT Workshop with CCS Cloud

CC3220SF IoT Workshop with CCS Cloud

Things used in this project

Hardware components

Software apps and online services

Story

Introduction

Lab 1: Blink a LED

Lab 2: Educational BoosterPack

Lab 3: IoT

Part 1: Weather

Part 2: Twitter

Conclusion

Code

LCD_Joystick + Twitter

Screen_HX8353E.cpp LCD Driver fix for MSP432

getMAC

Credits

Mark Easley

Adrian Fernandez

Comments

Related channels and tags