Published May 17, 2018 © GPL3+

Solar Powered Environmental Monitoring Kit

A solar-powered open source kit for monitoring air quality, sound level, humidity, and temperature.

IntermediateFull instructions provided2 hours10,870

10 Projects of Merit

Seeed for Earth 2018

Solar Powered Environmental Monitoring Kit

Things used in this project

Hardware components

Seeed Studio Seeeduino GPRS

Seeeduino GPRS is an Arduino board with integrated GPRS module (SIM800) and support GSM, Bluetooth and FM. Instead of using it you may use Seeeduino V4 and Seeed Studio GPRS Shield V3.0.

Seeed Studio Base Shield V2

Base Shield is very useful for connecting Grove Sensors to Arduino without any soldering.

Seeed Studio 1W Solar Panel 80X100

1W Solar Panel is required for charging the Battery and providing the required power for the kit. This panel is enough for delivering the power required to run the kit at least 48 hours with 4 hours sunlight. The size is important to adjust it in the 3D printed case.

Seeed Studio LiPo Rider Pro

The LiPo Rider Pro board allows you ride the solar wave to run your favorite 5V device. The LiPo Rider Pro board is the ideal green power solution for your outdoor sensor design. Attach the LiPo Rider Pro board to your sensor board and it can run on solar power forever! Instead of LiPo Rider Pro you may also use Solar Charger Shield v2.2.

Seeed Studio Grove - Air quality sensor v1.3

The sensor can detect carbon monoxide, alcohol, acetone, thinner, formaldehyde and other slightly toxic gases. It is compatible with 5V and 3.3V power supply. The sensor is used to monitor the air quality of the environment.

Seeed Studio Grove - Loudness Sensor

The Grove - Loudness Sensor is designed to detect the loudness of environmental sound. Based on amplifier LM2904 and a built-in microphone, it amplifies and filters the high frequency signal that received from the microphone, and outputs a positive envelop. This will make for Arduino's signal acquisition. The output value depends on the level of sound input. It gives an analog output. I mapped the analog value to dB with a sound level meter. The output dB is not accurate enough and for testing purpose only.

Seeed Studio Grove - Temperature & Humidity Sensor （DHT11）

Different types of Temperature and Humidity Sensors are available with different accuracy and price. I used DHT11 for the project.

Li-Ion Battery 1000mAh

1000mAh is required for powering the device for 48 hours assuming the data will be updated once in a minute. Capacity depends on the frequency of the data update.

Software apps and online services

Arduino IDE

ThingSpeak API

Hand tools and fabrication machines

3D Printer (generic)

Story

Introduction

My city Dhaka (capital of Bangladesh) is one of the world's largest cities, with a population of 18.89 million people in the Greater Dhaka Area. It is also the 4th most densely populated city in the world.

Sorry to say that Dhaka has been ranked highest in the US Air Quality Index (AQI), for having the worst level of air pollution in the world. Noise also always goes far beyond the permissible level. Sound pollution has reached the highest 120-130 decibels (dB) at many points of the city -- almost double of the permissible level.

The Plan

To save the city it is very high time to take necessary steps. Creating public awareness is first one of the steps. For creating public awareness we need real time data of the noise we are creating everyday. If every one can see the noise level and air quality in real time it will create a mental pressure for taking steps against the pollution. Researcher will also be benefited from this open source real time data.

From the thinking I designed an open source real time city pollution monitoring device which monitors noise level, air quality, temperature, and humidity and sends the data to the ThingSpeak. I used GSM for data transmission because availability of wifi is very much limited in the city. The device gets power from a solar panel.

I tried to keep it very simple so that anybody can make his own device. No soldering is required to make the device. Just collect the required components, upload the code and plug and play all the modules. You are ready to go.

Following figures shows all the required components and modules. All the things are available in seeedstudio.com.

Required components (Grove air quality sensor, Grove sound sensor, Grove temperature&humidity sensor, Seeeduino GPRS, Base Shield, Seeed 1W Solar panel, Seeed Lipo rider pro & Lipo battery)

Collecting and Connecting all the stuff

First things first. Collect all the components mentioned above. The connection is very simple. No soldering or wire joint is required for making the device. For making your own just follow the steps (I am sure, the image uploaded below will help you):

