Published April 29, 2020 © MIT

Simple digital clock using DIGISPARK ATTINY85

Simple... No... VERY SIMPLE clock in case of old "Elektronika" clock

BeginnerShowcase (no instructions)7,052

Simple digital clock using DIGISPARK ATTINY85

Things used in this project

Hardware components

DS3231 RTC module

DIGISPARK ATTINY85

MAX7219 LED matrix (32x8 dots)

Old clock's case

Wires

CR2032 Cell Battery

2.1-5.5 Power Socket

Arduino UNO

Software apps and online services

Arduino IDE

Hand tools and fabrication machines

Hot glue gun (generic)

Soldering iron (generic)

Story

Due to my natural laziness it took a lot of time to find a good case for LED-matrix based clock, but recently I got an old “Elektronika 6.15M” clock (Fig. 1). The LED-matrix and all other stuff would fit perfectly into its nice wooden case.

Fig. 1 - «Elektronika 6.15M», original version

New clock is going to have fantastic functionality in our time: it won’t connect to Internet, show weather and so on… It will display Time only. Hours and minutes. Nothing more.

DIGISPARK ATTINY85 board becomes a brain of this project (Fig. 2). All six pins are used. The main problem here may be the thing when the board comes from a factory with P5 connected to RESET of ATTINY85, which does not allow utilising this pin as usual GPIO-pin. Fortunately, this can be fixed by adjusting fuses of ATTINY85: http://thetoivonen.blogspot.com/2015/12/fixing-pin-p5-or-6-on-digispark-clones.html

Fig. 2 – DIGISPARK ATTINY85 (image from http://arduino.ua/prod1986-plata-razrabotchika-attiny85-microusb-ot-digispark)

Also the project incorporates RTC DS3231 module (Fig. 3) with battery holder to keep the IC going when there is no external power source. It works using I2C protocol.

Fig. 3 –DS3231 module (image from http://arduino.ua/prod1142-real-time-clock-modyl-s-batareikoi-ds3231)

And the clock’s “face” – 32x8 LED module with MAX7219 drivers (Fig. 4).

Fig. 4 – LED module (image from http://arduino.ua/prod2007-modyl-4-h-tochechnih-svetodiodnih-matric-na-max7219)

The circuit is shown in Fig. 5.

Fig. 5 – Circuit diagram

To compile the code of the project be sure to have libraries DS3231 and LedControl installed (Fig. 6). They can be found in Library Manager within ARDUINO IDE.

The project itself incorporates the main program (clock), files with definition and implementation of “button” class and a file with representation of digits in form of arrays (symbols, Fig. 7).

Fig. 6 – Files of the project and necessary libraries

Fig. 7 – Array representation of each digit

To debug the code I used ARDUINO Uno board because unlike DIGISPARK ATTINY85 board you don't have to reconnect it each time you need to flash it. Notice, that the code below is ready for ATTINY85.

It is recommended to flash the ATTINY85 before connecting it to other modules.

Some photos of the final assembly in Elektronika’s case:

Fig. 8 – Rear cover. I’m too lazy to make normal PCB, so there are wires, wires…

Fig. 9 – Battery bay suits well for holding the DS3231

Fig. 10 – There is enough space for ATTINY85 in power transformer bay

Fig. 11 – In fact, there is one PCB: it holds power pins for all hardware, as well as the only button. As a home-made product, there is a lot of hot glue in the project

Fig. 12 – LED module attached onto front panel using unfolded paper clips and hot glue. Contact areas are isolated with Kapton tape. It is remarkable how the matrix fits the hole

Fig. 13 – The only button and 2.1-5.5mm socket on the back. Holes for other buttons are covered

Fig. 14 – It is not necessary to disassemble the case to change the battery, just open the battery bay and take the DS3231 module

Fig. 15 – It works!

To set the time:

1) long press the button to enter hour setting mode;

2) adjust hours pressing the button normally (each press increments hours by 1);

3) long press the button to enter minute setting mode;

4) adjust minutes pressing the button normally (each press increments minutes by 1);

5) long press the button to get back into normal mode.

The clock at night:

Fig. 16 – The clock at night

Code

#include <DS3231.h>
#include <Wire.h>
#include <LedControl.h>
#include "symbols.h"
#include "button.h"

const byte PANEL_COUNT = 4;

DS3231 rtc;
//DIN, CLK, CS
LedControl lc(1, 5, 4, PANEL_COUNT);  
BUTTON btn(3);

const byte HH_MAX = 24;
const byte MM_MAX = 60;

bool h12 = false;
bool PM;

byte hh, mm, prev;

enum {rsNormal, rsSetH, rsSetM} rtcState;

