AlcoAlert

#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>

// --- MAX7219 Display Configuration ---
#define HARDWARE_TYPE MD_MAX72XX::FC16_HW
#define MAX_DEVICES 4

#define CLK_PIN   5
#define DATA_PIN  3
#define CS_PIN    4

// --- MQ-3 Sensor Configuration ---
#define MQ3_SENSOR_PIN 1  // Analog-capable pin

// --- Active Buzzer Configuration ---
#define BUZZER_PIN 6

// Display object
MD_Parola P = MD_Parola(HARDWARE_TYPE, DATA_PIN, CLK_PIN, CS_PIN, MAX_DEVICES);

// Flashing timing for danger alert
const unsigned long buzzerOnTime = 200;
const unsigned long buzzerOffTime = 300;
unsigned long lastFlashTime = 0;
bool flashState = false;

// Low alert flag
bool lowBeepPlayed = false;

void setup() {
  Serial.begin(115200);
  Serial.println("--- MQ-3 Alcohol Sensor Display ---");

  P.begin();
  P.setIntensity(5);
  P.displayClear();
  P.setTextAlignment(PA_CENTER);
  P.setSpeed(50);

  analogReadResolution(12);
  pinMode(BUZZER_PIN, OUTPUT);
  digitalWrite(BUZZER_PIN, LOW);
}

void loop() {
  int rawValue = analogRead(MQ3_SENSOR_PIN);
  Serial.print("MQ-3 Raw Value: ");
  Serial.println(rawValue);

  unsigned long now = millis();

  if (rawValue > 3000) {
    // High alcohol level - Danger!!
    unsigned long interval = flashState ? buzzerOnTime : buzzerOffTime;

    if (now - lastFlashTime >= interval) {
      flashState = !flashState;
      lastFlashTime = now;

      digitalWrite(BUZZER_PIN, flashState ? HIGH : LOW);
      P.displayClear();
      if (flashState) {
        P.displayText("Danger!", PA_CENTER, P.getSpeed(), 0, PA_PRINT, PA_NO_EFFECT);
      }
    }

    lowBeepPlayed = false;  // Reset one-time beep flag
    P.displayAnimate();

  } else if (rawValue > 2000) {
    // Low alcohol level
    digitalWrite(BUZZER_PIN, LOW);
    flashState = false;
    lastFlashTime = now;

    if (!lowBeepPlayed) {
      digitalWrite(BUZZER_PIN, HIGH);
      delay(200);  // Short beep
      digitalWrite(BUZZER_PIN, LOW);
      lowBeepPlayed = true;
    }

    if (P.displayAnimate()) {
      P.displayText("Warning", PA_CENTER, P.getSpeed(), 0, PA_NO_EFFECT, PA_NO_EFFECT);
    }

  } else {
    // Clean air
    digitalWrite(BUZZER_PIN, LOW);
    flashState = false;
    lowBeepPlayed = false;
    lastFlashTime = now;

    if (P.displayAnimate()) {
      P.displayText("Clean", PA_CENTER, P.getSpeed(), 0, PA_NO_EFFECT, PA_NO_EFFECT);
    }
  }

  delay(10);  // Stability
}