i ) Add a sim card to Seeeduino GPRS at the bottom side. Be sure you have enough mobile data in your SIM.

ii) Upload the code attached in the code section. First code snippet is for testing and debugging. Upload second or third file. Third code snippet works as power saving mode.

Connection of all the components

iii) 3D print the attached STL files

1 / 3

After printing both files check the top cover match parfectly to the main part. Use send paper to make it smooth if required.

Complete box

iv) Attach the base shield to the Seeeduino GPRS and place these inside the printed box. You can add some hot glue for tightly attaching the modules with the box.

v) Connect Grove sound sensor to A0, Air quality sensor to A1 and Temperature and Humidity sensor to D4 connector of the base shield.

1 / 2

vi) Place the solar panel at the top of the box and bring out the wires inside the box through the hole. Use some glue to fix the solar panel with the box.

1 / 2

vii) Fix all the sensor modules and the GPRS antenna to suitable location inside the box using hot glue,

1 / 2

Placing temperature and humidity sensor

viii) Connect the solar panel and battery to appropriate connector of the LiPo Rider pro module and place inside the box as shown in the photo below. Turn on the power switch and place the top cover of the box.

If everything goes well it will start uploading the sensor data to ThingSpeak.

Connecting solar panel and battery

Congratulations! You have made your own device. Place the device in a suitable location of your city and start sharing the environmental data of your location to the community.

1 / 2 • Placing of the completed device.

This is the sample graph generated on ThingSpeak.

Code

#include <SoftwareSerial.h>
#include "AirQuality.h"
#include "Arduino.h"
#include "DHT.h"

/* Create object named GPR of the class SoftwareSerial */
SoftwareSerial GPR(8, 7);

#define DHTPIN 4     // what digital pin DHT sensor connected to
#define DHTTYPE DHT11   // model of the sensor DHT11 

#define SIM800_POWER_PIN        9
#define SIM800_POWER_STATUS     12
#define DEFAULT_TIMEOUT     5

DHT dht(DHTPIN, DHTTYPE);

AirQuality airqualitysensor;
int current_quality =-1;

//replace with your own API key
String API_KEY = "api_key=B3FPE7GTVY1ISGQS";
String field = "";


const int sampleWindow = 50;                              // Sample window width in mS (50 mS = 20Hz)
unsigned int sample;
float value;
float temp, humid;
int airQuality;

 //--------------------------------------------------------------------------------------------
 //                                            SETUP
 //--------------------------------------------------------------------------------------------
void setup() 
{
   GPR.begin(9600);  /* Define baud rate for software serial communication */
   Serial.begin(9600);                                    //Serial comms for debugging
   airqualitysensor.init(14);
   dht.begin();
   //start sim800
   pinMode(SIM800_POWER_PIN, OUTPUT);
   digitalWrite(SIM800_POWER_PIN,HIGH);
   delay(200);
   digitalWrite(SIM800_POWER_PIN,LOW);
   delay(2000);
   digitalWrite(SIM800_POWER_PIN,HIGH);
   delay(3000);  

}
 
//--------------------------------------------------------------------------------------------
 //                                         MAIN LOOP
 //--------------------------------------------------------------------------------------------
  
void loop() 
{
 
 
 value = calculate_sound_in_db();
 API_KEY = "api_key=B3FPE7GTVY1ISGQS";
 API_KEY += "&field1=";
 API_KEY += value;
 send_data();


 airQuality = calculate_air_quality();
 API_KEY = "api_key=B3FPE7GTVY1ISGQS";
 API_KEY += "&field4=";
 API_KEY += airQuality;
 send_data();
 
 calculate_temp_humid();
 API_KEY = "api_key=B3FPE7GTVY1ISGQS";
 API_KEY += "&field2=";
 API_KEY += temp;
 send_data();
 
 API_KEY = "api_key=B3FPE7GTVY1ISGQS";
 API_KEY += "&field3=";
 API_KEY += humid;
 send_data();
 
 delay(5000);
}

