Published September 23, 2015

IoT Fall Detection

This project utilizes Texas Instruments hardware as well as services provided by Temboo to monitor for a fall and alert the user by SMS.

BeginnerFull instructions provided2,499

Things used in this project

Story

This project will walks through how easy it is to interface the Texas Instruments LaunchPad development kit with Temboo's online service to quickly prototype an IoT device. The beauty of the Temboo service is its ability to make interacting with APIs simple. Here we will be using the Twilio API to create and send an SMS triggered by a change in the Educational BoosterPack MKII's accelerometer readings. As the user we simply have to set up an account with both Temboo and Twilio, fill in some settings, and finally slightly modify some Temboo generated code.

Account Set Up

Getting a Temboo account set up is the first step required in creating this fall detector. Fortunately, Temboo makes it very easy to get up an running.

1. Getting set up in Temboo

Create a Temboo account and navigate to the Twilio library section which can be found here.

Twilio section of the Temboo Choreo database

2.Getting set up in Twilio

Follow the instructions to get a Twilio account set up in order to enable Temboo-triggered voice calls or SMS messages. The sign up link for Twilio can be found on the Temboo library page as well as here.

After getting Twilio set up, follow the steps provided to register the phone number you want alerted when your device falls.

Gather your Twilio API key from the user dashboard page. This can be found here.

Twilio dashboard used to find API credentials and the Twilio "From" number

3. Bring them both together

Once Twilio is set up, it is time to sit back and let Temboo do the work for us. Navigate to the SendSMS Choreo also found here.

Overview of the available SMS Choreos through Temboo

Building the Project

1. Connecting your LaunchPad to the network

First, make sure that the "IoT Mode" toggle switch found in the top right of the page is set to "on". This will unlock some new settings at the top of the page. Make sure to select "Texas Instruments LaunchPad" for hardware. For the connection, if this is your first time using Temboo, you will have to set the internet connection up. We will be using the TI CC3100 WiFi BoosterPack to connect to the network, so select that from the drop down. Fill in your network settings and give it a convenient name so you can save the settings and do not have to set up the connection every time. Go ahead and ignore the "Want to stream sensor data?" drop down for this project as it will not be used.

Setting up the connection through Temboo

2. Adapting the code to be triggered by an event

Hit the plus sign next to "Is this Choreo triggered by a sensor event?". By default this Choreo will trigger when pin 6.1's analog value drops down to zero. Leave this as a default. We will edit it in the code later, but it is important to have the conditional added.

3. Connecting to the Twilio API

In the input section, fill in the AccountSID and AuthToken from the user Twilio dashboard. This should have been found in Step 2 of the account set up. The Body is simply the text that you would like to be sent to your phone to indicate when the device has been knocked over. The "From" number is also from your Twilio profile, with a trial account you should be able to get one free number to call/text from. The "To" number is the number that you would like to send the SMS to, it is important to make sure that you have registered this number with Twilio or else the Choreo will fail.

4. Saving the Twilio profile in Temboo

Once everything is filled in, press the "save" button next to the "Select Profile" drop down. Give your Twilio profile a name, and make sure to remember it for later.

Finalized settings on Temboo to communicate with the Twilio service

5. Test the Choreo

That's all it takes from the Temboo side! We are almost completely done. Go ahead and hit the "Run" button on the Temboo page. This should return with a success and trigger a text message to be sent. This means that everything is set up and we are ready to copy our code into Energia where we need to make a couple of changes.

6. Set up the accelerometer event

Go ahead and download AccelTxt.ino, found below on the page, and open it in Energia. This code was created using the Temboo code as a foundation and manipulated to use the accelerometer from the Educational BoosterPack to trigger the SMS instead of the default analog pin 6.1. Make sure to change line 110, SendSMS.setProfile("Twilionum"), and rename the profile to whatever name you gave in step four of Building the Project. Take some time to compare the differences between the code on Temboo's site and AccelTxt.ino and realize how similar they are!

7. Edit the Temboo Account Library

The final step is to set up TembooAccount.h which is a library that the code uses to verify your Temboo account and successfully call Choreos. An example of the library can be found below, all you have to do is change the 'X's' to the values found on your Temboo page. You can also use the TembooAccount.h provided on the Temboo site instead of copying and pasting to replace the 'X's'. Make sure to add this as a header file to wherever your Energia libraries are stored.

8. Run it!

Thats it! Go ahead and flash your LaunchPad and open a serial monitor connection. You should see the LaunchPad connect to WiFi using the CC3100 BoosterPack and then it will start reading out accelerometer values. Once any of the values differ from the initialized values more than the maxChange variable (set by default to 100 in the code below) the sendSMS Choreo will trigger causing a text to be sent to the recipient specified through Temboo.

Success!

Happy Coding! Be sure to explore all of the other services Temboo offers!

