Published December 19, 2021

Christmas Jukebox

High quality JukeBox with M5Stack node (WM8978)

BeginnerFull instructions provided543

Things used in this project

Hardware components

M5Stack M5 Faces Pocket Computer with Keyboard/PyGamer/Calculator

M5Stack NODE Smart Speaker WM8978 Module

M5Stack PIR Sensor Human Body Infrared PIR Motion Sensor (AS312)

M5Stack Core Development of Proto Board

Software apps and online services

Arduino IDE

Hand tools and fabrication machines

3D Printer (generic)

Story

#25projectsofchristmas challenge

I wanted to have some nice melody when we are in front of the Christmas tree,so I made a small jukebox that play automatically a random song from SD card every time detect someone on the front, using the motion detector (PIR) unit.

Playing a song

Hardware

Most of the job is made by the M5Stack node module, with the chip WM8978 onboard. The M5 core is responsible to check the PIR sensor connected on port B and read from the SD card inserted.

1 / 3 • Hardware in use

Software

Most of the work is made by these libraries: ESP32-audioI2S and wm8978-esp32 I used on my project.During setup, the code initialize the WM8978 chip and scan the SD card searching for mp3 files. This scan generates a list that will be used later.

void listDir(fs::FS &fs, const char * dirname, uint8_t levels) {
  String filename;
  Serial.printf("Listing directory: %s\n", dirname);

  File root = fs.open(dirname);
  if (!root) {
    Serial.println("Failed to open directory");
    return;
  }
  if (!root.isDirectory()) {
    Serial.println("Not a directory");
    return;
  }

  File file = root.openNextFile();
  while (file) {
    if (file.isDirectory()) {

    } else {
      filename = file.name();
      Serial.print("  FILE: ");
      Serial.print(file.name());
      Serial.print("  SIZE: ");
      Serial.println(file.size());

      if ((filename.indexOf(".mp3") > 0) && (filename.indexOf(".") > 0) ) {
        Serial.println("Found MP3");
        myfiles[filenum].name = filename; // Add the file to the list
        filenum++;
      }
    }
    if (filenum > 100) {
      break ;
    };
    file = root.openNextFile();
  }
}

To not interrupt or restart a song every time the PIR detect people, I block detection using a flag (var play, 0=ready, 1=playing).If the flag is 0 and the PIR detect people, I call the function startsong(), that generated a random number and start playing the correspondent song.Also print the name of the song in a box in the middle of the screen

1 / 2 • Playing

I added some small graphic, just a list of the songs on the screen and the Title.The loop function is very simple: if is playing a song, just send new data to the decoder

audio.loop();

and eventually check the button A, that can stop the play anytime.

Evolutions

This project is just a test for the node module. Even using the internal speaker on the M5Stack, the quality of the sound is really high (check on the video). Additionally, as the module offer a 3.5 mm jack, it can send output to some HIFI system.

Christmas jukebox

#include <WM8978.h> /* https://github.com/CelliesProjects/wm8978-esp32 */
#include <Audio.h>  /* https://github.com/schreibfaul1/ESP32-audioI2S */
#include <M5Stack.h>
#include <SD.h>
/* M5Stack Node WM8978 I2C pins */
#define I2C_SDA     21
#define I2C_SCL     22

/* M5Stack Node I2S pins */
#define I2S_BCK      5
#define I2S_WS      13
#define I2S_DOUT     2
#define I2S_DIN     34

/* M5Stack WM8978 MCLK gpio number */
#define I2S_MCLKPIN  0

int play = 0;
/* list of mp3 files */
String*  filedir[] = {};
int filenum = 0;
struct files {
  String name;
  int size;
};
struct files myfiles[100];

Audio audio;
WM8978 dac;

void setup() {
  M5.begin();
  M5.Power.begin();
  listDir(SD, "/", 0);
  printsongs();
  pinMode(36, INPUT); // Pir unit
  /* Setup wm8978 I2C interface */
  if (!dac.begin(I2C_SDA, I2C_SCL)) {
    ESP_LOGE(TAG, "Error setting up dac. System halted");
    while (1) delay(100);
  }

  /* set the i2s pins */
  audio.setPinout(I2S_BCK, I2S_WS, I2S_DOUT);

  /* Select I2S MCLK pin */
  audio.i2s_mclk_pin_select(I2S_MCLKPIN);

  dac.setSPKvol(40); /* max 63 */
  dac.setHPvol(32, 32);

}

void startsong() {
  int song = random(filenum);

  audio.connecttoFS(SD, myfiles[song].name.c_str());

  play = 1;
  M5.Lcd.fillRect(50, 100, 220, 100, RED);
  M5.Lcd.setCursor(60, 110);
  M5.Lcd.setTextColor(BLACK);
  M5.Lcd.print("Playing :");
  M5.Lcd.setCursor(60, 160);
  M5.Lcd.setTextColor(WHITE);
  M5.Lcd.print(myfiles[song].name);
}

void audio_eof_mp3(const char *info) { //end of file
  play = 0;
  printsongs();
}

void listDir(fs::FS &fs, const char * dirname, uint8_t levels) {
  String filename;
  Serial.printf("Listing directory: %s\n", dirname);

  File root = fs.open(dirname);
  if (!root) {
    Serial.println("Failed to open directory");
    return;
  }
  if (!root.isDirectory()) {
    Serial.println("Not a directory");
    return;
  }

  File file = root.openNextFile();
  while (file) {
    if (file.isDirectory()) {

    } else {
      filename = file.name();
      Serial.print("  FILE: ");
      Serial.print(file.name());
      Serial.print("  SIZE: ");
      Serial.println(file.size());

      if ((filename.indexOf(".mp3") > 0) && (filename.indexOf(".") > 0) ) {
        Serial.println("Found MP3");
        myfiles[filenum].name = filename;
        filenum++;
      }
    }
    if (filenum > 100) {
      break ;
    };
    file = root.openNextFile();
  }
}

void printsongs () {
  M5.Lcd.fillRect(0, 0, 320, 240, WHITE);
  M5.Lcd.fillRect(0, 0, 320, 35, RED);
  M5.Lcd.setCursor(10, 0);
  M5.Lcd.setTextColor(BLACK);
  M5.Lcd.setTextFont(2);
  M5.Lcd.setTextSize(2);

  M5.Lcd.print("Christmas JukeBox");
  M5.Lcd.setCursor(0, 40);

  M5.Lcd.setTextSize(1);
  for (int i = 0; i < filenum ; i++) {
    M5.Lcd.print(" > ");
    M5.Lcd.println(myfiles[i].name);
  }
}

void loop() {
  M5.update(); //Read the press state of the key
  if (M5.BtnA.wasReleased() || M5.BtnA.pressedFor(1000, 200)) {
    play = 0;
    printsongs();
  }
  if ( play == 1) {
    audio.loop();
  } else {
    if (digitalRead(36) == 1) {
      startsong();
    }
  }
}

Credits

Enrico Casti

10 projects • 13 followers

My name is Enrico, I work in the IT sector but I have a great passion for electronics and microcontrollers