//this function calculate sound level in dB
float calculate_sound_in_db(){
   unsigned long startMillis= millis();                   // Start of sample window
   float peakToPeak = 0;                                  // peak-to-peak level
 
   unsigned int signalMax = 0;                            //minimum value
   unsigned int signalMin = 1024;                         //maximum value
 
                                                          // collect data for 50 mS
   while (millis() - startMillis < sampleWindow)
   {
      sample = analogRead(A1);                             //get reading from microphone
      if (sample < 1024)                                  // toss out spurious readings
      {
         if (sample > signalMax)
         {
            signalMax = sample;                           // save just the max levels
         }
         else if (sample < signalMin)
         {
            signalMin = sample;                           // save just the min levels
         }
      }
   }
   peakToPeak = signalMax - signalMin;                    // max - min = peak-peak amplitude
   //Serial.println(peakToPeak);                                     //write calibrated deciBels
   float db = map(peakToPeak,0,1000,48,120);             //calibrate for deciBels
   Serial.print(db);                                     //write calibrated deciBels
   Serial.println(" dB");                                  //write units
   return db;
}

int calculate_air_quality(){
  current_quality=airqualitysensor.slope();
    if (current_quality >= 0)// if a valid data returned.
    {
        if (current_quality==0)
            Serial.println("High pollution! Force signal active");
        else if (current_quality==1)
            Serial.println("High pollution!");
        else if (current_quality==2)
            Serial.println("Low pollution!");
        else if (current_quality ==3)
            Serial.println("Fresh air");
    }
  return current_quality;
}