void showTime(void) {
  byte f = 0;
  byte t = PANEL_COUNT;

  switch (rtcState) {
    case rsSetH: 
      f = PANEL_COUNT >> 1;
      for (byte i=0; i<f; i++) lc.clearDisplay(i);
      break;
    case rsSetM: 
      t = PANEL_COUNT >> 1;  
      for (byte i=t; i<PANEL_COUNT; i++) lc.clearDisplay(i);
      break;
  }
  
  byte digit;
  byte shift;
  
  for (byte i=f; i<t; i++) {
    switch (i) {
      case 0: digit = mm%10; shift = 1; break;
      case 1: digit = mm/10; shift = 0; break;
      case 2: digit = hh%10; shift = 3; break;
      case 3: digit = hh/10; shift = 2; break;
    }
   
    for (byte j=0; j<ROW_COUNT; j++) { 
      lc.setRow(i, j, pgm_read_byte(&symbols[digit][j]) << shift);
    }
  }

  lc.setLed(1, 1, 0, true);
  lc.setLed(1, 2, 0, true);
  lc.setLed(1, 5, 0, true);
  lc.setLed(1, 6, 0, true);

  lc.setLed(2, 1, 7, true);
  lc.setLed(2, 2, 7, true);
  lc.setLed(2, 5, 7, true);
  lc.setLed(2, 6, 7, true);
}

void setup() {
  Wire.begin();
  
  for (byte i=0; i<PANEL_COUNT; i++) {
    lc.shutdown(i, false);
    lc.setIntensity(i, 8);
    lc.clearDisplay(i);
  }
}

void loop() {
  if (rtcState == rsNormal) {
    mm = rtc.getMinute();

    if (mm != prev) {
      hh = rtc.getHour(h12, PM);
      showTime();
      prev = mm;
    }
  }
  
  switch (btn.isChanged()) {
    case bsPressed:
      switch (rtcState) {
        case rsSetH: hh = ++hh % HH_MAX; break;
        case rsSetM: mm = ++mm % MM_MAX; break;  
      }
      showTime(); 
      break;

    case bsLongPressed:
      switch (rtcState) {
        case rsNormal: rtcState = rsSetH; break;
        case rsSetH: rtc.setHour(hh); rtcState = rsSetM; break;
        case rsSetM: rtc.setMinute(mm); rtcState = rsNormal; break;
      }
      
      showTime();
      break;  
  }
}

#include "button.h"

BUTTON::BUTTON(byte pin) {
  _pin = pin;
  pinMode(_pin, INPUT_PULLUP);
  _stateS = HIGH;
  _stateL = HIGH;
  _prevTime = millis();
}

btnState BUTTON::isChanged(void) {
  btnState res = bsNone;
  unsigned long currTime = millis();

  if (!digitalRead(_pin)) {
    if (_stateS && ((currTime - _prevTime) > DEBOUNCE_DELAY)) {
       _prevTime = currTime;
       _stateS = LOW;
       _stateL = HIGH;
    }

    if (_stateL && ((currTime - _prevTime) > LONG_PRESS)) {
      _stateL = LOW;
      res = bsLongPressed;
    }
  }
  else {
    if (!_stateS) {
      if ((currTime - _prevTime) > DEBOUNCE_DELAY) {
        _prevTime = currTime;
        _stateS = HIGH;
        if (_stateL) res = bsPressed; 
      }
    }
  }  

  return res;  
}

#ifndef SYMBOLS_H
#define SYMBOLS_H

const byte ROW_COUNT = 8;
const byte SYM_COUNT = 10;

const byte symbols[SYM_COUNT][ROW_COUNT] PROGMEM = { 
  {B01110,  //0
   B11011,
   B11011,
   B11011,
   B11011,
   B11011,
   B11011,
   B01110},
  
  {B00010,  //1
   B00110,
   B01110,
   B00110,
   B00110,
   B00110,
   B00110,
   B00110},

  {B01110,  //2
   B11011,
   B00011,
   B00110,
   B01100,
   B11000,
   B11000,
   B11111},

  {B01110,  //3
   B11011,
   B00011,
   B00110,
   B00011,
   B10011,
   B11011,
   B01110},

  {B00011,  //4
   B00111,
   B01111,
   B11011,
   B10011,
   B11111,
   B00011,
   B00011},

  {B11111,  //5
   B11000,
   B11000,
   B11110,
   B00011,
   B00011,
   B11011,
   B01110},

  {B01110,  //6
   B11011,
   B11000,
   B11110,
   B11011,
   B11011,
   B11011,
   B01110},

  {B11111,  //7
   B10011,
   B00011,
   B00110,
   B01100,
   B11000,
   B11000,
   B11000},

  {B01110,  //8
   B11011,
   B11011,
   B01110,
   B11011,
   B11011,
   B11011,
   B01110},

  {B01110,  //9
   B11011,
   B11011,
   B01111,
   B00011,
   B00011,
   B11011,
   B01110} 
};

#endif

Simple digital clock using DIGISPARK ATTINY85

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Schematics

Circuit diagram

Code

clock

button.cpp

button.h

symbols.h

Credits

Comments

Embed the widget on your own site

Simple digital clock using DIGISPARK ATTINY85

Simple digital clock using DIGISPARK ATTINY85

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Schematics

Circuit diagram

Code

clock

button.cpp

button.h

symbols.h

Credits

Comments

Related channels and tags