EcoBouteille

#include <SPI.h>
#include <MFRC522.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <MKRWAN.h>

#define NOTE_B0 31
#define NOTE_C1 33
#define NOTE_CS1 35
#define NOTE_D1 37
#define NOTE_DS1 39
#define NOTE_E1 41
#define NOTE_F1 44
#define NOTE_FS1 46
#define NOTE_G1 49
#define NOTE_GS1 52
#define NOTE_A1 55
#define NOTE_AS1 58
#define NOTE_B1 62
#define NOTE_C2 65
#define NOTE_CS2 69
#define NOTE_D2 73
#define NOTE_DS2 78
#define NOTE_E2 82
#define NOTE_F2 87
#define NOTE_FS2 93
#define NOTE_G2 98
#define NOTE_GS2 104
#define NOTE_A2 110
#define NOTE_AS2 117
#define NOTE_B2 123
#define NOTE_C3 131
#define NOTE_CS3 139
#define NOTE_D3 147
#define NOTE_DS3 156
#define NOTE_E3 165
#define NOTE_F3 175
#define NOTE_FS3 185
#define NOTE_G3 196
#define NOTE_GS3 208
#define NOTE_A3 220
#define NOTE_AS3 233
#define NOTE_B3 247
#define NOTE_C4 262
#define NOTE_CS4 277
#define NOTE_D4 294
#define NOTE_DS4 311
#define NOTE_E4 330
#define NOTE_F4 349
#define NOTE_FS4 370
#define NOTE_G4 392
#define NOTE_GS4 415
#define NOTE_A4 440
#define NOTE_AS4 466
#define NOTE_B4 494
#define NOTE_C5 523
#define NOTE_CS5 554
#define NOTE_D5 587
#define NOTE_DS5 622
#define NOTE_E5 659
#define NOTE_F5 698
#define NOTE_FS5 740
#define NOTE_G5 784
#define NOTE_GS5 831
#define NOTE_A5 880
#define NOTE_AS5 932
#define NOTE_B5 988
#define NOTE_C6 1047
#define NOTE_CS6 1109
#define NOTE_D6 1175
#define NOTE_DS6 1245
#define NOTE_E6 1319
#define NOTE_F6 1397
#define NOTE_FS6 1480
#define NOTE_G6 1568
#define NOTE_GS6 1661
#define NOTE_A6 1760
#define NOTE_AS6 1865
#define NOTE_B6 1976
#define NOTE_C7 2093
#define NOTE_CS7 2217
#define NOTE_D7 2349
#define NOTE_DS7 2489
#define NOTE_E7 2637
#define NOTE_F7 2794
#define NOTE_FS7 2960
#define NOTE_G7 3136
#define NOTE_GS7 3322
#define NOTE_A7 3520
#define NOTE_AS7 3729
#define NOTE_B7 3951
#define NOTE_C8 4186
#define NOTE_CS8 4435
#define NOTE_D8 4699
#define NOTE_DS8 4978











#define RST_PIN 15
#define SS_PIN 21

MFRC522 mfrc522(SS_PIN, RST_PIN);
LoRaModem modem;
LiquidCrystal_I2C lcd(0x27, 16, 2);

const char *appEui = "YourAppEUI";
const char *appKey = "YourAppKey";

const int buttonPin = 3;
const int buttonPin1 = 0;
const int buttonPin2 = 1;
const int buttonPin3 = 2;

int lastButtonState = HIGH;
int previousButtonState1 = LOW;
int previousButtonState2 = LOW;
int previousButtonState3 = LOW;

const int isObstaclePin = 4;
int isObstacle = HIGH;

const int buzzer = 5;

int melody[] = {
  NOTE_E5, NOTE_D5, NOTE_FS4, NOTE_GS4, 
  NOTE_CS5, NOTE_B4, NOTE_D4, NOTE_E4, 
  NOTE_B4, NOTE_A4, NOTE_CS4, NOTE_E4,
  NOTE_A4
};

int durations[] = {
  8, 8, 4, 4,
  8, 8, 4, 4,
  8, 8, 4, 4,
  2
};