void calculate_temp_humid(){
  // Reading temperature or humidity takes about 250 milliseconds!
  // Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
  float h = dht.readHumidity();
  // Read temperature as Celsius (the default)
  float t = dht.readTemperature();

  // Check if any reads failed and exit early (to try again).
  if (isnan(h) || isnan(t)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  temp = t;
  humid = h;
  
  Serial.print("Humidity: ");
  Serial.print(h);
  Serial.print(" %\t");
  Serial.print("Temperature: ");
  Serial.print(t);
  Serial.print(" *C ");
}
//this function sends data to ThingSpeak server
//it takes approximately 13 seconds to send data to server using GPRS
void send_data(){ 
  Serial.print("Checking Communication...");
  GPR.println("AT"); /* Check Communication */
  delay(200);
  ShowSerialData(); /* Print response on the serial monitor */
  delay(100);
  /* Configure bearer profile 1 */
  Serial.print("Set connection type as GPRS: ");
  GPR.println("AT+SAPBR=3,1,\"CONTYPE\",\"GPRS\"");  /* Connection type GPRS */
  delay(1500);
  ShowSerialData();
  delay(100);
  Serial.print("Set APN as gpinternet: ");
  GPR.println("AT+SAPBR=3,1,\"APN\",\"gpinternet\"");  /* APN of the provider */
  delay(1500);
  ShowSerialData();
  delay(100);
  Serial.print("Open GPRS context: ");
  GPR.println("AT+SAPBR=1,1"); /* Open GPRS context */
  delay(1500);
  ShowSerialData();
  delay(100);
  Serial.print("Query the GPRS context: ");
  GPR.println("AT+SAPBR=2,1"); /* Query the GPRS context */
  delay(1500);
  ShowSerialData();
  delay(100);
  Serial.print("Initilize HTTP service: ");
  GPR.println("AT+HTTPINIT");  /* Initialize HTTP service */
  delay(1500); 
  ShowSerialData();
  delay(100);
  Serial.print("HTTP parameter set: ");
  GPR.println("AT+HTTPPARA=\"CID\",1");  /* Set parameters for HTTP session */
  delay(1500);
  ShowSerialData();
  delay(100);
  
  Serial.print("HTTP URL set: ");
  GPR.println("AT+HTTPPARA=\"URL\",\"api.thingspeak.com/update\"");  
  delay(2000);
  ShowSerialData();
  delay(100);
  Serial.print("HTTP Post data: ");
  GPR.println("AT+HTTPDATA=33,10000"); 
  delay(2000);
  ShowSerialData();
  delay(100);
  Serial.print("HTTP data set: ");  
  //GPR.println("api_key=B3FPE7GTVY1ISGQS&field1=2");
  GPR.println(API_KEY);
  delay(2000);
  ShowSerialData();
  delay(100);

  Serial.print("Start post session: ");
  GPR.println("AT+HTTPACTION=1");  /* Start POST session */
  delay(2000);
  ShowSerialData();
  delay(100);
  Serial.print("Terminate HTTP service: ");  
  GPR.println("AT+HTTPTERM");  /* Terminate HTTP service */
  delay(2000);
  ShowSerialData();
  delay(100);
  Serial.print("Close GPRS context: ");
  GPR.println("AT+SAPBR=0,1"); /* Close GPRS context */
  delay(2000);
  ShowSerialData();
  delay(100);
}

//this function is used for debugging purpose
//print the response back from gprs module
void ShowSerialData()
{
  while(GPR.available()!=0)  /* If data is available on serial port */
  Serial.write(char (GPR.read())); /* Print character received on to the serial monitor */
}
//interrupt service routine for air quality sensor
ISR(TIMER1_OVF_vect)
{
  if(airqualitysensor.counter==61)//set 2 seconds as a detected duty
  {

      airqualitysensor.last_vol=airqualitysensor.first_vol;
      airqualitysensor.first_vol=analogRead(A0);
      airqualitysensor.counter=0;
      airqualitysensor.timer_index=1;
      PORTB=PORTB^0x20;
  }
  else
  {
    airqualitysensor.counter++;
  }
}

#include <SoftwareSerial.h>
#include "AirQuality.h"
#include "Arduino.h"
#include "DHT.h"

/* Create object named GPRS of the class SoftwareSerial */
SoftwareSerial GPRS(8, 7);

#define DHTPIN 4     // what digital pin DHT sensor connected to
#define DHTTYPE DHT11   // model of the sensor DHT11 

#define SIM800_POWER_PIN        9
#define SIM800_POWER_STATUS     12
#define DEFAULT_TIMEOUT     5

DHT dht(DHTPIN, DHTTYPE);

AirQuality airqualitysensor;
int current_quality =-1;

//replace with your own API key
String API_KEY = "api_key=B3FPE7GTVY1ISGQS";
String field = "";


const int sampleWindow = 50;                              // Sample window width in mS (50 mS = 20Hz)
unsigned int sample;
float value;
float temp, humid;
int airQuality;

 //--------------------------------------------------------------------------------------------
 //                                            SETUP
 //--------------------------------------------------------------------------------------------
void setup() 
{
   GPRS.begin(9600);  /* Define baud rate for software serial communication */
   airqualitysensor.init(14);
   dht.begin();
   //start sim800
   pinMode(SIM800_POWER_PIN, OUTPUT);
   digitalWrite(SIM800_POWER_PIN,HIGH);
   delay(200);
   digitalWrite(SIM800_POWER_PIN,LOW);
   delay(2000);
   digitalWrite(SIM800_POWER_PIN,HIGH);
   delay(3000);  

}
 
//--------------------------------------------------------------------------------------------
 //                                         MAIN LOOP
 //--------------------------------------------------------------------------------------------
  
void loop() 
{
 
 
 value = calculate_sound_in_db();
 airQuality = calculate_air_quality();
 calculate_temp_humid();
 
 API_KEY = "api_key=B3FPE7GTVY1ISGQS";
 API_KEY += "&field1=";
 API_KEY += value;
 API_KEY += "&field2=";
 API_KEY += temp;
 API_KEY += "&field3=";
 API_KEY += humid;
 API_KEY += "&field4=";
 API_KEY += airQuality;
 send_data();
 
 delay(120000);
}

//this function calculate sound level in dB
float calculate_sound_in_db(){
   unsigned long startMillis= millis();                   // Start of sample window
   float peakToPeak = 0;                                  // peak-to-peak level
 
   unsigned int signalMax = 0;                            //minimum value
   unsigned int signalMin = 1024;                         //maximum value
 
                                                          // collect data for 50 mS
   while (millis() - startMillis < sampleWindow)
   {
      sample = analogRead(A1);                             //get reading from microphone
      if (sample < 1024)                                  // toss out spurious readings
      {
         if (sample > signalMax)
         {
            signalMax = sample;                           // save just the max levels
         }
         else if (sample < signalMin)
         {
            signalMin = sample;                           // save just the min levels
         }
      }
   }
   peakToPeak = signalMax - signalMin;                    // max - min = peak-peak amplitude
   //Serial.println(peakToPeak);                                     //write calibrated deciBels
   float db = map(peakToPeak,0,1000,48,120);             //calibrate for deciBels
   return db;
}

int calculate_air_quality(){
  current_quality=airqualitysensor.slope();
  return current_quality;
}

void calculate_temp_humid(){
  // Reading temperature or humidity takes about 250 milliseconds!
  // Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
  float h = dht.readHumidity();
  // Read temperature as Celsius (the default)
  float t = dht.readTemperature();

  // Check if any reads failed and exit early (to try again).
  if (isnan(h) || isnan(t)) {
    return;
  }

  temp = t;
  humid = h;
}
//this function sends data to ThingSpeak server
//it takes approximately 13 seconds to send data to server using GPRSS
void send_data(){  
  GPRS.println("AT"); /* Check Communication */
  delay(200);
  /* Configure bearer profile 1 */
  GPRS.println("AT+SAPBR=3,1,\"CONTYPE\",\"GPRSS\"");  /* Connection type GPRSS */
  delay(500);
  GPRS.println("AT+SAPBR=3,1,\"APN\",\"gpinternet\"");  /* APN of the provider */
  delay(1500);
  GPRS.println("AT+SAPBR=1,1"); /* Open GPRSS context */
  delay(1500);
  GPRS.println("AT+SAPBR=2,1"); /* Query the GPRSS context */
  delay(1500);
  GPRS.println("AT+HTTPINIT");  /* Initialize HTTP service */
  delay(1500); 
  GPRS.println("AT+HTTPPARA=\"CID\",1");  /* Set parameters for HTTP session */
  delay(1500);
  GPRS.println("AT+HTTPPARA=\"URL\",\"api.thingspeak.com/update\"");  
  delay(2000);
  GPRS.println("AT+HTTPDATA=33,10000"); 
  delay(2000);
  //GPRS.println("api_key=B3FPE7GTVY1ISGQS&field1=2");
  GPRS.println(API_KEY);
  delay(2000);
  GPRS.println("AT+HTTPACTION=1");  /* Start POST session */
  delay(2000); 
  GPRS.println("AT+HTTPTERM");  /* Terminate HTTP service */
  delay(2000);
  GPRS.println("AT+SAPBR=0,1"); /* Close GPRSS context */
  delay(2000);
}

//interrupt service routine for air quality sensor
ISR(TIMER1_OVF_vect)
{
  if(airqualitysensor.counter==61)//set 2 seconds as a detected duty
  {

      airqualitysensor.last_vol=airqualitysensor.first_vol;
      airqualitysensor.first_vol=analogRead(A0);
      airqualitysensor.counter=0;
      airqualitysensor.timer_index=1;
      PORTB=PORTB^0x20;
  }
  else
  {
    airqualitysensor.counter++;
  }
}

#include <SoftwareSerial.h>
#include <avr/sleep.h>
#include <avr/power.h>
#include <avr/wdt.h>
#include "AirQuality.h"
#include "Arduino.h"
#include "DHT.h"

/* Create object named GPRS of the class SoftwareSerial */
SoftwareSerial GPRS(8, 7);

#define DHTPIN 4     // what digital pin DHT sensor connected to
#define DHTTYPE DHT11   // model of the sensor DHT11 

#define SIM800_POWER_PIN        9
#define SIM800_POWER_STATUS     12
#define DEFAULT_TIMEOUT     5
#define DTR_PIN 11

DHT dht(DHTPIN, DHTTYPE);

AirQuality airqualitysensor;
int current_quality =-1;

//replace with your own API key
String API_KEY = "api_key=B3FPE7GTVY1ISGQS";
String field = "";

//Value for watchdog timer interrupt.
volatile int f_wdt = 1;
int seconds = 0;
int minutes = 2;
int hours = 0;
int interval = ((hours*60*60) + (minutes*60) + (seconds))/8;
int timerCounter = 0;

const int sampleWindow = 50;                              // Sample window width in mS (50 mS = 20Hz)
unsigned int sample;
float value;
float temp, humid;
int airQuality;


//ISR for watchdog timer.
ISR(WDT_vect)
{
  if(f_wdt == 0)
  {
    f_wdt=1;
    timerCounter++;
  }
  else
  {
    Serial.println("WDT Overrun!!!");
  }
}

 //--------------------------------------------------------------------------------------------
 //                                            SETUP
 //--------------------------------------------------------------------------------------------
void setup() 
{
   GPRS.begin(9600);  /* Define baud rate for software serial communication */
   airqualitysensor.init(14);
   dht.begin();
   setupWdt();
   //start sim800
   pinMode(SIM800_POWER_PIN, OUTPUT);
   digitalWrite(SIM800_POWER_PIN,HIGH);
   delay(200);
   digitalWrite(SIM800_POWER_PIN,LOW);
   delay(2000);
   digitalWrite(SIM800_POWER_PIN,HIGH);
   delay(3000);  
   pinMode(DTR_PIN, OUTPUT);
   digitalWrite(DTR_PIN, HIGH); //this pin should be high to enable sleep mode of sim800

}
 
//--------------------------------------------------------------------------------------------
 //                                         MAIN LOOP
 //--------------------------------------------------------------------------------------------
  
void loop() 
{
 if(f_wdt == 1)
  {
    if (timerCounter == interval)
    {
      //wdt_disable();
      //Serial.println(F("Tried to stop the watchdog."));
      //wdt_reset();

      value = calculate_sound_in_db();
      airQuality = calculate_air_quality();
      calculate_temp_humid();
      //field should be according to ThingSpeak chennel seting
      API_KEY = "api_key=B3FPE7GTVY1ISGQS";
      API_KEY += "&field1=";
      API_KEY += value;
      API_KEY += "&field2=";
      API_KEY += temp;
      API_KEY += "&field3=";
      API_KEY += humid;
      API_KEY += "&field4=";
      API_KEY += airQuality;
      send_data();

      //Reset timer.
      timerCounter = 0;
      //wdt_enable();
      //Serial.println(F("Tried to re-enable watchdog."));
    }

    /* Don't forget to clear the flag. */
    f_wdt = 0;

    /* Re-enter sleep mode. */
    enterSleep();
  }
  else
  {
    /* Do nothing. */
  }

}

//this function calculate sound level in dB
float calculate_sound_in_db(){
   unsigned long startMillis= millis();                   // Start of sample window
   float peakToPeak = 0;                                  // peak-to-peak level
 
   unsigned int signalMax = 0;                            //minimum value
   unsigned int signalMin = 1024;                         //maximum value
 
                                                          // collect data for 50 mS
   while (millis() - startMillis < sampleWindow)
   {
      sample = analogRead(A1);                             //get reading from microphone
      if (sample < 1024)                                  // toss out spurious readings
      {
         if (sample > signalMax)
         {
            signalMax = sample;                           // save just the max levels
         }
         else if (sample < signalMin)
         {
            signalMin = sample;                           // save just the min levels
         }
      }
   }
   peakToPeak = signalMax - signalMin;                    // max - min = peak-peak amplitude
   //Serial.println(peakToPeak);                                     //write calibrated deciBels
   float db = map(peakToPeak,0,1000,48,120);             //calibrate for deciBels
   return db;
}

int calculate_air_quality(){
  current_quality=airqualitysensor.slope();
  return current_quality;
}

void calculate_temp_humid(){
  // Reading temperature or humidity takes about 250 milliseconds!
  // Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
  float h = dht.readHumidity();
  // Read temperature as Celsius (the default)
  float t = dht.readTemperature();

  // Check if any reads failed and exit early (to try again).
  if (isnan(h) || isnan(t)) {
    return;
  }

  temp = t;
  humid = h;
}
//this function sends data to ThingSpeak server
//it takes approximately 13 seconds to send data to server using GPRSS
void send_data(){  
  GPRS.println("AT"); /* Check Communication */
  delay(200);
  GPRS.println("AT"); /* Check Communication */
  delay(200);
  GPRS.println("AT+CSCLK=0"); /* disable sleep mode */
  delay(500);
  /* Configure bearer profile 1 */
  GPRS.println("AT+SAPBR=3,1,\"CONTYPE\",\"GPRSS\"");  /* Connection type GPRSS */
  delay(500);
  GPRS.println("AT+SAPBR=3,1,\"APN\",\"gpinternet\"");  /* APN of the provider */
  delay(1500);
  GPRS.println("AT+SAPBR=1,1"); /* Open GPRSS context */
  delay(1500);
  wdt_reset(); //manually reset wdt timer to prevent interrupt
  GPRS.println("AT+SAPBR=2,1"); /* Query the GPRSS context */
  delay(1500);
  GPRS.println("AT+HTTPINIT");  /* Initialize HTTP service */
  delay(1500); 
  GPRS.println("AT+HTTPPARA=\"CID\",1");  /* Set parameters for HTTP session */
  delay(1500);
  wdt_reset();
  GPRS.println("AT+HTTPPARA=\"URL\",\"api.thingspeak.com/update\"");  
  delay(2000);
  GPRS.println("AT+HTTPDATA=33,10000"); 
  delay(2000);
  wdt_reset();
  //GPRS.println("api_key=B3FPE7GTVY1ISGQS&field1=2");
  GPRS.println(API_KEY);
  delay(2000);
  GPRS.println("AT+HTTPACTION=1");  /* Start POST session */
  delay(2000); 
  wdt_reset();
  GPRS.println("AT+HTTPTERM");  /* Terminate HTTP service */
  delay(2000);
  GPRS.println("AT+SAPBR=0,1"); /* Close GPRSS context */
  delay(2000);
  wdt_reset();
  GPRS.println("AT+CSCLK=2"); /* enable sleep mode */
  delay(500);
}

void enterSleep(void)
{
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);
  sleep_enable();

  /* Now enter sleep mode. */
  sleep_mode();

  /* The program will continue from here after the WDT timeout*/
  sleep_disable(); /* First thing to do is disable sleep. */

  /* Re-enable the peripherals. */
  power_all_enable();
}

