Introduction: A Tale of Mud, Laziness, and Enlightenment
Mission: Cheap and Tough (But Highly Effective!
Our Heroes (Component List
How It Works (Simply Explained
In Conclusion: A Tale of Savings and Clean Shoes
What’s Next? (When You Just Can’t Sit Still

Bahrik • Posted by Дмитрий Батьковичь

Published June 16, 2025 © MIT

Second Life of an ESP32 Gate Barrier

Project "Never Again Muck!"

IntermediateFull instructions provided8 hours173

Things used in this project

Hardware components

Espressif ESP32 Development Board - Developer Edition

Digilent 60W PCIe 12V 5A Power Supply

SparkFun Dual H-Bridge motor drivers L298

Geared DC Motor, 12 V

Reed Switch, SPST-NO

Switch Replacement Magnet, Honeywell 2SS

Software apps and online services

Arduino IDE

Story

Introduction: A Tale of Mud, Laziness, and Enlightenment

Be honest: who wants to crawl out of a warm car in the rain (or, even worse, after it) and trudge through clay just to lift a miserable barrier? We got fed up too—especially when it’s your own cozy corner and uninvited guests aren’t welcome. That’s when the idea struck: what if we could give our trusty old gate barrier a brain? And keep the budget from crying expensive tears? The goal seemed impossible (yet we spent far less than you’d think), and the solution turned out to be brilliantly simple. We took an old barrier, gave it a bit of an upgrade, added a couple of electronic brains—and voilà: goodbye, dirty boots!

Mission: Cheap and Tough (But Highly Effective!)

Objective: Restrict access to the property without extra hassle or major spending.Approach: Breathe new life into an old barrier. We added an electronic heart powered by an ESP32, attached a motor, and now it opens on command. No frills—just hardcore functionality!

Our Heroes (Component List)

Brain: ESP32 — our tiny but proud controller, fluent in Wi‑Fi and a million other protocols.
Muscles: 12 V planetary gearbox motor — a Chinese powerhouse rated for 200 kg. You can’t stop it by hand (we tried!).
Trainer: 5 A H‑bridge motor driver — our personal coach, telling the motor whether to spin "forward" or "backward."
Power Core: 12 V power supply — nothing fancy, just reliable.
Energy Regulator: 3.3 V DC‑DC converter — keeps the ESP32 well-fed but never overstuffed.
Barrier’s Eyes: A pair of magnets and reed switches — our end‑stop sensors. They beat push‑buttons in simplicity and tidiness; plus, you can reposition the magnets for a perfect fit.
Main Character: The barrier itself — a little battle‑worn, but freshly painted and ready for action.
Lifeline: 220 V cable — because where else would our barrier live?

How It Works (Simply Explained)

Power: We ran a 220 V line from a nearby streetlight (a bit of electrical wizardry!), connected the 12 V supply, and tucked everything inside the barrier post.
Motor Installation: Instead of fancy brackets, we welded the motor housing directly inside the post. The motor shaft links to the barrier’s pivot, and the gearbox trades speed for torque—slow but relentless.
End Stops: Reed switches and magnets serve as our barrier’s eyes. When the barrier fully opens or closes, the magnet triggers the switch, and the ESP32 cuts power to the motor. A few tweaks and the magnets stayed put perfectly.

Brain & Software: The ESP32 orchestrates it all. We wrote a simple Arduino sketch.

Initially, you connect via Wi‑Fi, open a browser, hit "Open Gate, " and watch it swing.

As our "barrier club" grew, we added a tunnel to the outside world—now you can control it remotely. A neighbor’s Wi‑Fi hotspot even saved us from buying a GSM module

In Conclusion: A Tale of Savings and Clean Shoes!

We didn’t just build a barrier—we carved out comfort and banished muddy footprints forever. And it cost almost nothing! The system turned out to be robust, user‑friendly, and—most importantly—reliable. We started with smartphone control and ended with full remote access. Progress, indeed!

Don't pay attention to the list of components, everything was bought on Aliexpress

What’s Next? (When You Just Can’t Sit Still)

Eagle Eye (Camera): Imagine seeing who’s at your gate in real time. A camera mount would let you monitor visitors—and give any would‑be thieves a second thought.
Fail‑Safe Timer: What if a reed switch fails? Our motor could spin endlessly. Add a runtime limiter—say, 10 seconds max—and stop on timeout. Safety first, even for a humble barrier.
Automatic Reclosure: Who hasn’t driven off and forgotten to close the gate? Add a timed auto‑close with photo‑eyes to avoid pinches. Open, go, and—after a preset delay—the gate swings shut all on its own.

Code

skech

#include <Arduino.h>
#include <WiFi.h>
#include <WebServer.h>
#include <ESPTunnel.h>
#include "index_page.h"

// Motor control pins (H-bridge)
#define MOTOR_FORWARD_PIN    GPIO_NUM_16  // Pin for forward movement (opening)
#define MOTOR_BACKWARD_PIN   GPIO_NUM_17  // Pin for backward movement (closing)
// Reed switch pins (limit switches)  
#define REED_OPEN_PIN        GPIO_NUM_18  // Reed switch for open position
#define REED_CLOSED_PIN      GPIO_NUM_19  // Reed switch for closed position
// WiFi
#define WIFI_SSID "MY_WIFI"
#define WIFI_PASSWORD "MY_WIFI_PASSWORD"
// To World Tunnel// Domain and secret registred in https://device-tunnel.top/
#define TUNNEL_DOMAIN "my-barrier.sytes.net" 
#define TUNNEL_SECRET ""

WebServer server(80);

bool needsOpened = false;
bool realOpened = false;

char buffer[4096]; //page render buffer
void sendPage(const char* page, ...){
  va_list args;
  va_start(args, page);
  vsnprintf_P(buffer, sizeof(buffer), page, args);
  va_end(args);
  server.send(200, "text/html", buffer);
}

void indexPage() {
  sendPage(indexPageHtml, needsOpened ? "open" : "closed");
}
void redirect(const char* url){
  server.sendHeader("Location", url, true);  
  server.send(302, "text/plain", "");
}

void stopMotor() {
  digitalWrite(MOTOR_FORWARD_PIN, LOW);
  digitalWrite(MOTOR_BACKWARD_PIN, LOW);
}
//TODO MAX WORK TIME
void startOpening() {
  digitalWrite(MOTOR_BACKWARD_PIN, LOW);
  digitalWrite(MOTOR_FORWARD_PIN, HIGH);
}
void startClosing() {
  digitalWrite(MOTOR_FORWARD_PIN, LOW);
  digitalWrite(MOTOR_BACKWARD_PIN, HIGH);
}

void setup() {
  Serial.begin(115200);

 // Pin setup
  pinMode(MOTOR_FORWARD_PIN, OUTPUT);
  pinMode(MOTOR_BACKWARD_PIN, OUTPUT);
  pinMode(REED_OPEN_PIN, INPUT_PULLUP);
  pinMode(REED_CLOSED_PIN, INPUT_PULLUP);
  stopMotor();  // Stop motor at startup
  
  // Determine initial real position
  if (digitalRead(REED_OPEN_PIN) == LOW) {
    realOpened = true;
    needsOpened = true; // Assume if open, then should be open
    Serial.println("Initial position: OPEN");
  } else if (digitalRead(REED_CLOSED_PIN) == LOW) {
    realOpened = false;
    needsOpened = false; // Assume if closed, then should be closed
    Serial.println("Initial position: CLOSED");  
  } else {
    realOpened = false;
    needsOpened = false; // Default closed
    Serial.println("Initial position: UNKNOWN (assume CLOSED)");
  }

  Serial.print("Connecting to WiFi ");
  Serial.println(WIFI_SSID);

  WiFi.mode(WIFI_STA);
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.print(" IP address: ");
  Serial.println(WiFi.localIP());

  Serial.println("Run tunnel");
  startPrivateTunnel(TUNNEL_DOMAIN, "wicket", TUNNEL_SECRET);
  //debugPrivateTunnel(TUNNEL_DOMAIN, "wicket", TUNNEL_SECRET);

  Serial.println("Run web server");

  server.on("/wicket/open", [] {
    needsOpened = true;
    Serial.println("OPEN Barrier");
    redirect("/wicket");
  });
  server.on("/wicket/close", [] {
    needsOpened = false;
    Serial.println("CLOSE Barrier");
    redirect("/wicket");
  });
  server.on("/wicket",  indexPage);
  server.on("/", [] {
    redirect("/wicket");
  });

  server.begin();
}

void loop() {
  server.handleClient();

  // Update real position by sensors
  if (digitalRead(REED_OPEN_PIN) == LOW) {
    realOpened = true;
  } else if (digitalRead(REED_CLOSED_PIN) == LOW) {
    realOpened = false;
  }

  if (needsOpened && !realOpened) {
    startOpening();
  } else if (!needsOpened && realOpened) {
    startClosing();
  } else {
    stopMotor();
  }

  delay(50);
}

Credits

Bahrik

Posted by

Дмитрий Батьковичь

Thanks to Bahrik.

Second Life of an ESP32 Gate Barrier

Things used in this project

Hardware components

Software apps and online services

Story

Introduction: A Tale of Mud, Laziness, and Enlightenment

Mission: Cheap and Tough (But Highly Effective!)

Our Heroes (Component List)

How It Works (Simply Explained)

In Conclusion: A Tale of Savings and Clean Shoes!

What’s Next? (When You Just Can’t Sit Still)

Schematics

sheme_4oohh8NLDH.png

Code

skech

Credits

Comments

Embed the widget on your own site

Second Life of an ESP32 Gate Barrier

Second Life of an ESP32 Gate Barrier

Things used in this project

Hardware components

Software apps and online services

Story

Introduction: A Tale of Mud, Laziness, and Enlightenment

Mission: Cheap and Tough (But Highly Effective!)

Our Heroes (Component List)

How It Works (Simply Explained)

In Conclusion: A Tale of Savings and Clean Shoes!

What’s Next? (When You Just Can’t Sit Still)

Schematics

sheme_4oohh8NLDH.png

Code

skech

Credits

Comments

Related channels and tags