#include <SPI.h>
#include <WiFi.h>
#include <WiFiClient.h>

#include <Temboo.h>
#include "TembooAccount.h" // Contains Temboo account information

WiFiClient client;

// Set the number of Max Calls to one since the user only needs to be notified once that the object has fallen
int maxCalls = 1;

// The number of times this Choreo has been run so far in this sketch
int calls = 0;

const int xpin = 23;                  // x-axis of the accelerometer
const int ypin = 24;                  // y-axis
const int zpin = 25;                  // z-axis (only on 3-axis models)
const int maxChange = 100;             // increment the accelerometer value needs to change in order to trigger the choreo
//initialize accelerometer values
int x_val = 0;
int y_val = 0;
int z_val = 0;
int x_init = 0;
int y_init = 0;
int z_init = 0;
boolean firstRun = 1;

void setup() {
  Serial.begin(9600);

  int wifiStatus = WL_IDLE_STATUS;

  // Determine if the WiFi Shield is present
  Serial.print("\n\nShield:");
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("FAIL");

    // If there's no WiFi shield, stop here
    while(true);
  }

  Serial.println("OK");

  // Try to connect to the local WiFi network
  while(wifiStatus != WL_CONNECTED) {
    Serial.print("WiFi:");
    wifiStatus = WiFi.begin(WIFI_SSID, WPA_PASSWORD);

    if (wifiStatus == WL_CONNECTED) {
      Serial.println("OK");
    } 
    else {
      Serial.println("FAIL");
    }
    delay(5000);
  }

  // Initialize pins
  pinMode(xpin,INPUT);
  pinMode(ypin,INPUT);
  pinMode(zpin,INPUT);

  Serial.println("Setup complete.\n");
}

void loop() {
  //read in current values of accelerometer and print through serial
  x_val = analogRead(xpin);
  y_val = analogRead(ypin);
  z_val = analogRead(zpin);
  Serial.print(x_val);
  Serial.print("\t");
  Serial.print(y_val);
  Serial.print("\t");
  Serial.print(z_val);
  Serial.print("\n\r");
  //check if first time running through and if base values need to be set
  if(!firstRun){
    //trigger the choreo if the accelerometer values have changed more than the max allowed amount
    if ((abs(x_val-x_init)>=maxChange)||(abs(y_val-y_init)>=maxChange)||(abs(z_val-z_init)>=maxChange)) {
      if (calls < maxCalls) {
        Serial.println("\nTriggered! Calling SendSMS Choreo...");
        runSendSMS();
        calls++;
      } 
      else {
        Serial.println("\nTriggered! Already notified user of the fall so no text sent!");
      }
    }
    delay(250);
  }
  else{
    //if this is the first time through, set the initial values and change the firstRun boolean value
    x_init = x_val;
    y_init = y_val;
    z_init = z_val;
    firstRun = 0;
  }
}
void runSendSMS() {
  TembooChoreo SendSMSChoreo(client);

  // Set Temboo account credentials
  SendSMSChoreo.setAccountName(TEMBOO_ACCOUNT);
  SendSMSChoreo.setAppKeyName(TEMBOO_APP_KEY_NAME);
  SendSMSChoreo.setAppKey(TEMBOO_APP_KEY);

  // Set profile to use for execution
  SendSMSChoreo.setProfile("Twiliownum");
  // Identify the Choreo to run
  SendSMSChoreo.setChoreo("/Library/Twilio/SMSMessages/SendSMS");

  // Run the Choreo
  unsigned int returnCode = SendSMSChoreo.run();

  // Read and print the error message
  while (SendSMSChoreo.available()) {
    char c = SendSMSChoreo.read();
    Serial.print(c);
  }
  Serial.println();
  SendSMSChoreo.close();
}

/*
IMPORTANT NOTE about TembooAccount.h

TembooAccount.h contains your Temboo account information and must be included
alongside your sketch. To do so, make a new tab in Energia, call it TembooAccount.h,
and copy this content into it. 
*/

#define TEMBOO_ACCOUNT "XXXXXXXX"  // Your Temboo account name 
#define TEMBOO_APP_KEY_NAME "myFirstApp"  // Your Temboo app name
#define TEMBOO_APP_KEY "XXXXXXXX"  // Your Temboo app key

#define WIFI_SSID "XXXXXXXX"
#define WPA_PASSWORD "XXXXXXXX!"

/* 
The same TembooAccount.h file settings can be used for all Temboo sketches.

Keeping your account information in a separate file means you can share the 
main .ino file without worrying that you forgot to delete your credentials.
*/

Credits

Chris Roberts

8 projects • 21 followers

I am an applications engineer with Texas Instruments working with the Launchpad by trade, and a maker by passion!

IoT Fall Detection

Things used in this project

Hardware components

Software apps and online services