void setupWdt()
{
  /*** Setup the WDT ***/

  /* Clear the reset flag. */
  MCUSR &= ~(1<<WDRF);

  /* In order to change WDE or the prescaler, we need to
   * set WDCE (This will allow updates for 4 clock cycles).
   */
  WDTCSR |= (1<<WDCE) | (1<<WDE);

  /* set new watchdog timeout prescaler value */
  WDTCSR = 1<<WDP0 | 1<<WDP3; /* 8.0 seconds */

  /* Enable the WD interrupt (note no reset). */
  WDTCSR |= _BV(WDIE);
}

//interrupt service routine for air quality sensor
ISR(TIMER1_OVF_vect)
{
  if(airqualitysensor.counter==61)//set 2 seconds as a detected duty
  {

      airqualitysensor.last_vol=airqualitysensor.first_vol;
      airqualitysensor.first_vol=analogRead(A0);
      airqualitysensor.counter=0;
      airqualitysensor.timer_index=1;
      PORTB=PORTB^0x20;
  }
  else
  {
    airqualitysensor.counter++;
  }
}

Credits

Md. Khairul Alam

64 projects • 568 followers

Developer, Maker & Hardware Hacker. Currently working as a faculty at the University of Asia Pacific, Dhaka, Bangladesh.

Comments

Awards

10 Projects of Merit

Seeed for Earth 2018

Solar Powered Environmental Monitoring Kit

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Introduction

The Plan

Collecting and Connecting all the stuff

Custom parts and enclosures

Main Body of the box

Front Cover

Code

Code for Testing

Final Code

Final Sketch with Power Saving

Credits

Md. Khairul Alam

Comments

Awards

Embed the widget on your own site

Solar Powered Environmental Monitoring Kit

Solar Powered Environmental Monitoring Kit

Things used in this project

Hardware components

Software apps and online services

Hand tools and fabrication machines

Story

Introduction

The Plan

Collecting and Connecting all the stuff

Custom parts and enclosures

Main Body of the box

Front Cover

Code

Code for Testing

Final Code

Final Sketch with Power Saving

Credits

Md. Khairul Alam

Comments

Awards

Related channels and tags