bool allButtonsPressed = false;
byte localUserList[3] = {0x0A, 0x0B, 0x0C};
byte correspondingId = 0xFF;
int nbBottles = 0;
bool isConnected = false;


void setup() {
  Serial.begin(9600);
  pinMode(isObstaclePin, INPUT);
  pinMode(buzzer, OUTPUT);
  noTone(buzzer);
  pinMode(21, OUTPUT);
  SPI.begin();
  mfrc522.PCD_Init();
  Serial.println("Approchez une carte RFID...");



  int size = sizeof(durations) / sizeof(int);
  for (int note = 0; note < size; note++) {
    //to calculate the note duration, take one second divided by the note type.
    //e.g. quarter note = 1000 / 4, eighth note = 1000/8, etc.
    int duration = 1000 / durations[note];
    tone(buzzer, melody[note], duration);

    //to distinguish the notes, set a minimum time between them.
    //the note's duration + 30% seems to work well:
    int pauseBetweenNotes = duration * 1.30;
    delay(pauseBetweenNotes);
    
    //stop the tone playing:
    noTone(buzzer);
  }


  if (!modem.begin(EU868)) {
    Serial.println("Échec de l'initialisation du modem LoRa");
    while (1);
  }

  int connected = modem.joinOTAA(appEui, appKey);
  if (!connected) {
    Serial.println("Échec de la connexion au réseau");
    while (1);
  }
  lcd.init();
  lcd.backlight();

  Serial.println("Connecté au réseau TTN");
  pinMode(buttonPin, INPUT_PULLUP);
  initializeLCD();
}

void initializeLCD() {

  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Scannez votre");
  lcd.setCursor(0, 1);
  lcd.print("carte svp");
  delay(500);
}

void checkRFID() {
  if (!mfrc522.PICC_IsNewCardPresent() || !mfrc522.PICC_ReadCardSerial()) {
    delay(50);
    return;
  }

  MFRC522::MIFARE_Key key;
  for (byte i = 0; i < 6; i++) key.keyByte[i] = 0xFF;

  byte sector = 1;
  byte blockAddr = 4;
  byte trailerBlock = 7;
  MFRC522::StatusCode status = mfrc522.PCD_Authenticate(MFRC522::PICC_CMD_MF_AUTH_KEY_A, trailerBlock, &key, &(mfrc522.uid));

  if (status != MFRC522::STATUS_OK) {
    Serial.print("PCD_Authenticate() failed: ");
    Serial.println(mfrc522.GetStatusCodeName(status));
    return;
  }

  byte buffer[18];
  byte size = sizeof(buffer);
  status = mfrc522.MIFARE_Read(blockAddr, buffer, &size);

  if (status != MFRC522::STATUS_OK) {
    Serial.print("MIFARE_Read() failed: ");
    Serial.println(mfrc522.GetStatusCodeName(status));
  } else {
    byte id = buffer[0];
    Serial.print("ID lu depuis la carte : ");
    Serial.println(id, HEX);

    for (unsigned i = 0; i < 3; i++) {
      if (id == localUserList[i]) {
        isConnected = true;
        correspondingId = id;
            tone(buzzer, 500);
      delay(400);
     noTone(buzzer);
     delay(100);
        displayWelcomeMessage(id);
       break;
      } else {
        
        if(i == 2){
   
        tone(buzzer, 300);
        delay(200);
        noTone(buzzer);
        delay(50);
        tone(buzzer, 300);
        delay(200);
        noTone(buzzer);
        delay(50);
          lcd.clear();
         lcd.setCursor(0, 0);
         lcd.print("ID non");
         lcd.setCursor(0, 1);
        lcd.print("reconnu");
         delay(500);
        Serial.println("ID non reconnu.");
        initializeLCD();
      }
      }
    }
  }
  mfrc522.PICC_HaltA();
  mfrc522.PCD_StopCrypto1();
}

void displayWelcomeMessage(byte id) {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Connecte !");
  delay(1000);

  String messageAccueil = "Bonjour ! ";
  lcd.setCursor(0, 0);
  lcd.print(messageAccueil.substring(0, min(0 + 16, messageAccueil.length())));
  delay(300); // bistoufly

  for (int i = 0; i < messageAccueil.length(); i++) {
    lcd.setCursor(0, 0);
    lcd.print(messageAccueil.substring(i, min(i + 16, messageAccueil.length())));
    delay(150);
  }

  lcd.clear();
  lcd.setCursor(0, 0);
  String messageBouteilles = "Ins. Bouteille";
  lcd.print(messageBouteilles);
}

void checkButtons() {
  int buttonState1 = digitalRead(buttonPin1);
  int buttonState2 = digitalRead(buttonPin2);
  int buttonState3 = digitalRead(buttonPin3);

  if (buttonState1 == HIGH && buttonState2 == HIGH && buttonState3 == HIGH) {
    allButtonsPressed = true;
  }

  if (allButtonsPressed && buttonState1 == LOW && buttonState2 == LOW && buttonState3 == LOW) {
    tone(buzzer, 1000);
    delay(200);
    noTone(buzzer);
    delay(100);
    nbBottles++;
    displayBottleInsertionMessage();
    allButtonsPressed = false;
  }

  previousButtonState1 = buttonState1;
  previousButtonState2 = buttonState2;
  previousButtonState3 = buttonState3;
}


void checkIR() {
    isObstacle = digitalRead(isObstaclePin);
    if (isObstacle == LOW) {
        tone(buzzer, 1000);
        delay(200);
        noTone(buzzer);
        delay(100);
        Serial.println("bouteille detectee");
        
        nbBottles++;
       displayBottleInsertionMessage();

    } else {
       // Serial.println("clear");
      
        delay(300);
    }
   // delay(200);
}



void displayBottleInsertionMessage() {
  lcd.clear();
  lcd.setCursor(0, 0);
  String messageBouteilles = "Ins. Bouteille";
  lcd.print(messageBouteilles);

  String message = "Bouteille remise ";
  lcd.setCursor(0, 1);
  lcd.print(message.substring(0, min(0 + 16, message.length())));
  delay(300);

  for (int i = 0; i < message.length(); i++) {
    lcd.setCursor(0, 1);
    lcd.print(message.substring(i, min(i + 16, message.length())));
    delay(200);
  }

  delay(50);
  lcd.setCursor(0, 1);
  lcd.print("                ");
}

void checkDisconnectButton() {
  int buttonState = digitalRead(buttonPin);

  if (buttonState == LOW && lastButtonState == HIGH) {
    delay(50);
    if (digitalRead(buttonPin) == LOW) {
      disconnectUser();
    }
  }
  lastButtonState = buttonState;
}

void disconnectUser() {

  isConnected = false;
  byte dataToSend[2];
  dataToSend[0] = correspondingId;
  dataToSend[1] = nbBottles;
  Serial.println(dataToSend[0]);
  Serial.println(dataToSend[1]);
  modem.beginPacket();
  modem.write(dataToSend, sizeof(dataToSend));
  int err = modem.endPacket(true);

  if (err > 0) {
    Serial.println("ID envoyé avec succès");
  } else {
    Serial.println("Échec de l'envoi de l'ID");
  }

  Serial.println("Écoute des messages entrants...");
  if (modem.available()) {
    String receivedData = "";
    while (modem.available()) {
      receivedData += (char)modem.read();
    }
    Serial.println(receivedData);
    lcd.clear();
    lcd.setCursor(0, 1);
    lcd.print(receivedData.substring(0, min(0 + 16, receivedData.length())));
    delay(300);

    for (int i = 0; i < receivedData.length(); i++) {
      lcd.setCursor(0, 1);
      lcd.print(receivedData.substring(i, min(i + 16, receivedData.length())));
      delay(150);
    }
  }

  correspondingId = 0xFF;
  nbBottles = 0; 
      tone(buzzer, 500);
    delay(400);
    noTone(buzzer);
    delay(100);
  displayDisconnectMessage();
}

void displayDisconnectMessage() {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Deconnexion...");
  delay(2000);
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Scannez votre");
  lcd.setCursor(0, 1);
  lcd.print("carte svp");
}

void loop() {
  if (!isConnected) {
    checkRFID();
  } else {
    //checkButtons();
    checkIR();

    checkDisconnectButton();
  }
}